Add binary-puzzle exercise

config.json

@@ -909,6 +909,14 @@
         "practices": [],
         "prerequisites": [],
         "difficulty": 1
+      },
+      {
+        "slug": "binary-puzzle",
+        "name": "Binary Puzzle",
+        "uuid": "3b24f261-3916-4bbf-a52f-5758173ad83e",
+        "practices": [],
+        "prerequisites": [],
+        "difficulty": 1
       }
     ],
     "foregone": [

exercises/practice/binary-puzzle/.docs/instructions.md

@@ -0,0 +1,21 @@
+# Instruction
+
+Your task is to solve a binary puzzle.
+Every binary puzzle has exactly _one_ solution, which can be found by applying these rules:
+
+1. Every cell must contain either a zero or a one.
+2. More than two of the same digits can't be adjacent. Thus, if two adjacents cells contain the same digit, the cells next to the digits must contain the other digit.
+3. Each row and each column must contain an equal number of zeros and ones.
+4. Each row and column is unique.
+
+You'll get passed in an uncompleted puzzle as rows of zeros and ones, with placeholders (`_`) for the unknown values.
+The goal is to define the rules for the binary puzzle, which will let the tests figure out the values for the placeholders (you don't do that yourselves).
+Your implementation must useProlog's [Constraint Logic Programming over Finite Domains (CLP(FD))](https://www.swi-prolog.org/man/clpfd.html), which is perfect for these types of tasks.
+
+````exercism/note
+To help you get started, the stub file already includes the [`clpfd` library](https://www.swi-prolog.org/man/clpfd.html) via:
+
+```prolog
+:- use_module(library(clpfd)).
+```
+````

exercises/practice/binary-puzzle/.docs/introduction.md

@@ -0,0 +1,6 @@
+# Introduction
+
+Your grandma has recently taken a keen interest in solving binary puzzles.
+Whilst she's becoming better at it, she does get stuck fairly regularly.
+Being the helpful grandchild you are, you decide to build a small application that can solve any binary puzzle.
+This will allow you to give your grandma hints for her next move.

exercises/practice/binary-puzzle/.meta/binary_puzzle.example.pl

@@ -0,0 +1,28 @@
+:- use_module(library(clpfd)).
+
+binary_puzzle(Rows) :-
+    length(Rows, Dimension),
+    transpose(Rows, Cols),
+    maplist(same_length(Rows), Rows),
+    maplist(max_two_identical_consecutive_numbers, Rows),
+    maplist(max_two_identical_consecutive_numbers, Cols),    
+    maplist(binary_digits, Cols, ColsAsIntegers),
+    maplist(binary_digits, Rows, RowsAsIntegers),
+    all_different(RowsAsIntegers),
+    all_different(ColsAsIntegers),
+    Half #= Dimension // 2,
+    maplist(zeros_and_ones_have_same_count(Half), Rows),
+    maplist(zeros_and_ones_have_same_count(Half), Cols).
+
+binary_digits(Digits, Decimal) :- 
+    Digits ins 0..1,
+    foldl([Digit,Acc,NewAcc]>>(NewAcc #= Acc << 1 + Digit), Digits, 0, Decimal).
+
+zeros_and_ones_have_same_count(Count, Digits) :-
+    global_cardinality(Digits, [0-Count, 1-Count]).
+
+max_two_identical_consecutive_numbers([_, _]).
+max_two_identical_consecutive_numbers([X, Y, Z | Rest]) :-
+    X #= Y #==> Y #\= Z,
+    Y #= Z #==> X #\= Z,
+    max_two_identical_consecutive_numbers([Y, Z | Rest]).

exercises/practice/binary-puzzle/.meta/config.json

@@ -0,0 +1,17 @@
+{
+  "authors": [
+    "erikschierboom"
+  ],
+  "files": {
+    "solution": [
+      "binary_puzzle.pl"
+    ],
+    "test": [
+      "binary_puzzle_tests.plt"
+    ],
+    "example": [
+      ".meta/binary_puzzle.example.pl"
+    ]
+  },
+  "blurb": "Solve a binary puzzle"
+}

exercises/practice/binary-puzzle/binary_puzzle.pl

@@ -0,0 +1,3 @@
+:- use_module(library(clpfd)).
+
+binary_puzzle(Rows).

exercises/practice/binary-puzzle/binary_puzzle_tests.plt

@@ -0,0 +1,83 @@
+pending :-
+    current_prolog_flag(argv, ['--all'|_]).
+pending :-
+    write('\nA TEST IS PENDING!\n'),
+    fail.
+
+:- begin_tests(binary_puzzle).
+
+    test(puzzle_4x4, condition(true)) :-
+        Rows = 
+            [
+                [_, 1, _, 0],
+                [_, _, 0, 1],
+                [_, 0, _, _],
+                [1, 1, _, 0]
+            ],
+        binary_puzzle(Rows),
+        maplist(label, Rows),
+        Rows == 
+            [
+                [0, 1, 1, 0],
+                [1, 0, 0, 1],
+                [0, 0, 1, 1],
+                [1, 1, 0, 0]
+            ].
+
+    test(puzzle_6x6, condition(pending)) :-
+        Rows = 
+            [
+                [1, _, _, 0, _, _],
+                [_, _, 0, 0, _, 1],
+                [_, 0, 0, _, _, 1],
+                [_, _, _, _, _, _],
+                [0, 0, _, 1, _, _],
+                [_, 1, _, _, 0, 0]
+            ],
+        binary_puzzle(Rows),
+        maplist(label, Rows),
+        Rows == 
+            [
+                [1, 0, 1, 0, 1, 0],
+                [0, 1, 0, 0, 1, 1],
+                [1, 0, 0, 1, 0, 1],
+                [0, 1, 1, 0, 1, 0],
+                [0, 0, 1, 1, 0, 1],
+                [1, 1, 0, 1, 0, 0]
+            ].
+
+    test(puzzle_12x12, condition(pending)) :-
+        Rows = 
+            [
+                [_, _, 1, _, _, _, _, 0, _, _, 0, _],
+                [_, _, _, 1, _, 0, _, _, 1, _, _, 1],
+                [_, _, 0, _, 0, _, _, _, _, 0, _, 1],
+                [1, _, 0, _, _, _, 0, 0, _, _, _, _],
+                [_, 1, _, _, _, _, _, _, _, _, _, 1],
+                [_, _, _, _, 1, _, _, _, _, 0, _, _],
+                [_, _, _, _, _, _, 1, _, 0, 0, _, _],
+                [_, _, 0, _, _, _, _, 1, _, _, 1, _],
+                [1, _, 0, 0, _, _, _, _, _, 0, _, _],
+                [_, _, _, _, _, 1, _, _, _, 0, _, 0],
+                [_, 0, _, _, _, _, 0, _, _, _, 1, _],
+                [0, 0, _, 1, _, 1, _, 1, _, 1, _, _]
+            ],
+        binary_puzzle(Rows),
+        maplist(label, Rows),
+        Rows == 
+            [
+                [0, 1, 1, 0, 1, 1, 0, 0, 1, 1, 0, 0],
+                [0, 0, 1, 1, 0, 0, 1, 0, 1, 1, 0, 1],
+                [1, 0, 0, 1, 0, 0, 1, 1, 0, 0, 1, 1],
+                [1, 1, 0, 0, 1, 1, 0, 0, 1, 0, 1, 0],
+                [0, 1, 1, 0, 0, 1, 0, 1, 0, 1, 0, 1],
+                [1, 0, 0, 1, 1, 0, 1, 0, 1, 0, 0, 1],
+                [0, 1, 1, 0, 1, 0, 1, 1, 0, 0, 1, 0],
+                [1, 0, 0, 1, 0, 1, 0, 1, 0, 1, 1, 0],
+                [1, 1, 0, 0, 1, 0, 1, 0, 1, 0, 0, 1],
+                [0, 1, 1, 0, 0, 1, 1, 0, 1, 0, 1, 0],
+                [1, 0, 0, 1, 1, 0, 0, 1, 0, 1, 1, 0],
+                [0, 0, 1, 1, 0, 1, 0, 1, 0, 1, 0, 1]
+            ].
+
+:- end_tests(binary_puzzle).