build.gradle

buildscript {
    repositories {
        jcenter()
        maven {
            url 'https://geonet.artifactoryonline.com/geonet/public-releases'
        }
    }
    dependencies {
        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:0.6'
        classpath 'nz.org.geonet:gradle-build-version-plugin:1.0.4'
    }
}

allprojects {
    apply plugin: 'java'
    apply plugin: 'groovy'
    apply plugin: 'eclipse'
    apply plugin: 'idea'
    apply plugin: 'maven'
    apply plugin: 'maven-publish'
    apply plugin: 'com.jfrog.bintray'
    apply plugin: 'build-version'


    buildVersion {
        releaseTagPattern = "^v(\\d+\\.\\d+\\.\\d+)"
    }

    sourceCompatibility = 1.7
    targetCompatibility = 1.7
    group = 'net.thucydides'
    version = buildVersion.version

    repositories {
        mavenLocal()
        jcenter()
    }

    ext {
        bintrayBaseUrl = 'https://api.bintray.com/maven'
        bintrayRepository = 'maven'
        bintrayPackage = 'thucydides-core-libraries'
        projectDescription = 'Thucydides core libraries'
        if (!project.hasProperty("bintrayUsername")) {
           bintrayUsername = 'wakaleo'
        }
        if (!project.hasProperty("bintrayApiKey")) {
            bintrayApiKey = ''
        }
    }

    task wrapper(type: Wrapper) {
        gradleVersion = '2.1'
    }

    test {
        exclude '**/*$*'
        exclude '**/integration/**'
        exclude '**/samples/**'
        exclude '**/*Sample*'
        minHeapSize = "128m"
        maxHeapSize = "512m"
        jvmArgs '-XX:MaxPermSize=256m'
    }

    task integrationTests(type: Test) {
        exclude '**/*$*'
        exclude '**/samples/**'
        exclude '**/*Sample*'
        exclude '**/integration/browsers**'
        include '**/integration/**'
        reports.junitXml.destination = "${buildDir}/reports/integration-tests"
        reports.html.destination = "${buildDir}/reports/integration-tests"
        minHeapSize = "128m"
        maxHeapSize = "1024m"
        jvmArgs '-XX:MaxPermSize=256m'
    }

    test {
        testLogging {
            exceptionFormat = 'full'
        }
    }

    integrationTests {
        testLogging {
            exceptionFormat = 'full'
        }
    }


    task browserTests(type: Test) {
        exclude '**/*$*'
        exclude '**/samples/**'
        exclude '**/*Sample*'
        exclude '**/*Base'
        include '**/integration/browsers/**'
    }

    task javadoc(type: Javadoc, overwrite:true) {
        source = sourceSets.main.allJava
        options.memberLevel = JavadocMemberLevel.PUBLIC
        options.addStringOption('views')
        options.addStringOption('all')
        options.addStringOption('quiet')
        options.addStringOption('qualify')
        options.addStringOption('Xdoclint:none')
        classpath = configurations.compile
    }

//    integrationTests.dependsOn test
    check.dependsOn -= integrationTests


    dependencies {
        compile "com.google.inject:guice:3.0"
        compile "org.slf4j:slf4j-api:1.6.4"
        testCompile "ch.qos.logback:logback-classic:1.0.13"
        testCompile "junit:junit:4.11"
        testCompile "org.hamcrest:hamcrest-integration:1.3"
        testCompile "org.hamcrest:hamcrest-library:1.3"
        testCompile "org.hamcrest:hamcrest-core:1.3"
        testCompile('org.mockito:mockito-all:1.10.8') {
            exclude group: "org.hamcrest"
        }
        testCompile("org.spockframework:spock-core:0.7-groovy-2.0") {
            exclude group: "junit"
        }
        testCompile("com.github.goldin:spock-extensions:0.1.4") {
            exclude module: "spock-core"
        }
        testCompile("org.codehaus.groovy:groovy-all:2.3.3")
        testCompile("org.easytesting:fest-assert:1.4")
    }

    bintray {
        user = bintrayUsername //this usually comes form gradle.properties file in ~/.gradle
        key = bintrayApiKey //this usually comes form gradle.properties file in ~/.gradle
        publications = ['mavenJava'] // see publications closure
        pkg {
            repo = 'maven'
            userOrg = 'thucydides'
            name = 'thucydides-core-libraries'
            desc = 'Thucydides core libraries'
            licenses = ['Apache-2.0']
            labels = ['thucydides','bdd']
        }
    }
}

subprojects {
    task sourcesJar(type: Jar, dependsOn: classes) {
        classifier = 'sources'
        from sourceSets.main.allSource
    }

    task javadocJar(type: Jar, dependsOn: javadoc) {
        classifier = 'javadoc'
        from javadoc.destinationDir
    }

    artifacts {
        archives sourcesJar, javadocJar
    }


    publishing {
        publications {
            mavenJava(MavenPublication) {

                println "Publishing $project.name:$project.group:$project.version"

                from components.java

                artifact sourcesJar {
                    classifier "sources"
                }

                artifact javadocJar {
                    classifier "javadoc"
                }

                pom.withXml {
                    asNode().children().last() + {
                        resolveStrategy = Closure.DELEGATE_FIRST
                        name "$project.name"
                        description "$projectDescription"

                        if (project.name == 'thucydides-maven-plugin') {
                            packaging 'maven-plugin'
                        }

                        url 'https://github.com/thucydides-webtests/$project.name'
                        scm {
                            url 'scm:git:git@github.com:thucydides-webtests/$project.name.git'
                            connection 'scm:git:git@github.com:thucydides-webtests/$project.name.git'
                            developerConnection 'scm:git:git@github.com:thucydides-webtests/$project.name.git'
                        }
                        licenses {
                            license {
                                name 'The Apache Software License, Version 2.0'
                                url 'http://www.apache.org/license/LICENSE-2.0.txt'
                                distribution 'repo'
                            }
                        }
                        developers {
                            developer {
                                id 'johnsmart'
                                name 'John Ferguson Smart'
                                email 'john.smart@wakaleo.com'
                            }
                        }
                    }
                    // Preserve compile-scope dependencies
                    asNode().dependencies.'*'.findAll() {
                        it.scope.text() == 'runtime' && project.configurations.compile.allDependencies.find { dep ->
                            dep.name == it.artifactId.text()
                        }
                    }.each() {
                        it.scope*.value = 'compile'
                    }
                }
            }
        }
    }

    tasks.withType(JavaCompile) {
        options.compilerArgs << "-Xlint:-options"
    }
}