Add flake.parts module

examples/simple-flake-parts/flake.nix

@@ -0,0 +1,30 @@
+# SPDX-FileCopyrightText: 2024 Sefa Eyeoglu <[email protected]>
+#
+# SPDX-License-Identifier: MPL-2.0
+
+{
+  description = "Deploy GNU hello to localhost";
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
+    flake-parts.url = "github:hercules-ci/flake-parts";
+    deploy-rs.url = "github:serokell/deploy-rs";
+  };
+
+  outputs = inputs@{ flake-parts, ... }:
+    flake-parts.lib.mkFlake { inherit inputs; } {
+      imports = [inputs.deploy-rs.flakeModule];
+
+      flake.deploy.nodes.example = {
+        hostname = "localhost";
+        profiles.hello = {
+          user = "balsoft";
+          path = inputs.deploy-rs.lib.x86_64-linux.setActivate inputs.nixpkgs.legacyPackages.x86_64-linux.hello "./bin/hello";
+        };
+      };
+      systems = [
+        # systems for which you want to build the `perSystem` attributes
+        "x86_64-linux"
+      ];
+    };
+}

flake.nix

@@ -13,10 +13,13 @@
       url = "github:edolstra/flake-compat";
       flake = false;
     };
+    flake-parts.url = "github:hercules-ci/flake-parts";
   };
 
   outputs = { self, nixpkgs, utils, ... }@inputs:
   rec {
+    flakeModule = ./nix/flake-module.nix;
+
     overlay = final: prev: let
       system = final.stdenv.hostPlatform.system;
       darwinOptions = final.lib.optionalAttrs final.stdenv.isDarwin {

nix/flake-module.nix

@@ -0,0 +1,115 @@
+# SPDX-FileCopyrightText: 2024 Sefa Eyeoglu <[email protected]>
+#
+# SPDX-License-Identifier: MPL-2.0
+
+{config, inputs, lib, ...}: let
+  inherit (lib) mkOption types;
+  inherit (inputs) deploy-rs;
+
+  cfg = config.flake.deploy;
+
+  genericSettings = {
+    options = {
+      sshUser = mkOption {
+        type = with types; nullOr str;
+        default = null;
+      };
+      user = mkOption {
+        type = with types; nullOr str;
+        default = null;
+      };
+      sshOpts = mkOption {
+        type = with types; listOf str;
+        default = [];
+      };
+      fastConnection = mkOption {
+        type = with types; nullOr bool;
+        default = null;
+      };
+      autoRollback = mkOption {
+        type = with types; nullOr bool;
+        default = null;
+      };
+      confirmTimeout = mkOption {
+        type = with types; nullOr int;
+        default = null;
+      };
+      activationTimeout = mkOption {
+        type = with types; nullOr int;
+        default = null;
+      };
+      tempPath = mkOption {
+        type = with types; nullOr str;
+        default = null;
+      };
+      magicRollback = mkOption {
+        type = with types; nullOr bool;
+        default = null;
+      };
+      sudo = mkOption {
+        type = with types; nullOr str;
+        default = null;
+      };
+      remoteBuild = mkOption {
+        type = with types; nullOr bool;
+        default = null;
+      };
+      interactiveSudo = mkOption {
+        type = with types; nullOr bool;
+        default = null;
+      };
+    };
+  };
+  profileSettings = {
+    options = {
+      path = mkOption {
+        type = types.package;
+      };
+      profilePath = mkOption {
+        type = with types; nullOr str;
+        default = null;
+      };
+    };
+  };
+  nodeSettings = {
+    options = {
+      hostname = mkOption {
+        type = types.str;
+      };
+      profilesOrder = mkOption {
+        type = with types; listOf str;
+        default = [];
+      };
+      profiles = mkOption {
+        type = types.attrsOf profileModule;
+      };
+    };
+  };
+
+  nodesSettings = {
+    options.nodes = mkOption {
+      type = types.attrsOf nodeModule;
+    };
+  };
+
+  profileModule = types.submoduleWith {
+    modules = [genericSettings profileSettings];
+  };
+
+  nodeModule = types.submoduleWith {
+    modules = [genericSettings nodeSettings];
+  };
+
+  rootModule = types.submoduleWith {
+    modules = [genericSettings nodesSettings];
+  };
+in {
+  options.flake.deploy = mkOption {
+    type = rootModule;
+  };
+  config = {
+    perSystem = {system, ...}: {
+      checks = lib.mkIf (deploy-rs.lib ? ${system}) (deploy-rs.lib.${system}.deployChecks cfg);
+    };
+  };
+}