Bring NMODL transpiler under NEURON project

cmake/nmodl/ClangTidyHelper.cmake

@@ -0,0 +1,20 @@
+set(ENABLE_CLANG_TIDY
+    OFF
+    CACHE BOOL "Add clang-tidy automatically to builds")
+if(ENABLE_CLANG_TIDY)
+  find_program(CLANG_TIDY_EXE NAMES "clang-tidy")
+  if(CLANG_TIDY_EXE)
+    message(STATUS "clang-tidy found: ${CLANG_TIDY_EXE}")
+    set(CLANG_TIDY_CHECKS
+        "-*,modernize-*,readability-*,performance-*,cppcoreguidelines-*,clang-analyzer-core*,google-*"
+    )
+    set(CMAKE_CXX_CLANG_TIDY
+        "${CLANG_TIDY_EXE};-checks=${CLANG_TIDY_CHECKS};-fix;-header-filter='${CMAKE_SOURCE_DIR}/*'"
+        CACHE STRING "" FORCE)
+  else()
+    message(AUTHOR_WARNING "clang-tidy not found!")
+    set(CMAKE_CXX_CLANG_TIDY
+        ""
+        CACHE STRING "" FORCE) # delete it
+  endif()
+endif()

cmake/nmodl/CompilerHelper.cmake

@@ -0,0 +1,54 @@
+if(CMAKE_CXX_COMPILER_ID MATCHES "PGI" OR CMAKE_CXX_COMPILER_ID MATCHES "NVHPC")
+  set(NMODL_PGI_COMPILER TRUE)
+
+  # CMake adds standard complaint PGI flag "-A" which breaks compilation of of spdlog and fmt
+  set(CMAKE_CXX14_STANDARD_COMPILE_OPTION --c++14)
+
+  # Avoid errors related to "excessive recursion at instantiation of function ...", Eigen-related
+  # (in accelerated regions), e.g., transposeInPlace()
+  list(APPEND NMODL_EXTRA_CXX_FLAGS "-Wc,--pending_instantiations=0")
+
+  # ~~~
+  # PGI enables number of diagnostic messages by default classes which results into thousands of
+  # messages specifically for AST. Disable these verbose warnings for now.
+  # TODO : fix these warnings from template modification (#272)
+  # ~~~
+  if(${CMAKE_CXX_COMPILER_VERSION} VERSION_LESS 20.7)
+    set(NMODL_COMPILER_WARNING_SUPPRESSIONS --diag_suppress=1,82,111,115,177,186,611,997,1097,1625)
+  else()
+    # https://forums.developer.nvidia.com/t/many-all-diagnostic-numbers-increased-by-1-from-previous-values/146268/3
+    # changed the numbering scheme in newer versions. The following list is from a clean start 13
+    # August 2021. It would clearly be nicer to apply these suppressions only to relevant files.
+    # Examples of the suppressed warnings are given below.
+    # ~~~
+    # "ext/spdlog/include/spdlog/fmt/fmt.h", warning #1-D: last line of file ends without a newline
+    # "ext/fmt/include/fmt/format.h", warning #111-D: statement is unreachable
+    # "ext/fmt/include/fmt/format.h", warning #128-D: loop is not reachable
+    # "ext/spdlog/include/spdlog/fmt/bundled/format.h", warning #185-D: dynamic initialization in unreachable code
+    # "ext/json/json.hpp", warning #186-D: pointless comparison of unsigned integer with zero
+    # "src/ast/all.hpp", warning #998-D: function "..." is hidden by "..." -- virtual function override intended?
+    # "ext/spdlog/include/spdlog/fmt/bundled/format.h", warning #1098-D: unknown attribute "fallthrough"
+    # "ext/pybind11/include/pybind11/detail/common.h", warning #1626-D: routine is both "inline" and "noinline"
+    # "ext/spdlog/include/spdlog/fmt/bundled/core.h", warning #1676-D: unrecognized GCC pragma
+    # ~~~
+    # The following warnings do not seem to be suppressible with --diag_suppress:
+    # ~~~
+    # "src/codegen/codegen_cuda_visitor.cpp", NVC++-W-0277-Cannot inline function - data type mismatch
+    # "nvc++IkWUbMugiSgNH.s: Warning: stand-alone `data16' prefix
+    # ~~~
+    # The situation may be better once https://github.com/fmtlib/fmt/pull/2582 is included in a
+    # release.
+    set(NMODL_COMPILER_WARNING_SUPPRESSIONS --diag_suppress=1,111,128,185,186,998,1098,1626,1676)
+    # There are a few more warnings produced by the unit test infrastructure.
+    # ~~~
+    # "test/unit/visitor/constant_folder.cpp", warning #177-D: variable "..." was declared but never referenced
+    # ~~~
+    set(NMODL_TESTS_COMPILER_WARNING_SUPPRESSIONS --diag_suppress=177)
+  endif()
+endif()
+
+if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
+  set(NMODL_COMPILER_MAX_ERRORS_FLAG -fmax-errors=${NMODL_MAX_ERRORS})
+elseif(CMAKE_CXX_COMPILER_ID MATCHES "Clang")
+  set(NMODL_COMPILER_MAX_ERRORS_FLAG -ferror-limit=${NMODL_MAX_ERRORS})
+endif()

cmake/nmodl/Config.cmake.in

@@ -0,0 +1,7 @@
+@PACKAGE_INIT@
+
+include("${CMAKE_CURRENT_LIST_DIR}/nmodlTargets.cmake")
+
+set(nmodl_BINARY ${PACKAGE_PREFIX_DIR}/@nmodl_BINARY@)
+
+check_required_components(nmodl)

cmake/nmodl/ExternalProjectHelper.cmake

@@ -0,0 +1,12 @@
+find_package(Git QUIET)
+
+# initialize submodule with given path
+function(initialize_submodule path)
+  if(NOT ${GIT_FOUND})
+    message(
+      FATAL_ERROR "git not found and ${path} sub-module not cloned (use git clone --recursive)")
+  endif()
+  message(STATUS "Sub-module : missing ${path}: running git submodule update --init")
+  execute_process(COMMAND git submodule update --init -- ${path}
+                  WORKING_DIRECTORY ${NMODL_PROJECT_SOURCE_DIR})
+endfunction()

cmake/nmodl/FlexHelper.cmake

@@ -0,0 +1,17 @@
+# Often older version of flex is available in /usr. Even we set PATH for newer flex, CMake will set
+# FLEX_INCLUDE_DIRS to /usr/include. This will result in compilation errors. Hence we check for flex
+# include directory for the corresponding FLEX_EXECUTABLE. If found, we add that first and then we
+# include include path from CMake.
+
+get_filename_component(FLEX_BIN_DIR ${FLEX_EXECUTABLE} DIRECTORY)
+
+if(NOT FLEX_BIN_DIR MATCHES "/usr/bin")
+  if(NOT FLEX_INCLUDE_PATH)
+    get_filename_component(FLEX_INCLUDE_PATH ${FLEX_BIN_DIR} PATH)
+    set(FLEX_INCLUDE_PATH ${FLEX_INCLUDE_PATH}/include/)
+  endif()
+  if(EXISTS "${FLEX_INCLUDE_PATH}/FlexLexer.h")
+    message(STATUS " Adding Flex include path as : ${FLEX_INCLUDE_PATH}")
+    include_directories(${FLEX_INCLUDE_PATH})
+  endif()
+endif()

cmake/nmodl/GitRevision.cmake

@@ -0,0 +1,49 @@
+# For now use simple approach to get version information as git is always avaialble on the machine
+# where we are building
+
+find_package(Git)
+
+if(GIT_FOUND)
+
+  # get last commit sha1
+  execute_process(
+    COMMAND ${GIT_EXECUTABLE} log -1 --format=%h
+    WORKING_DIRECTORY ${NMODL_PROJECT_SOURCE_DIR}
+    OUTPUT_VARIABLE NMODL_GIT_REVISION_SHA1
+    RESULT_VARIABLE NMODL_GIT_STATUS
+    ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE)
+  if(NOT NMODL_GIT_STATUS EQUAL 0)
+    set(NMODL_GIT_REVISION_SHA1 "git-error")
+  endif()
+
+  # get last commit date
+  execute_process(
+    COMMAND ${GIT_EXECUTABLE} show -s --format=%ci
+    WORKING_DIRECTORY ${NMODL_PROJECT_SOURCE_DIR}
+    OUTPUT_VARIABLE NMODL_GIT_REVISION_DATE
+    RESULT_VARIABLE NMODL_GIT_STATUS
+    ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE)
+  if(NOT NMODL_GIT_STATUS EQUAL 0)
+    set(NMODL_GIT_REVISION_SHA1 "git-error")
+  endif()
+
+  # remove extra double quotes
+  string(REGEX REPLACE "\"" "" NMODL_GIT_REVISION_DATE "${NMODL_GIT_REVISION_DATE}")
+  set(NMODL_GIT_REVISION "${NMODL_GIT_REVISION_SHA1} ${NMODL_GIT_REVISION_DATE}")
+
+  # get the last version tag from git
+  execute_process(
+    COMMAND ${GIT_EXECUTABLE} describe --abbrev=0 --tags
+    WORKING_DIRECTORY ${NMODL_PROJECT_SOURCE_DIR}
+    OUTPUT_VARIABLE NMODL_GIT_LAST_TAG
+    RESULT_VARIABLE NMODL_GIT_STATUS
+    ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE)
+  if(NOT NMODL_GIT_STATUS EQUAL 0)
+    # Must be a valid version from CMake's perspective.
+    set(NMODL_GIT_LAST_TAG "0.0")
+  endif()
+else()
+  set(NMODL_GIT_REVISION "unknown")
+  # Must be a valid version from CMake's perspective.
+  set(NMODL_GIT_LAST_TAG "0.0")
+endif()

cmake/nmodl/PythonLinkHelper.cmake

@@ -0,0 +1,30 @@
+# =============================================================================
+# Support for building NMODL without python library
+# =============================================================================
+# ~~~
+# When NMODL is built under environment  (e.g. manylinux) without python-dev
+# package i.e. libpython.so, we have to build extension and binaries by
+# ignoring undefned symbols. The python library will be loaded later on target
+# system.
+# ~~~
+
+# use same variable name as NEURON as it won't be user option
+set(LINK_AGAINST_PYTHON
+    TRUE
+    CACHE BOOL "Disable linking to python library")
+
+mark_as_advanced(LINK_AGAINST_PYTHON)
+
+# Flags for ignoring undefined symbols for wheel
+if(CMAKE_CXX_COMPILER_ID MATCHES "Clang")
+  set(UNDEFINED_SYMBOLS_IGNORE_FLAG "-Wl,-undefined,dynamic_lookup")
+else()
+  set(UNDEFINED_SYMBOLS_IGNORE_FLAG "-Wl,--unresolved-symbols=ignore-all")
+endif()
+
+if(NOT LINK_AGAINST_PYTHON)
+  string(APPEND CMAKE_EXE_LINKER_FLAGS " ${UNDEFINED_SYMBOLS_IGNORE_FLAG}")
+  set(NMODL_WRAPPER_LIBS pyembed dl)
+else()
+  set(NMODL_WRAPPER_LIBS pyembed pywrapper dl)
+endif()

cmake/nmodl/RpathHelper.cmake

@@ -0,0 +1,25 @@
+# Copyright 2023 Blue Brain Project, EPFL. See the top-level LICENSE file for details.
+#
+# SPDX-License-Identifier: Apache-2.0
+
+# =============================================================================
+# Set full RPATHs in build-tree, also set RPATHs in install for non-system libs
+# =============================================================================
+
+# use, i.e. don't skip the full RPATH for the build tree
+set(CMAKE_SKIP_BUILD_RPATH FALSE)
+
+# when building, don't use the install RPATH already (but later on when installing)
+set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
+
+set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
+
+# add the automatically determined parts of the RPATH which point to directories outside the build
+# tree to the install RPATH
+set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
+
+# the RPATH to be used when installing, but only if it's not a system directory
+list(FIND CMAKE_PLATFORM_IMPLICIT_LINK_DIRECTORIES "${CMAKE_INSTALL_PREFIX}/lib" isSystemDir)
+if("${isSystemDir}" STREQUAL "-1")
+  set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
+endif("${isSystemDir}" STREQUAL "-1")