Added in Rubella, Mumps, and DTP antigens

input/cql/IMMZCommon.cql

@@ -147,15 +147,30 @@ define "Doses Administered to Patient":
 /**
  * Contraindications 
  */
+define "Planning to get pregnant in the next month Condition":
+  [Condition: IMMZc."Planning to get pregnant in the next month"]
+
 define "Severely Immunosuppressed Condition":
   [Condition: IMMZc."Severely immunosuppressed"]
 
+define "Exposed to immunosuppressive treatment Condition":
+  [Condition: IMMZc."Exposed to immunosuppressive treatment"]
+
+define "Receiving blood products Condition":
+  [Condition: IMMZc."Receiving blood products"]
+
+define "TB disease Condition":
+  [Condition: IMMZc."TB disease"]
+
 define "History of Anaphylactic Reactions Condition":
   [Condition: IMMZc."History of anaphylactic reactions"]
 
 define "Severe Allergic Reactions Condition":
   [Condition: IMMZc."Severe allergic reactions"]
 
+define "Severe Acute Illness Condition":
+  [Condition: IMMZc."Severe acute illness" ]
+
 define "Symptomatic HIV Infection Condition":
   [Condition: IMMZc."Symptomatic HIV infection"]
 

input/cql/IMMZConcepts.cql

@@ -40,9 +40,15 @@ valueset "ARV Drugs": 'http://smart.who.int/ig/smart-immunizations/ValueSet/ARVD
 valueset "MCV Vaccine": 'http://smart.who.int/ig/smart-immunizations/ValueSet/IMMZ.Z.DE9'
 valueset "Yellow Fever Vaccine": 'http://smart.who.int/ig/smart-immunizations/ValueSet/IMMZ.Z.DE23'
 valueset "Polio Vaccine": 'http://smart.who.int/ig/smart-immunizations/ValueSet/IMMZ.Z.DE14'
-valueset "Polio Vaccine - bOPV": 'http://smart.who.int/ig/smart-immunizations/ValueSet/IMMZ.Z.DE14.bOPV'
-valueset "Polio Vaccine - IPV": 'http://smart.who.int/ig/smart-immunizations/ValueSet/IMMZ.Z.DE14.IPV'
+valueset "Polio Vaccine - bOPV": 'http://smart.who.int/ig/smart-immunizations/ValueSet/IMMZ.Z.DE30'
+valueset "Polio Vaccine - IPV": 'http://smart.who.int/ig/smart-immunizations/ValueSet/IMMZ.Z.DE31'
 valueset "Hepatitis B Vaccine": 'http://smart.who.int/ig/smart-immunizations/ValueSet/IMMZ.Z.DE6'
+valueset "DTP Vaccine": 'http://smart.who.int/ig/smart-immunizations/ValueSet/IMMZ.Z.DE24'
+valueset "Tetanus and Diphtheria Vaccine": 'http://smart.who.int/ig/smart-immunizations/ValueSet/IMMZ.Z.DE28'
+valueset "Pertussis Vaccine": 'http://smart.who.int/ig/smart-immunizations/ValueSet/IMMZ.Z.DE12'
+valueset "Rubella Vaccine": 'http://smart.who.int/ig/smart-immunizations/ValueSet/IMMZ.Z.DE17'
+valueset "Measles and Rubella Vaccine": 'http://smart.who.int/ig/smart-immunizations/ValueSet/IMMZ.Z.DE32'
+valueset "Mumps Vaccine": 'http://smart.who.int/ig/smart-immunizations/ValueSet/IMMZ.Z.DE11'
 
 
 /*
@@ -59,10 +65,15 @@ code "Adverse Event Severity": '246112005' from "SNOMED-CT" display 'Severity (a
 code "Adverse Event Manifestation": '246112005' from "SNOMED-CT" display 'Severity (attribute)'
 
 code "Currently Pregnant": 'DE162' from "IMMZ.D" display 'Currently Pregnant'
-code "Severely immunosuppressed": 'DE165' from "IMMZ.D" display 'Severely immunosuppressed' 
+code "Planning to get pregnant in the next month": 'DE169' from "IMMZ.D" display 'Planning to get pregnant in the next month'
+code "Receiving blood products": 'DE170' from "IMMZ.D" display 'Receiving blood products'
+code "Severely immunosuppressed": 'DE165' from "IMMZ.D" display 'Severely immunosuppressed'
+code "Exposed to immunosuppressive treatment": 'DE164' from "IMMZ.D" display 'Exposed to immunosuppressive treatment'
 code "History of anaphylactic reactions": 'DE166' from "IMMZ.D" display 'History of anaphylactic reactions'
 code "Severe allergic reactions": 'DE167' from "IMMZ.D" display 'Severe allergic reactions'
 code "Symptomatic HIV infection": 'DE168' from "IMMZ.D" display 'Symptomatic HIV infection'
+code "TB disease": 'DE190' from "IMMZ.D" display 'TB disease'
 code "Immunodeficiency syndromes": 'DE187' from "IMMZ.D" display 'Immunodeficiency syndromes'
 code "Severely immunocompromised": 'DE200' from "IMMZ.D" display 'Severely immunocompromised'
 code "Breastfeeding": 'DE191' from "IMMZ.D" display 'Breastfeeding'
+code "Severe acute illness": 'DE188' from "IMMZ.D" display 'Severe acute illness'

input/cql/IMMZD2DTDTPInput.cql

@@ -0,0 +1,318 @@
+/*
+ * Library: IMMZD2DTDTPInput (IMMZ.D2.DT.DTPInput)					
+ */
+library IMMZD2DTDTPInput
+// Start Skeleton CQL
+using FHIR version '4.0.1'
+include FHIRHelpers version '4.0.1'
+include IMMZCommon called IMMZCom
+include IMMZConcepts called IMMZc
+include IMMZConfig called IMMZCon
+include IMMZVaccineLibrary called IMMZvl
+include FHIRCommon called FC
+
+// End Skeleton CQL
+context Patient
+
+
+/*
+@internal: DTP containing Doses Administered to Patient
+*/
+define "DTP Doses Administered to Patient":
+  IMMZCom."Doses Administered to Patient" I
+  where
+    I.vaccineCode in IMMZc."DTP Vaccine"
+
+/*
+@internal: Date of latest DTP Vaccine
+*/
+define "Date of latest DTP Vaccine":
+	First("DTP Doses Administered to Patient").occurrence as dateTime
+
+/*
+@internal: Tetanus and Diphtheria containing Doses Administered to Patient
+*/
+define "Tetanus and Diphtheria containing Doses Administered to Patient":
+  IMMZCom."Doses Administered to Patient" I where I.vaccineCode in IMMZc."Tetanus and Diphtheria Vaccine"
+
+/*
+@internal: Tetanus and Diphtheria containing Booster Doses Administered to Patient
+*/
+define "Tetanus and Diphtheria Booster Doses Administered to Patient":
+  Take( "Tetanus and Diphtheria containing Doses Administered to Patient", Count("Tetanus and Diphtheria containing Doses Administered to Patient") - 3 )
+
+/*
+@internal: Date of latest Tetanus and Diphtheria Vaccine
+*/
+define "Date of latest Tetanus and Diphtheria Vaccine":
+	First("Tetanus and Diphtheria containing Doses Administered to Patient").occurrence as dateTime
+
+/*
+@internal: Pertussis containing Doses Administered to Patient
+*/
+define "Pertussis Doses Administered to Patient":
+  IMMZCom."Doses Administered to Patient" I where I.vaccineCode in IMMZc."Pertussis Vaccine"
+
+/*
+@internal: Pertussis containing Booster Doses Administered to Patient
+*/
+define "Pertussis Booster Doses Administered to Patient":
+  Take( "Pertussis Doses Administered to Patient", Count("Pertussis Doses Administered to Patient") - 3 )
+
+/*
+@input: No DTP primary series doses were administered
+@pseudocode: Count of vaccines administered (where "Vaccine type" = "'Diphtheria-tetanus-pertussis containing vaccines" and "Type of dose" = "Primary series") = 0
+*/
+define "No DTP primary series doses were administered":
+	not exists("DTP Doses Administered to Patient")
+
+/*
+@input: One DTP primary series dose was administered
+@pseudocode: Count of vaccines administered (where "Vaccine type" = "'Diphtheria-tetanus-pertussis containing vaccines" and "Type of dose" = "Primary series") = 1
+*/
+define "One DTP primary series dose was administered":
+	Count("DTP Doses Administered to Patient") = 1
+
+/*
+@input: Two DTP primary series doses were administered
+@pseudocode: Count of vaccines administered (where "Vaccine type" = 'Diphtheria-tetanus-pertussis containing vaccines' and "Type of dose" = 'Primary series') = 2
+*/
+define "Two DTP primary series doses were administered":
+	Count("DTP Doses Administered to Patient") = 2
+
+/*
+@input: Three DTP primary series doses were administered
+@pseudocode: Count of vaccines administered (where "Vaccine type" = 'Diphtheria-tetanus-pertussis containing vaccines' and "Type of dose" = 'Primary series') = 3
+*/
+define "Three DTP primary series doses were administered":
+	Count("DTP Doses Administered to Patient") >= 3
+
+/*
+@input: No tetanus and diphtheria booster doses were administered
+@pseudocode: Count of vaccines administered (where "Vaccine type" = "Tetanus and diphtheria containing vaccines" and "Type of dose" = "Booster dose") = 0
+*/
+define "No tetanus and diphtheria booster doses were administered":
+	not exists( "Tetanus and Diphtheria Booster Doses Administered to Patient" )
+
+/*
+@input: No tetanus and diphtheria booster dose was administered
+@pseudocode: Count of vaccines administered (where "Vaccine type" = "Tetanus and diphtheria containing vaccines" and "Type of dose" = "Booster dose") = 0
+*/
+define "No tetanus and diphtheria booster dose was administered":
+  "No tetanus and diphtheria booster doses were administered"
+
+/*
+@input: One tetanus and diphtheria booster dose was administered
+@pseudocode: Count of vaccines administered where "Vaccine type" = "Tetanus and diphtheria containing vaccines" and "Type of dose" = "Booster dose" ) = 1
+*/
+define "One tetanus and diphtheria booster dose was administered":
+	Count("Tetanus and Diphtheria Booster Doses Administered to Patient") = 1
+
+/*
+@input: Two tetanus and diphtheria booster doses were administered
+@pseudocode: Count of vaccines administered where "Vaccine type" = "Tetanus and diphtheria containing vaccines" and "Type of dose" = "Booster dose" ) = 2
+*/
+define "Two tetanus and diphtheria booster doses were administered":
+	Count("Tetanus and Diphtheria Booster Doses Administered to Patient") = 2
+
+/*
+@input: Three tetanus and diphtheria booster doses were administered
+@pseudocode: Count of vaccines administered where "Vaccine type" = "Tetanus and diphtheria containing vaccines" and "Type of dose" = "Booster dose" ) = 3
+*/
+define "Three tetanus and diphtheria booster doses were administered":
+	Count("Tetanus and Diphtheria Booster Doses Administered to Patient") >= 3
+
+/*
+@input: No pertussis booster doses were administered
+@pseudocode: Count of vaccines administered where "Vaccine type" = "Pertussis containing vaccines" and "Type of dose" = "Booster dose" ) = 0
+*/
+define "No pertussis booster doses were administered":
+	not exists( "Pertussis Booster Doses Administered to Patient" )
+
+/*
+@input: One pertussis booster dose was administered
+@pseudocode: Count of vaccines administered where "Vaccine type" = "Pertussis containing vaccines" and "Type of dose" = "Booster dose" =1
+*/
+define "One pertussis booster dose was administered":
+	Count("Pertussis Booster Doses Administered to Patient") = 1
+
+/*
+@input: Client's age is less than 6 weeks
+@pseudocode: Today's date - "Date of birth" < 6 'week'
+*/
+define "Client's age is less than 6 weeks":
+	IMMZCom."Current Patient Age In Weeks" < 6
+
+/*
+@input: Client's age is between 6 weeks and 1 year
+@pseudocode: 6 'week' ≤ Today's date - "Date of birth" < 1 'year'
+*/
+define "Client's age is between 6 weeks and 1 year":
+	not("Client's age is less than 6 weeks") and "Client's age is less than 1 year"
+
+/*
+@input: Client's age is less than 12 months
+@pseudocode: Today's date - "Date of birth" < 12 'month'
+*/
+define "Client's age is less than 12 months":
+	IMMZCom."Current Patient Age In Months" < 12
+
+/*
+@input: Client's age is more than or equal to 12 months
+@pseudocode: Today's date - "Date of birth" ≥ 12 'month'
+*/
+define "Client's age is more than or equal to 12 months":
+	not("Client's age is less than 12 months")
+
+/*
+@input: Client's age is less than 4 years
+@pseudocode: Today's date - "Date of birth" < 4 'year'
+*/
+define "Client's age is less than 4 years":
+	IMMZCom."Current Patient Age In Years" < 4
+
+/*
+@input: Client's age is more than or equal to 4 years
+@pseudocode: Today's date - "Date of birth" ≥ 4 'year'
+*/
+define "Client's age is more than or equal to 4 years":
+	not("Client's age is less than 4 years")
+
+/*
+@input: Client's age is less than 9 years
+@pseudocode: Today's date - "Date of birth" < 9 'year'
+*/
+define "Client's age is less than 9 years":
+	IMMZCom."Current Patient Age In Years" < 9
+
+/*
+@input: Client's age is more than or equal to 9 years
+@pseudocode: Today's date - "Date of birth" ≥ 9 'year'
+*/
+define "Client's age is more than or equal to 9 years":
+	not("Client's age is less than 9 years")
+
+/*
+@input: Client's age is less than 1 year
+@pseudocode: Today's date - "Date of birth" < 1 'year'
+*/
+define "Client's age is less than 1 year":
+	IMMZCom."Current Patient Age In Years" < 1
+
+/*
+@input: Client's age is more than 1 year
+@pseudocode: Today's date - "Date of birth" > 1 year
+*/
+define "Client's age is more than 1 year":
+	not( "Client's age is less than 1 year" )
+
+/*
+@input: Client's age is between 1 year and 6 years
+@pseudocode: 1 'year' ≤  Today's date - "Date of birth" ≤  6 'year'
+*/
+define "Client's age is between 1 year and 6 years":
+	not("Client's age is less than 1 year") and not("Client's age is more than 6 years")
+
+/*
+@input: Client's age is between 1 year and 6 years old
+@pseudocode: 1 year ≤  Today's date - "Date of birth" ≤  6 years
+*/
+define "Client's age is between 1 year and 6 years old":
+  "Client's age is between 1 year and 6 years"
+
+/*
+@input: Client's age is more than 6 years
+@pseudocode: Today's date - "Date of birth" >  6 'year'
+*/
+define "Client's age is more than 6 years":
+	IMMZCom."Current Patient Age In Years" > 6
+
+/*
+@input: The latest DTP dose was administered less than 4 weeks ago
+@pseudocode: Today's date - latest "Date and time of vaccination" (where "Vaccine type" = 'Diphtheria-tetanus-pertussis containing vaccines') < 4 'week'
+*/
+define "The latest DTP dose was administered less than 4 weeks ago":
+	"Date of latest DTP Vaccine" is not null and duration in weeks between "Date of latest DTP Vaccine" and Now() < 4
+/*
+@input: The latest DTP dose was administered more than 4 weeks ago
+@pseudocode: Today's date - latest "Date and time of vaccination" (where "Vaccine type" = 'Diphtheria-tetanus-pertussis containing vaccines') ≥ 4 'week'
+*/
+define "The latest DTP dose was administered more than 4 weeks ago":
+	not("The latest DTP dose was administered less than 4 weeks ago")
+
+/*
+@input: The latest DTP dose was administered less than 6 months ago
+@pseudocode: Today's date - latest "Date and time of vaccination" (where "Vaccine type" = 'Diphtheria-tetanus-pertussis containing vaccines') < 6 'month'
+*/
+define "The latest DTP dose was administered less than 6 months ago":
+	"Date of latest DTP Vaccine" is not null and duration in months between "Date of latest DTP Vaccine" and Now() < 6
+
+/*
+@input: The latest DTP dose was administered more than 6 months ago
+@pseudocode: Today's date - latest "Date and time of vaccination" (where "Vaccine type" = 'Diphtheria-tetanus-pertussis containing vaccines') ≥ 6 'month'
+*/
+define "The latest DTP dose was administered more than 6 months ago":
+	not("The latest DTP dose was administered less than 6 months ago")
+
+/*
+@input: The latest DTP dose was administered less than 1 year ago
+@pseudocode: Today's date - latest "Date and time of vaccination" (where "Vaccine type" = "Diphtheria-tetanus-pertussis containing vaccines") < 1 year
+*/
+define "The latest DTP dose was administered less than 1 year ago":
+	"Date of latest DTP Vaccine" is not null and duration in years between "Date of latest DTP Vaccine" and Now() < 1
+
+/*
+@input: The latest DTP dose was administered more than 1 year ago
+@pseudocode: Today's date - latest "Date and time of vaccination" (where "Vaccine type" = "Diphtheria-tetanus-pertussis containing vaccines") ≥ 1 year
+*/
+define "The latest DTP dose was administered more than 1 year ago":
+	not("The latest DTP dose was administered less than 1 year ago")
+
+/*
+@input: The latest tetanus and diphtheria dose was administered less than 4 weeks ago
+@pseudocode: Today's date - Latest "Date and time of vaccination" (where "Vaccine type" = "Tetanus and diphtheria containing vaccines") < 4 weeks
+*/
+define "The latest tetanus and diphtheria dose was administered less than 4 weeks ago":
+  "Date of latest Tetanus and Diphtheria Vaccine" is not null and duration in weeks between "Date of latest Tetanus and Diphtheria Vaccine" and Now() < 4
+
+/*
+@input: The latest tetanus and diphtheria dose was administered more than 4 weeks ago
+@pseudocode: Today's date - Latest "Date and time of vaccination" (where "Vaccine type" = "Tetanus and diphtheria containing vaccines") > 4 weeks
+*/
+define "The latest tetanus and diphtheria dose was administered more than 4 weeks ago":
+	not("The latest tetanus and diphtheria dose was administered less than 4 weeks ago")
+
+/*
+@input: The latest tetanus and diphtheria dose was administered less than 1 year ago
+@pseudocode: Today's date - Latest "Date and time of vaccination" (where "Vaccine type" = "Tetanus and diphtheria containing vaccines") < 1 year
+*/
+define "The latest tetanus and diphtheria dose was administered less than 1 year ago":
+  "Date of latest Tetanus and Diphtheria Vaccine" is not null and duration in years between "Date of latest Tetanus and Diphtheria Vaccine" and Now() < 1
+
+/*
+@input: The latest tetanus and diphtheria dose was administered more than 1 year ago
+@pseudocode: Today's date - Latest "Date and time of vaccination" (where "Vaccine type" = "Tetanus and diphtheria containing vaccines") ≥ 1 year
+*/
+define "The latest tetanus and diphtheria dose was administered more than 1 year ago":
+	not("The latest tetanus and diphtheria dose was administered less than 1 year ago")
+
+/*
+@input: Client is currently pregnant
+@pseudocode: "Currently pregnant" = TRUE
+*/
+define "Client is currently pregnant":
+	IMMZCom."Pregnant"
+
+/*
+@input: The client has a history of anaphylactic reactions
+@pseudocode: "Potential contraindications" = "History of anaphylactic reactions"
+*/
+define "The client has a history of anaphylactic reactions":
+	exists(IMMZCom."History of Anaphylactic Reactions Condition")
+
+/*
+@input: The client currently has a severe acute illness
+@pseudocode: "Potential contraindications" = "Severe acute illness"
+*/
+define "The client currently has a severe acute illness":
+	exists(IMMZCom."Severe Acute Illness Condition")