main.sk

# ==================================================================
# ___  __                  ___ ___   ___
# | | / /                  |_| |  \ /  |
# | |/ /  ___   ___ __ ___ ___ | \ V / |   ___   __ ____   ___   ___
# |   <   | |   | | | ' _| | | | |\_/| |  / _ \  | ' _  \  | |   | |
# | |\ \  |  \_/  | |  /   | | | |   | | |  ___| |  / \  | |  \_/  |
# |_| \_\  \____/_| |_|    |_| |_|   | |  \___/  |_|   |_|  \____/_|
#
# ==================================================================
#
# Author: Take-John
# SPDX-License-Identifier: GPL-3.0


# このファイルはメニューの配置やアイコンの動作を定義する。
#
# ここでは一つのページを定義でき、
# プログラムはページからチェストインベントリを作成してプレイヤーに表示する。
# 新しくページを作成するにはこのファイルをコピー＆ペーストして適宜書き換えよう。


options:
    # 関数呼び出しをいちいち書くのが面倒なので options で定義
    # on inventory click イベントの中で {@slot_letter} はページデザインで設定した対応する文字となる。
    slot_letter: kurimenu_slot_letter(script, player, index of event-slot)


# ページデザインの設定
on load:
    # 設定の開始
    kurimenu_start_setting(script)

    # GUI のタイトル
    kurimenu_title(script, "&1&lMain Menu")

    # 配置を表すリストを作成する。
    # 要素数は 1 個以上 6 個以下。
    # それぞれの要素はインベントリの行を上から順に表現する。
    # それぞれの要素は 9 つの文字を並べた文字列となる。
    kurimenu_row(script, ".........")
    kurimenu_row(script, "..A.~.~..")
    kurimenu_row(script, ".........")
    kurimenu_row(script, ".....>...")
    kurimenu_row(script, ".......X.")
    kurimenu_row(script, ".........")

    # 文字に対応するアイテムの設定
    kurimenu_item(script, ".", light blue stained glass pane named " ")
    kurimenu_item(script, "~", blue stained glass pane named " ")
    kurimenu_item(script, "X", barrier named "閉じる")
    kurimenu_item(script, "A", grass block named "ワールドへ")
    kurimenu_item(script, ">", stone named "次のページへ")

    # 設定の終了
    kurimenu_end_setting(script)


command /menu:
    executable by: player
    trigger:
        kurimenu_open(script, player)


on inventory click:
    {@slot_letter} is "X"
    close player's inventory


on inventory click:
    {@slot_letter} is "A"
    send "まだ実装してないよ！"


on inventory click:
    {@slot_letter} is ">"
    kurimenu_open("kurimenu/examples/sub", player)