build.gradle

plugins {
    id 'com.gradle.plugin-publish' version '1.3.0'
    id 'java-gradle-plugin'
    id 'groovy'
    id 'jacoco'
    id 'signing'
    id 'net.researchgate.release' version '3.0.2'
    id 'ru.vyarus.quality' version '5.0.0'
    id 'io.github.gradle-nexus.publish-plugin' version '2.0.0'
    id 'ru.vyarus.java-lib' version '3.0.0'
    id 'ru.vyarus.github-info' version '2.0.0'
    id 'com.github.ben-manes.versions' version '0.51.0'
    id "pl.droidsonroids.jacoco.testkit" version "1.0.12"
    id 'ru.vyarus.mkdocs' version '3.0.0'
}

java {
    sourceCompatibility = 1.8
}

wrapper {
    gradleVersion = '8.5'
    distributionType = Wrapper.DistributionType.BIN
}

ext {
    animalsnifferVersion = '1.7.2'
    cpdVersion = '3.5'
    spotbugsPluginVersion = '5.2.5'
    docVersion = '5.0.0'
}

repositories { mavenLocal(); mavenCentral(); gradlePluginPortal() }
dependencies {
    implementation "com.github.spotbugs.snom:spotbugs-gradle-plugin:$spotbugsPluginVersion"

    testImplementation('org.spockframework:spock-core:2.3-groovy-3.0') {
        exclude group: 'org.codehaus.groovy'
    }
    testImplementation "ru.vyarus:gradle-animalsniffer-plugin:$animalsnifferVersion"
    testImplementation "de.aaschmid:gradle-cpd-plugin:$cpdVersion"
}

group = 'ru.vyarus'
description = 'Gradle quality plugin for Java and Groovy'

github {
    user 'xvik'
    license 'MIT'
}

mkdocs {
    publish {
        docPath = project.docVersion
        rootRedirect = true
        rootRedirectTo = 'latest'
        versionAliases = ['latest']
    }
    extras = [
            'version': project.docVersion,
            'checkstyle': '10.12.7',
            'pmd': '6.55.0',
            'spotbugs': '4.8.3',
            'codenarc': '3.4.0',
            'spotbugsPlugin': project.spotbugsPluginVersion,
            'cpd': project.cpdVersion,
            'animalsnifferPlugin': project.animalsnifferVersion,
    ]
}

maven.pom {
    developers {
        developer {
            id = 'xvik'
            name = 'Vyacheslav Rusakov'
            email = 'vyarus@gmail.com'
        }
    }
}

nexusPublishing {
    repositories {
        sonatype {
            username = findProperty('sonatypeUser')
            password = findProperty('sonatypePassword')
        }
    }
}

// skip signing for jitpack (snapshots)
tasks.withType(Sign).configureEach { onlyIf { !System.getenv('JITPACK') } }

// Required signing properties for release: signing.keyId, signing.password and signing.secretKeyRingFile
// (https://docs.gradle.org/current/userguide/signing_plugin.html#sec:signatory_credentials)

javaLib {
    // don't publish gradle metadata artifact
    withoutGradleMetadata()
}


gradlePlugin {
    plugins {
        qualityPlugin {
            id = 'ru.vyarus.quality'
            displayName = project.description
            description = 'Static code analysis for Java and Groovy projects'
            tags.set(['java', 'groovy', 'quality', 'checkstyle', 'pmd', 'cpd', 'spotbugs', 'codenarc'])
            implementationClass = 'ru.vyarus.gradle.plugin.quality.QualityPlugin'
        }
    }
}

release.git.requireBranch.set('master')

afterReleaseBuild {
    dependsOn = [
            'publishMavenPublicationToSonatypeRepository',
            'closeAndReleaseSonatypeStagingRepository',
            publishPlugins]
    doLast {
        logger.warn "RELEASED $project.group:$project.name:$project.version"
    }
}

test {
    useJUnitPlatform()
    testLogging {
        events 'skipped', 'failed'
        exceptionFormat 'full'
    }
    maxHeapSize = '2g'
    doLast {
        sleep(1000)
    }
}

dependencyUpdates.revision = 'release'