build.gradle

plugins {
	id 'fabric-loom' version '0.7-SNAPSHOT'
	id 'maven-publish'
}

sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8

archivesBaseName = project.archives_base_name
version = "${project.mod_version}+${project.minecraft_version}-fabric"
group = project.maven_group

dependencies {
	// Main Fabric
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
	modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"
	modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_api_version}"

	// Cloth
	modImplementation "me.shedaniel.cloth:cloth-config-fabric:${project.cloth_config_version}"
	include "me.shedaniel.cloth:cloth-config-fabric:${project.cloth_config_version}"

	// Modmenu
	modCompileOnly("com.terraformersmc:modmenu:${project.modmenu_version}") {transitive(false)}
	modRuntime("com.terraformersmc:modmenu:${project.modmenu_version}")

	modImplementation "com.terraformersmc.terraform-api:terraform-wood-api-v1:${project.terraform_wood_api_version}"
	include "com.terraformersmc.terraform-api:terraform-wood-api-v1:${project.terraform_wood_api_version}"
}

repositories {
	maven {
		name = 'TerraformersMC Maven'
		url = 'https://maven.terraformersmc.com/'
	}
	maven {
		name = 'Shedaniel Maven'
		url "https://maven.shedaniel.me/"
	}
}

loom {
	accessWidener "src/main/resources/${project.archives_base_name}.accesswidener"
}

processResources {
	inputs.property "version", project.version

	filesMatching("fabric.mod.json") {
		expand "version": project.version
	}
}

tasks.withType(JavaCompile).configureEach {
	it.options.encoding = "UTF-8"
	def targetVersion = 8
	if (JavaVersion.current().isJava9Compatible()) {
		it.options.release = targetVersion
	}
}

java {
	withSourcesJar()
}

jar {
	from("LICENSE") {
		rename { "${it}_${project.archivesBaseName}"}
	}
}