build.gradle

buildscript {
    repositories {
        mavenCentral()
        maven { url "https://oss.sonatype.org/content/repositories/snapshots/" }
        maven { url "https://plugins.gradle.org/m2/" }
    }

    dependencies {
        classpath "com.netflix.nebula:gradle-extra-configurations-plugin:3.0.3"
        classpath "io.codearte.gradle.nexus:gradle-nexus-staging-plugin:0.5.3"
        classpath "com.kotcrab.vis:vis-usl:0.2.1"
        classpath "com.badlogicgames.gdx:gdx-tools:1.9.2"
    }
}

apply plugin: 'distribution'
apply plugin: 'io.codearte.nexus-staging'

allprojects {
    apply plugin: "eclipse"
    apply plugin: "idea"
    apply plugin: "nebula.provided-base"
    apply plugin: "nebula.optional-base"

    version = '0.3.2-SNAPSHOT'
    ext {
        // Build Properties
        appName = 'vis'
        mainClassName = 'com.kotcrab.vis.editor.Main'
        // Dependency Properties
        gdxVersion = '1.9.3'
        editorGdxVersion = '1.9.3'
        box2dLightsVersion = '1.4'
        jnaVersion = '4.1.0'
        jnaPlatformVersion = '3.5.2'
        appleJavaExtensionsVersion = '1.4'
        junitVersion = '4.12'
        artemisVersion = '1.3.1'
        kryoVersion = '3.0.1'
        commonsIoVersion = '2.4'
        commonsLangVersion = '3.3.2'
        commonsExecVersion = '1.3'
        guavaVersion = '18.0'
        jsoupVersion = '1.8.2'
        slf4jVersion = '1.7.12'
        imgscalrVersion = '4.2'
        gsonVersion = '2.4'
        cloningVersion = '1.9.2'
        joorVersion = '0.9.5'
    }

    repositories {
        mavenCentral()
        maven { url "https://oss.sonatype.org/content/repositories/snapshots/" }
        maven { url "https://oss.sonatype.org/content/repositories/releases/" }
    }
}

project(':editor') {
    apply plugin: "java"

    dependencies {
        compile project(":runtime")
        compile project(":ui")
        compile "com.badlogicgames.gdx:gdx:$editorGdxVersion"
        compile "com.badlogicgames.gdx:gdx-backend-lwjgl3:$editorGdxVersion"
        compile "com.badlogicgames.gdx:gdx-platform:$editorGdxVersion:natives-desktop"
        compile "com.badlogicgames.gdx:gdx-freetype:$editorGdxVersion"
        compile "com.badlogicgames.gdx:gdx-freetype-platform:$editorGdxVersion:natives-desktop"
        compile "com.badlogicgames.gdx:gdx-box2d:$editorGdxVersion"
        compile "com.badlogicgames.gdx:gdx-box2d-platform:$editorGdxVersion:natives-desktop"
        compile "com.badlogicgames.box2dlights:box2dlights:$box2dLightsVersion"
        compile "net.onedaybeard.artemis:artemis-odb:$artemisVersion"
        compile "com.esotericsoftware:kryo:$kryoVersion"
        compile "commons-io:commons-io:$commonsIoVersion"
        compile "org.apache.commons:commons-lang3:$commonsLangVersion"
        compile "org.apache.commons:commons-exec:$commonsExecVersion"
        compile "net.java.dev.jna:jna:$jnaVersion"
        compile "net.java.dev.jna:platform:$jnaPlatformVersion"
        compile "com.google.guava:guava:$guavaVersion"
        compile "org.jsoup:jsoup:$jsoupVersion"
        compile "org.slf4j:slf4j-simple:$slf4jVersion"
        compile "org.imgscalr:imgscalr-lib:$imgscalrVersion"
        compile "com.google.code.gson:gson:$gsonVersion"
        compile "uk.com.robust-it:cloning:$cloningVersion"
        compile "org.jooq:joor:$joorVersion"
        provided "com.apple:AppleJavaExtensions:$appleJavaExtensionsVersion", optional
    }
}

project(':runtime') {
    apply plugin: "java"

    dependencies {
        provided "com.badlogicgames.gdx:gdx:$gdxVersion"
        provided "com.badlogicgames.gdx:gdx-freetype:$gdxVersion"
        provided "com.badlogicgames.gdx:gdx-box2d:$gdxVersion"
        provided "com.badlogicgames.box2dlights:box2dlights:$box2dLightsVersion"
        compile "net.onedaybeard.artemis:artemis-odb:$artemisVersion"
        provided "net.onedaybeard.artemis:artemis-odb-processor:$artemisVersion"
    }
}

project(':runtime-gwt') {
    apply plugin: "java"

    dependencies {
        compile project(":runtime")
        provided "com.badlogicgames.gdx:gdx:$gdxVersion"
        provided "com.badlogicgames.gdx:gdx-freetype:$gdxVersion"
        provided "com.badlogicgames.gdx:gdx-box2d:$gdxVersion"
    }
}

project(':ui') {
    apply plugin: "java"

    dependencies {
        compile "com.badlogicgames.gdx:gdx:$gdxVersion"
        provided "com.apple:AppleJavaExtensions:$appleJavaExtensionsVersion", optional
        testCompile "com.badlogicgames.gdx:gdx-backend-lwjgl3:$gdxVersion"
        testCompile "com.badlogicgames.gdx:gdx-platform:$gdxVersion:natives-desktop"
        testCompile "junit:junit:$junitVersion"
        //testCompile "org.imgscalr:imgscalr-lib:4.2"
    }
}

project(':plugins:vis-editor-spine') {
    apply plugin: 'java'

    dependencies {
        provided project(':editor')
        provided project(':plugins:vis-runtime-spine')
    }
}

project(':plugins:vis-runtime-spine') {
    apply plugin: 'java'

    dependencies {
        provided project(':runtime')
        provided "com.badlogicgames.gdx:gdx:$gdxVersion"
    }
}

project(':plugins:vis-editor-spine-notifier') {
    apply plugin: 'java'

    dependencies {
        provided project(':editor')
        provided "com.badlogicgames.gdx:gdx:$gdxVersion"
    }
}

project(':usl') {
    apply plugin: 'java'

    dependencies {
        testCompile "junit:junit:$junitVersion"
    }
}

project(':tools:crash-reporter') {
    apply plugin: 'java'

    dependencies {
        compile "org.apache.commons:commons-exec:$commonsExecVersion"
        testCompile "junit:junit:$junitVersion"
    }
}

nexusStaging {
    packageGroup = "com.kotcrab"
    username = ossrhUsername
    password = ossrhPassword
}

tasks.eclipse.doLast {
    delete ".project"
}

task wrapper(type: Wrapper) {
    gradleVersion = '2.13'
}

distributions {
    main {
        baseName = "VisEditor"
        contents {
            project(':editor') {
                from jar
                into('lib') {
                    from configurations.runtime
                }
            }

            def plugin = project(':plugins:vis-editor-spine')
            into('plugins/spine') {
                from plugin.jar
            }

            plugin = project(':plugins:vis-runtime-spine')
            into('plugins/spine/lib') {
                from plugin.jar
            }

            plugin = project(':plugins:vis-editor-spine-notifier')
            into('plugins/spine-notifier') {
                from plugin.jar
            }

            def tool = project(':tools:crash-reporter')
            into('tools') {
                from tool.jar
                rename("(.*).jar", "crash-reporter.jar")
            }
        }
    }
}