build.gradle

plugins {
    id 'io.franzbecker.gradle-lombok' version '1.8'
    id "com.palantir.git-version" version "0.12.3"
}

println 'Building version: ' + gitVersion()

subprojects {

    group = 'com.unidev.polydata4'
    version = gitVersion()

    apply plugin: 'java'
    apply plugin: 'idea'
    apply plugin: 'maven-publish'
    apply plugin: 'java-library'

    repositories {
        google()
        mavenCentral()
        jcenter()
        maven {
            url "https://mvn.universal-development.com/public"
        }
    }


    dependencies {

        compileOnly "org.projectlombok:lombok:${lombokVersion}"
        annotationProcessor "org.projectlombok:lombok:${lombokVersion}"

        testCompileOnly "org.projectlombok:lombok:${lombokVersion}"
        testAnnotationProcessor "org.projectlombok:lombok:${lombokVersion}"

        testImplementation "org.mockito:mockito-all:${mokitoVersion}"
        testImplementation "org.hamcrest:hamcrest-all:${hamcrestVersion}"
        testImplementation "org.assertj:assertj-core:${assertjCoreVersion}"

        testImplementation "org.testcontainers:testcontainers:${testcontainersVersion}"
        testImplementation "org.testcontainers:junit-jupiter:${testcontainersVersion}"

        testImplementation "org.junit.jupiter:junit-jupiter:${junitJupiterVersion}"
    }

    idea {
        module {
            downloadSources = true
        }
    }

    // if is model project, apply jdk 1.8
    if (project.name == 'polydata-model') {
        tasks.withType(JavaCompile) {
            sourceCompatibility = JavaVersion.VERSION_1_8
            targetCompatibility = JavaVersion.VERSION_1_8
        }
    } else {
        tasks.withType(JavaCompile) {
            sourceCompatibility = JavaVersion.VERSION_17
            targetCompatibility = JavaVersion.VERSION_17
        }
    }


    tasks.withType(Copy).all { duplicatesStrategy 'exclude' }

    test {
        useJUnitPlatform()
    }

    publishing {
        publications {
            mavenJava(MavenPublication) {
                from components.java
            }
        }
    }
}