Merge pull request #14 from onflow/improvement/create-fund

Add create account with funding template

main.go

@@ -11,6 +11,9 @@ var AddContract string
 //go:embed templates/cadence/create-account.cdc
 var CreateAccount string
 
+//go:embed templates/cadence/create-and-fund-account.cdc
+var CreateAccountFunding string
+
 //go:embed templates/cadence/revoke-account-key.cdc
 var RemoveAccountKey string
 

templates/cadence/create-and-fund-account.cdc

@@ -0,0 +1,36 @@
+import Crypto
+import "FlowToken"
+import "FungibleToken"
+
+transaction(publicKeys: [Crypto.KeyListEntry], contracts: {String: String}, fundAmount: UFix64) {
+    let tokenReceiver: &{FungibleToken.Receiver}
+    let sentVault: @FungibleToken.Vault
+
+	prepare(signer: AuthAccount) {
+		let account = AuthAccount(payer: signer)
+
+		// add all the keys to the account
+		for key in publicKeys {
+			account.keys.add(publicKey: key.publicKey, hashAlgorithm: key.hashAlgorithm, weight: key.weight)
+		}
+
+		// add contracts if provided
+		for contract in contracts.keys {
+			account.contracts.add(name: contract, code: contracts[contract]!.decodeHex())
+		}
+
+		self.tokenReceiver = account
+          .getCapability(/public/flowTokenReceiver)!
+          .borrow<&{FungibleToken.Receiver}>()
+          ?? panic("Unable to borrow receiver reference")
+
+        let vaultRef = signer.borrow<&FlowToken.Vault>(from: /storage/flowTokenVault)
+            ?? panic("Could not borrow reference to the owner's Vault!")
+
+        self.sentVault <- vaultRef.withdraw(amount: fundAmount)
+	}
+
+	execute {
+	    self.tokenReceiver.deposit(from: <-self.sentVault)
+	}
+}