build.gradle

plugins {
	id "java"
	id "edu.wpi.first.GradleRIO" version "2023.4.3"
	id "com.peterabeles.gversion" version "1.10.2"
	id "com.diffplug.spotless" version "6.23.3"
}

sourceCompatibility = JavaVersion.VERSION_11
targetCompatibility = JavaVersion.VERSION_11

def ROBOT_MAIN_CLASS = "frc.robot.Main"

repositories {
	maven {
		url = uri("https://maven.pkg.github.com/Mechanical-Advantage/AdvantageKit")
		credentials {
			username = "Mechanical-Advantage-Bot"
			password = "\u0067\u0068\u0070\u005f\u006e\u0056\u0051\u006a\u0055\u004f\u004c\u0061\u0079\u0066\u006e\u0078\u006e\u0037\u0051\u0049\u0054\u0042\u0032\u004c\u004a\u006d\u0055\u0070\u0073\u0031\u006d\u0037\u004c\u005a\u0030\u0076\u0062\u0070\u0063\u0051"
		}
	}
}

configurations.all {
	exclude group: "edu.wpi.first.wpilibj"
}

// Define my targets (RoboRIO) and artifacts (deployable files)
// This is added by GradleRIO's backing project DeployUtils.
deploy {
	targets {
		roborio(getTargetTypeClass('RoboRIO')) {
			// Team number is loaded either from the .wpilib/wpilib_preferences.json
			// or from command line. If not found an exception will be thrown.
			// You can use getTeamOrDefault(team) instead of getTeamNumber if you
			// want to store a team number in this file.
			team = project.frc.getTeamNumber()
			debug = project.frc.getDebugOrDefault(false)

			artifacts {
				// First part is artifact name, 2nd is artifact type
				// getTargetTypeClass is a shortcut to get the class type using a string

				frcJava(getArtifactTypeClass('FRCJavaArtifact')) {
					// Java profiler
					// 	jvmArgs.add("-Dcom.sun.management.jmxremote=true")
					// 	jvmArgs.add("-Dcom.sun.management.jmxremote.port=1099")
					// 	jvmArgs.add("-Dcom.sun.management.jmxremote.local.only=false")
					// 	jvmArgs.add("-Dcom.sun.management.jmxremote.ssl=false")
					// 	jvmArgs.add("-Dcom.sun.management.jmxremote.authenticate=false")
					// 	jvmArgs.add("-Djava.rmi.server.hostname=10.5.81.2")
				}

				// Static files artifact
				frcStaticFileDeploy(getArtifactTypeClass('FileTreeArtifact')) {
					files = project.fileTree('src/main/deploy')
					directory = '/home/lvuser/deploy'
				}
			}
		}
	}
}

def deployArtifact = deploy.targets.roborio.artifacts.frcJava

// Set to true to use debug for JNI.
wpi.java.debugJni = false

// Set this to true to enable desktop support.
def includeDesktopSupport = false

// Defining my dependencies. In this case, WPILib (+ friends), and vendor libraries.
// Also defines JUnit 5.
dependencies {
	implementation wpi.java.deps.wpilib()
	implementation wpi.java.vendor.java()

	roborioDebug wpi.java.deps.wpilibJniDebug(wpi.platforms.roborio)
	roborioDebug wpi.java.vendor.jniDebug(wpi.platforms.roborio)

	roborioRelease wpi.java.deps.wpilibJniRelease(wpi.platforms.roborio)
	roborioRelease wpi.java.vendor.jniRelease(wpi.platforms.roborio)

	nativeDebug wpi.java.deps.wpilibJniDebug(wpi.platforms.desktop)
	nativeDebug wpi.java.vendor.jniDebug(wpi.platforms.desktop)
	simulationDebug wpi.sim.enableDebug()

	nativeRelease wpi.java.deps.wpilibJniRelease(wpi.platforms.desktop)
	nativeRelease wpi.java.vendor.jniRelease(wpi.platforms.desktop)
	simulationRelease wpi.sim.enableRelease()

	testImplementation 'org.junit.jupiter:junit-jupiter-api:5.8.2'
	testImplementation 'org.junit.jupiter:junit-jupiter-params:5.8.2'
	testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.8.2'

	annotationProcessor "org.littletonrobotics.akit.junction:junction-autolog:2.0.0"
}

test {
	useJUnitPlatform()
	systemProperty 'junit.jupiter.extensions.autodetection.enabled', 'true'
}

// Simulation configuration (e.g. environment variables).
wpi.sim.addGui().defaultEnabled = true
wpi.sim.addDriverstation()

// Setting up my Jar File. In this case, adding all libraries into the main jar ('fat jar')
// in order to make them all available at runtime. Also adding the manifest so WPILib
// knows where to look for our Robot Class.
jar {
	from {
		configurations.runtimeClasspath.collect {
			it.isDirectory() ? it : zipTree(it)
		}
	}
	manifest edu.wpi.first.gradlerio.GradleRIOPlugin.javaManifest(ROBOT_MAIN_CLASS)
	duplicatesStrategy = DuplicatesStrategy.INCLUDE
}

// Configure jar and deploy tasks
deployArtifact.jarTask = jar
wpi.java.configureExecutableTasks(jar)
wpi.java.configureTestTasks(test)

// Configure string concat to always inline compile
tasks.withType(JavaCompile) {
	options.compilerArgs.add '-XDstringConcat=inline'
}

// Create build constants file during build
project.compileJava.dependsOn(createVersionFile)
gversion {
	srcDir       = "src/main/java"
	classPackage = "frc.robot.generated"
	className    = "BuildConstants"
	dateFormat   = "yyyy-MM-dd HH:mm:ss z"
	timeZone     = "America/Los_Angeles"
	indent       = "  "
}

apply plugin: 'groovy'
spotless {
	enforceCheck false

	encoding 'UTF-8'
	lineEndings 'UNIX'

	java {
		licenseHeader '// Copyright (c) FIRST and other WPILib contributors.\n' +
				'// Open Source Software; you can modify and/or share it under the terms of\n' +
				'// the WPILib BSD license file in the root directory of this project.\n\n'
		toggleOffOn()
		importOrder()
		removeUnusedImports()
		googleJavaFormat()
		trimTrailingWhitespace()
		endWithNewline()

		targetExclude('src/main/java/frc/robot/generated/**')
	}

	groovy {
		importOrder()
		excludeJava()
		greclipse()
	}

	groovyGradle {
		greclipse()
	}

	json {
		target '**/*.json'
		simple().indentWithSpaces(2)
	}

	format 'misc', {
		target '.gitignore'

		trimTrailingWhitespace()
		endWithNewline()
	}
}