[bazel] Add bazel rules for manual tests

Signed-off-by: Alphan Ulusoy <[email protected]>

rules/opentitan_test.bzl

@@ -518,3 +518,42 @@ def opentitan_functest(
             # For more see https://bazel.build/reference/be/general#test_suite.tags
         ],
     )
+
+def _manual_test_impl(ctx):
+    executable = ctx.actions.declare_file("manual_test_wrapper")
+    ctx.actions.write(
+        output = executable,
+        content = "{runner} {testplan}".format(
+            runner = ctx.executable._runner.short_path,
+            testplan = ctx.file.testplan.short_path,
+        ),
+    )
+    return [
+        DefaultInfo(
+            runfiles = ctx.runfiles(
+                files = [
+                    ctx.executable._runner,
+                    ctx.file.testplan,
+                ],
+            ).merge(ctx.attr._runner[DefaultInfo].default_runfiles),
+            executable = executable,
+        ),
+    ]
+
+manual_test = rule(
+    _manual_test_impl,
+    attrs = {
+        "testplan": attr.label(
+            allow_single_file = [".hjson"],
+            doc = "Testplan with manual testpoints",
+            mandatory = True,
+        ),
+        "_runner": attr.label(
+            default = "//util:run_manual_tests",
+            executable = True,
+            cfg = "exec",
+        ),
+    },
+    doc = "Walks through the manual testpoints in a testplan",
+    test = True,
+)

sw/device/silicon_creator/rom/BUILD

@@ -7,6 +7,7 @@ load("//rules:exclude_files.bzl", "exclude_files")
 load("//rules:linker.bzl", "ld_library")
 load(
     "//rules:opentitan_test.bzl",
+    "manual_test",
     "opentitan_functest",
 )
 load("//rules:cross_platform.bzl", "dual_cc_library", "dual_inputs")
@@ -318,3 +319,12 @@ pkg_files(
     srcs = [":pre_package"],
     prefix = "earlgrey/rom",
 )
+
+manual_test(
+    name = "manual_test",
+    tags = [
+        "manual",
+        "no-cache",
+    ],
+    testplan = "//sw/device/silicon_creator/rom/data:rom_manual_testplan.hjson",
+)

sw/device/silicon_creator/rom/data/BUILD

@@ -0,0 +1,10 @@
+# Copyright lowRISC contributors.
+# Licensed under the Apache License, Version 2.0, see LICENSE for details.
+# SPDX-License-Identifier: Apache-2.0
+
+package(default_visibility = ["//visibility:public"])
+
+exports_files([
+    "rom_e2e_testplan.hjson",
+    "rom_manual_testplan.hjson",
+])

util/BUILD

@@ -65,3 +65,16 @@ py_test(
         "generate_compilation_db_test.py",
     ],
 )
+
+py_binary(
+    name = "run_manual_tests",
+    srcs = [
+        "run_manual_tests.py",
+    ],
+    deps = [
+        requirement("typer"),
+        requirement("hjson"),
+        requirement("rich"),
+        requirement("pluralizer"),
+    ],
+)