webos: webos-backports-5.1: linux-raspberrypi=v6.1.77 linux-raspberry…

…pi=v6.6.36

:Release Notes:
Backport latest kernel for rpi MACHINEs to fix compatibility with
wireless-regdb-2024.01.23 and newer.

:Detailed Notes:
There is recipes-kernel/linux/linux-raspberrypi_6.1.bb recipe in
meta-raspberrypi/kirkstone which was backported to support raspberrypi5
which we can switch to by setting PREFERRED_VERSION_linux-raspberrypi
(all rpis use 6.1 since mickledore and 6.6 since scarthgap).

rpi-6.1.y has these changes as well:

BUILD/work-shared/raspberrypi4-64/kernel-source $ git log rpi-6.1.y --oneline net/wireless/certs/wens.hex
db57ef0dd4c2 wifi: cfg80211: fix certs build to not depend on file order
ec350809cd98 wifi: cfg80211: Add my certificate

but only since 6.1.74 (not 6.1.61 currently used in meta-raspberrypi/kirkstone),
so backport newer 6.1 from:
agherzan/meta-raspberrypi#1317 [kirkstone] linux-raspberrypi_6.1.bb: Upgrade to 6.1.77
agherzan/meta-raspberrypi#1319 [mickledore] linux-raspberrypi_6.1.bb: Upgrade to 6.1.77
agherzan/meta-raspberrypi#1318 [nanbield] linux-raspberrypi_6.1.bb: Upgrade to 6.1.77
agherzan/meta-raspberrypi#1320 [scarthgap] linux-raspberrypi: Drop 5.15

This can be dropped once the above PRs are merged upstream and
weboslayers.py updated but it would be useful to keep for langdale
compatibility as meta-raspberrypi/langdale doesn't have 6.1 recipe
at all and it would break the bisect-ability of yocto upgrade chain.

:Testing Performed:
Only build tested.

:QA Notes:
No change to image.

:Issues Addressed:
[WRQ-20169] CCC: webos-backports-5.1: linux-raspberrypi=v6.1.77 linux-raspberrypi=v6.6.36
[WRQ-20759] iw reg set doesn't work
[WRQ-16273] [TAS Failed][OSE][QWAPI-3045] com.webos.service.wifi: getCountryCode
[WRQ-693] Create GPVB with Yocto 4.2 Mickledore

Cherry-picked-from-commit: 967ac81f069d6b9e05f56c6bf7b76da7f0737b73
Cherry-picked-from-branch:

meta-webos-backports/meta-webos-backports-5.1/conf/layer.conf

@@ -18,4 +18,18 @@ LAYERDEPENDS_meta-webos-backports-5.1 = " \
     openembedded-layer \
 "
 
-BBFILE_PATTERN_IGNORE_EMPTY_meta-webos-backports-5.1 = "1"
+BBFILES_DYNAMIC += " \
+    raspberrypi:${LAYERDIR}/dynamic-layers/raspberrypi/*/*/*.bb \
+    raspberrypi:${LAYERDIR}/dynamic-layers/raspberrypi/*/*/*.bbappend \
+"
+
+# We need to BBMASK the other 6.1.77 recipe from upstream meta-raspberrypi
+# because now when they have the same PV, then PREFERRED_VERSION doesn't
+# allow us to use the version from meta-webos-backports and the one
+# from upstream meta-raspberrypi (which has priority 50 in our builds
+# while this meta-webos-backports-5.1 layer only 34) is missing
+# android-driver.cfg update from:
+# https://github.com/agherzan/meta-raspberrypi/pull/1351
+# Similarly with 6.6 in scarthgap builds.
+BBMASK += "meta-raspberrypi/recipes-kernel/linux/linux-raspberrypi_6.1.bb"
+BBMASK += "meta-raspberrypi/recipes-kernel/linux/linux-raspberrypi_6.6.bb"

meta-webos-backports/meta-webos-backports-5.1/dynamic-layers/raspberrypi/recipes-kernel/linux/files/android-drivers.cfg

@@ -0,0 +1,3 @@
+#CONFIG_ANDROID_BINDERFS is not set
+CONFIG_ANDROID_BINDER_IPC=y
+CONFIG_ANDROID_BINDER_DEVICES="binder"

meta-webos-backports/meta-webos-backports-5.1/dynamic-layers/raspberrypi/recipes-kernel/linux/files/default-cpu-governor.cfg

@@ -0,0 +1,9 @@
+# The defconfigs from the RPi Kernel set "powersave" as the default CPU governor.
+# That is a bad idea as it reduces performance, so we unset that default option here.
+# The option to build the powersave governor (but not as the default) is also enabled.
+# A fix for this was sent to upstream: https://github.com/raspberrypi/linux/pull/5666
+# However, we need to carry this option override until those defconfigs are fixed on
+# *all* the kernel branches that we support. So that can be a long time depending
+# on wheter the above PR gets accepted and/or backported to the stable branches.
+CONFIG_CPU_FREQ_DEFAULT_GOV_POWERSAVE=n
+CONFIG_CPU_FREQ_GOV_POWERSAVE=y

meta-webos-backports/meta-webos-backports-5.1/dynamic-layers/raspberrypi/recipes-kernel/linux/files/initramfs-image-bundle.cfg

@@ -0,0 +1,5 @@
+CONFIG_OVERLAY_FS=y
+CONFIG_SQUASHFS=y
+CONFIG_MTD=y
+CONFIG_MTD_UBI=y
+CONFIG_UBIFS_FS=y

meta-webos-backports/meta-webos-backports-5.1/dynamic-layers/raspberrypi/recipes-kernel/linux/files/powersave.cfg

@@ -0,0 +1,13 @@
+CONFIG_SUSPEND=y
+CONFIG_SUSPEND_FREEZER=y
+CONFIG_HIBERNATE_CALLBACKS=y
+CONFIG_HIBERNATION=y
+CONFIG_PM_STD_PARTITION="/dev/mmcblk0p2"
+CONFIG_PM_SLEEP=y
+CONFIG_PM_SLEEP_SMP=y
+CONFIG_PM_AUTOSLEEP=y
+CONFIG_PM_WAKELOCKS=y
+CONFIG_PM_WAKELOCKS_LIMIT=100
+CONFIG_PM_WAKELOCKS_GC=y
+CONFIG_PM_GENERIC_DOMAINS_SLEEP=y
+CONFIG_ARCH_HIBERNATION_HEADER=y

meta-webos-backports/meta-webos-backports-5.1/dynamic-layers/raspberrypi/recipes-kernel/linux/files/raspberrypi4/rpi4-nvmem.cfg

@@ -0,0 +1 @@
+CONFIG_NVMEM_RMEM=y

meta-webos-backports/meta-webos-backports-5.1/dynamic-layers/raspberrypi/recipes-kernel/linux/files/vc4graphics.cfg

@@ -0,0 +1,6 @@
+CONFIG_I2C_BCM2835=y
+CONFIG_DRM=y
+CONFIG_DRM_FBDEV_EMULATION=y
+CONFIG_DRM_VC4=y
+CONFIG_SND=y
+CONFIG_SND_SOC=y

meta-webos-backports/meta-webos-backports-5.1/dynamic-layers/raspberrypi/recipes-kernel/linux/files/wm8960.cfg

@@ -0,0 +1,2 @@
+CONFIG_I2C_BCM2835=y
+CONFIG_SND_SOC_WM8960=y

meta-webos-backports/meta-webos-backports-5.1/dynamic-layers/raspberrypi/recipes-kernel/linux/linux-raspberrypi.inc

@@ -0,0 +1,48 @@
+DESCRIPTION = "Linux Kernel for Raspberry Pi"
+SECTION = "kernel"
+LICENSE = "GPL-2.0-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
+
+COMPATIBLE_MACHINE ?= "^rpi$"
+
+PE = "1"
+PV = "${LINUX_VERSION}+git${SRCPV}"
+
+inherit siteinfo
+require recipes-kernel/linux/linux-yocto.inc
+
+SRC_URI += " \
+    ${@bb.utils.contains("INITRAMFS_IMAGE_BUNDLE", "1", "file://initramfs-image-bundle.cfg", "", d)} \
+    ${@bb.utils.contains("MACHINE_FEATURES", "vc4graphics", "file://vc4graphics.cfg", "", d)} \
+    ${@bb.utils.contains("MACHINE_FEATURES", "wm8960", "file://wm8960.cfg", "", d)} \
+    file://default-cpu-governor.cfg \
+    "
+
+SRC_URI:append:raspberrypi4 = " \
+    file://rpi4-nvmem.cfg \
+"
+
+KCONFIG_MODE = "--alldefconfig"
+KBUILD_DEFCONFIG:raspberrypi0-wifi ?= "bcmrpi_defconfig"
+KBUILD_DEFCONFIG:raspberrypi ?= "bcmrpi_defconfig"
+KBUILD_DEFCONFIG:raspberrypi-cm3 ?= "bcm2709_defconfig"
+KBUILD_DEFCONFIG:raspberrypi2 ?= "bcm2709_defconfig"
+KBUILD_DEFCONFIG:raspberrypi3 ?= "bcm2709_defconfig"
+KBUILD_DEFCONFIG:raspberrypi3-64 ?= "bcmrpi3_defconfig"
+KBUILD_DEFCONFIG:raspberrypi4 ?= "bcm2711_defconfig"
+KBUILD_DEFCONFIG:raspberrypi4-64 ?= "bcm2711_defconfig"
+KBUILD_DEFCONFIG:raspberrypi-armv7 ?= "bcm2711_defconfig"
+KBUILD_DEFCONFIG:raspberrypi-armv8 ?= "bcm2711_defconfig"
+KBUILD_DEFCONFIG:raspberrypi5 ?= "bcm2712_defconfig"
+
+LINUX_VERSION_EXTENSION ?= ""
+
+KERNEL_MODULE_AUTOLOAD += "${@bb.utils.contains("MACHINE_FEATURES", "pitft28r", "stmpe-ts", "", d)}"
+
+# A LOADADDR is needed when building a uImage format kernel. This value is not
+# set by default in rpi-4.8.y and later branches so we need to provide it
+# manually. This value unused if KERNEL_IMAGETYPE is not uImage.
+KERNEL_EXTRA_ARGS += "LOADADDR=${UBOOT_ENTRYPOINT}"
+
+UBOOT_ENTRYPOINT =       "0x00008000"
+UBOOT_LOADADDRESS =      "0x00008000"

meta-webos-backports/meta-webos-backports-5.1/dynamic-layers/raspberrypi/recipes-kernel/linux/linux-raspberrypi_6.1.bb

@@ -0,0 +1,31 @@
+LINUX_VERSION ?= "6.1.77"
+LINUX_RPI_BRANCH ?= "rpi-6.1.y"
+LINUX_RPI_KMETA_BRANCH ?= "yocto-6.1"
+
+SRCREV_machine = "77fc1fbcb5c013329af9583307dd1ff3cd4752aa"
+SRCREV_meta = "43d1723dbe0ce7b341cf32feeb35ecbe6b0ce29a"
+
+KMETA = "kernel-meta"
+
+SRC_URI = " \
+    git://github.com/raspberrypi/linux.git;name=machine;branch=${LINUX_RPI_BRANCH};protocol=https \
+    git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=${LINUX_RPI_KMETA_BRANCH};destsuffix=${KMETA} \
+    file://powersave.cfg \
+    file://android-drivers.cfg \
+    "
+
+require linux-raspberrypi.inc
+
+KERNEL_DTC_FLAGS += "-@ -H epapr"
+
+RDEPENDS:${KERNEL_PACKAGE_NAME}:raspberrypi-armv7:append = " ${RASPBERRYPI_v7_KERNEL_PACKAGE_NAME}"
+RDEPENDS:${KERNEL_PACKAGE_NAME}-base:raspberrypi-armv7:append = " ${RASPBERRYPI_v7_KERNEL_PACKAGE_NAME}-base"
+RDEPENDS:${KERNEL_PACKAGE_NAME}-image:raspberrypi-armv7:append = " ${RASPBERRYPI_v7_KERNEL_PACKAGE_NAME}-image"
+RDEPENDS:${KERNEL_PACKAGE_NAME}-dev:raspberrypi-armv7:append = " ${RASPBERRYPI_v7_KERNEL_PACKAGE_NAME}-dev"
+RDEPENDS:${KERNEL_PACKAGE_NAME}-vmlinux:raspberrypi-armv7:append = " ${RASPBERRYPI_v7_KERNEL_PACKAGE_NAME}-vmlinux"
+RDEPENDS:${KERNEL_PACKAGE_NAME}-modules:raspberrypi-armv7:append = " ${RASPBERRYPI_v7_KERNEL_PACKAGE_NAME}-modules"
+RDEPENDS:${KERNEL_PACKAGE_NAME}-dbg:raspberrypi-armv7:append = " ${RASPBERRYPI_v7_KERNEL_PACKAGE_NAME}-dbg"
+
+DEPLOYDEP = ""
+DEPLOYDEP:raspberrypi-armv7 = "${RASPBERRYPI_v7_KERNEL}:do_deploy"
+do_deploy[depends] += "${DEPLOYDEP}"

meta-webos-backports/meta-webos-backports-5.1/dynamic-layers/raspberrypi/recipes-kernel/linux/linux-raspberrypi_6.6.bb

@@ -0,0 +1,31 @@
+LINUX_VERSION ?= "6.6.36"
+LINUX_RPI_BRANCH ?= "rpi-6.6.y"
+LINUX_RPI_KMETA_BRANCH ?= "yocto-6.6"
+
+SRCREV_machine = "769634f344626ed73bcda14c91b567067974d7b2"
+SRCREV_meta = "733366844f5e114221372929392bf237fc8d823c"
+
+KMETA = "kernel-meta"
+
+SRC_URI = " \
+    git://github.com/raspberrypi/linux.git;name=machine;branch=${LINUX_RPI_BRANCH};protocol=https \
+    git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=${LINUX_RPI_KMETA_BRANCH};destsuffix=${KMETA} \
+    file://powersave.cfg \
+    file://android-drivers.cfg \
+    "
+
+require linux-raspberrypi.inc
+
+KERNEL_DTC_FLAGS += "-@ -H epapr"
+
+RDEPENDS:${KERNEL_PACKAGE_NAME}:raspberrypi-armv7:append = " ${RASPBERRYPI_v7_KERNEL_PACKAGE_NAME}"
+RDEPENDS:${KERNEL_PACKAGE_NAME}-base:raspberrypi-armv7:append = " ${RASPBERRYPI_v7_KERNEL_PACKAGE_NAME}-base"
+RDEPENDS:${KERNEL_PACKAGE_NAME}-image:raspberrypi-armv7:append = " ${RASPBERRYPI_v7_KERNEL_PACKAGE_NAME}-image"
+RDEPENDS:${KERNEL_PACKAGE_NAME}-dev:raspberrypi-armv7:append = " ${RASPBERRYPI_v7_KERNEL_PACKAGE_NAME}-dev"
+RDEPENDS:${KERNEL_PACKAGE_NAME}-vmlinux:raspberrypi-armv7:append = " ${RASPBERRYPI_v7_KERNEL_PACKAGE_NAME}-vmlinux"
+RDEPENDS:${KERNEL_PACKAGE_NAME}-modules:raspberrypi-armv7:append = " ${RASPBERRYPI_v7_KERNEL_PACKAGE_NAME}-modules"
+RDEPENDS:${KERNEL_PACKAGE_NAME}-dbg:raspberrypi-armv7:append = " ${RASPBERRYPI_v7_KERNEL_PACKAGE_NAME}-dbg"
+
+DEPLOYDEP = ""
+DEPLOYDEP:raspberrypi-armv7 = "${RASPBERRYPI_v7_KERNEL}:do_deploy"
+do_deploy[depends] += "${DEPLOYDEP}"