-
Notifications
You must be signed in to change notification settings - Fork 1
/
instr.m4
1673 lines (1492 loc) · 110 KB
/
instr.m4
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
m4_divert(-1)
#
# Copyright (C) 2015 Cybernetica
#
# Research/Commercial License Usage
# Licensees holding a valid Research License or Commercial License
# for the Software may use this file according to the written
# agreement between you and Cybernetica.
#
# GNU General Public License Usage
# Alternatively, this file may be used under the terms of the GNU
# General Public License version 3.0 as published by the Free Software
# Foundation and appearing in the file LICENSE.GPL included in the
# packaging of this file. Please review the following information to
# ensure the GNU General Public License version 3.0 requirements will be
# met: http://www.gnu.org/copyleft/gpl-3.0.html.
#
# For further information, please contact us at [email protected].
#
m4_changequote([,]) # use [ and ] instead of ` and '
################################################################################
## MACROS ##
################################################################################
## Here we define some macros used by the instruction definitions below and #
# m4 files depending these instruction definitions. #
################################################################################
m4_define([COMMENT],)
m4_include([forloop.m4])
m4_include([foreach.m4])
m4_include([product.m4])
m4_include([datatypebyte.m4])
m4_include([operandlocationbyte.m4])
m4_define([_ARG1],[$1]) # _ARG1(a1,a2,...) -> a1
m4_define([_ARG2],[$2]) # _ARG1(a1,a2,...) -> a2
m4_define([_ARG3],[$3]) # _ARG1(a1,a2,...) -> a3
m4_define([_ARG4],[$4]) # _ARG1(a1,a2,...) -> a4
m4_define([_ARG5],[$5]) # _ARG1(a1,a2,...) -> a5
# DEC_TO_HEX(value) changes the representation of value for decimal base to hexadecimal
m4_define([DEC_TO_HEX], [_$0(m4_eval([$1 % 16]))[]m4_ifelse(m4_eval([$1 >= 16]),
[1],
[$0(m4_eval([$1 / 16]))])])
m4_define([_DEC_TO_HEX], [m4_ifelse([$1], [15], [f], [$1], [14], [e], [$1], [13], [d],
[$1], [12], [c], [$1], [11], [b], [$1], [10], [a], [$1])])
m4_define([INSTR_COUNT],0)
m4_define([INSTR], [m4_defn(m4_format([[INSTR_%s]], [$1]))])
m4_define([INSTR_DEFINE], [m4_ifelse(m4_eval(m4_len([$1])[ >= 64]),[1],[m4_errprint([Instruction name "$1" (length ]m4_len([$1])[) exceeds maximum length limit of 63 characters!])m4_m4exit(1)])
m4_define(m4_format([[INSTR_%s]], [$1]), [$1, $2, $3, $4, $5, $6, $7, $8, ]INSTR_COUNT)
m4_define([INSTR_COUNT],m4_incr(INSTR_COUNT))
m4_define([INSTR_]INSTR_COUNT,[$1])])
m4_define([INSTRS],[forloop([i], 1, INSTR_COUNT, [m4_ifelse(i, [1], [], [, ])(INSTR(INSTR(i)))])])
m4_define([INSTR_FOREACH],[forloop([i], 1, INSTR_COUNT, [m4_indir([$1],_ARG1(INSTR(INSTR(i))))])])
m4_define([STRIP_NAME], [m4_patsubst($1, [\.[^.]*$])])
m4_define([STRIP_TOP_NAMESPACE], [m4_patsubst($1, [^[^.]*\.])])
m4_define([STRIP_NAMESPACE], [m4_patsubst($1, [^\([^.]*\.\)*])])
m4_define([INSTR_FULLNAME], $1)
m4_define([INSTR_NAME], [STRIP_NAMESPACE($1)])
m4_define([INSTR_NAMESPACE], [STRIP_NAME($1)])
m4_define([INSTR_CODE], $2)
m4_define([INSTR_ARGS], $3)
m4_define([INSTR_PREPARATION], $4)
m4_define([INSTR_IMPL_SUFFIX], $5)
m4_define([INSTR_IMPL], $6)
m4_define([INSTR_NEED_DISPATCH], $7)
m4_define([INSTR_NEED_PREPARE_FINISH], $8)
m4_define([INSTR_INDEX], $9)
m4_define([EMPTY_IMPL_COUNT],0)
m4_define([EMPTY_IMPL], [m4_defn(m4_format([[EMPTY_IMPL_%s]], [$1]))])
m4_define([EMPTY_IMPL_DEFINE], [m4_define(m4_format([[EMPTY_IMPL_%s]], [$1]), [$1, $2, $3, $4, ]EMPTY_IMPL_COUNT)
m4_define(m4_format([[EMPTY_IMPL_LABEL_%s]], [$1]), [$1])
m4_define(m4_format([[EMPTY_IMPL_ARGS_%s]], [$1]), [$2])
m4_define(m4_format([[EMPTY_IMPL_CODE_%s]], [$1]), [$3])
m4_define(m4_format([[EMPTY_IMPL_NEED_DISPATCH_%s]], [$1]), [$4])
m4_define(m4_format([[EMPTY_IMPL_INDEX_%s]], [$1]), [$5])
m4_define([EMPTY_IMPL_COUNT],m4_incr(EMPTY_IMPL_COUNT))
m4_define([EMPTY_IMPL_]EMPTY_IMPL_COUNT,[$1])])
m4_define([EMPTY_IMPLS],[forloop([i], 1, EMPTY_IMPL_COUNT, [m4_ifelse(i, [1], [], [, ])(EMPTY_IMPL(EMPTY_IMPL(i)))])])
m4_define([EMPTY_IMPL_FOREACH],[forloop([i], 1, EMPTY_IMPL_COUNT, [m4_indir([$1],_ARG1(EMPTY_IMPL(EMPTY_IMPL(i))))])])
m4_define([EMPTY_IMPL_FULLLABEL], $1)
m4_define([EMPTY_IMPL_LABEL], [STRIP_NAMESPACE($1)])
m4_define([EMPTY_IMPL_NAMESPACE], [STRIP_NAME($1)])
m4_define([EMPTY_IMPL_ARGS], $2)
m4_define([EMPTY_IMPL_CODE], $3)
m4_define([EMPTY_IMPL_NEED_DISPATCH], $4)
m4_define([EMPTY_IMPL_INDEX], $5)
m4_define([CODE], [($1, $2, $3, $4, $5, $6, $7, $8)])
m4_define([ARGS], [$1])
m4_define([NO_ARGS], [0])
m4_define([PREPARATION], [m4_ifelse([$1], [NO_PREPARATION], [], [$1])])
m4_define([IMPL_SUFFIX], [$1])
m4_define([NO_IMPL_SUFFIX], [])
m4_define([IMPL], [$1])
m4_define([REVERSE_2], [$2, $1])
m4_define([REVERSE_4], [$4, $3, $2, $1])
m4_define([REVERSE_8], [$8, $7, $6, $5, $4, $3, $2, $1])
m4_define([BYTES_TO_UINT16_BE], [m4_format([0x%02x%02x],m4_eval($2),m4_eval($1))])
m4_define([BYTES_TO_UINT16_LE], [BYTES_TO_UINT16_BE(REVERSE_2($@))])
m4_define([BYTES_TO_UINT32_BE], [m4_format([0x%02x%02x%02x%02x],m4_eval($4),m4_eval($3),m4_eval($2),m4_eval($1))])
m4_define([BYTES_TO_UINT32_LE], [BYTES_TO_UINT32_BE(REVERSE_4($@))])
m4_define([BYTES_TO_UINT64_BE], [m4_format([0x%02x%02x%02x%02x%02x%02x%02x%02x],m4_eval($8),m4_eval($7),m4_eval($6),m4_eval($5),m4_eval($4),m4_eval($3),m4_eval($2),m4_eval($1))])
m4_define([BYTES_TO_UINT64_LE], [BYTES_TO_UINT64_BE(REVERSE_8($@))])
m4_define([INSTR_CODE_TO_BYTECODE], [BYTES_TO_UINT64_BE($@)])
m4_define([COMPOSE], [$1$2])
################################################################################
## INSTRUCTION DEFINITIONS ##
################################################################################
INSTR_DEFINE([common.nop],
CODE(0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00),
NO_ARGS, NO_PREPARATION, NO_IMPL_SUFFIX, IMPL([SHAREMIND_MI_NOP]), DO_DISPATCH, PREPARE_FINISH)
INSTR_DEFINE([common.trap],
CODE(0x00, 0x00, 0x01, 0x00, 0x00, 0x00, 0x00, 0x00),
NO_ARGS, NO_PREPARATION, NO_IMPL_SUFFIX, IMPL([SHAREMIND_MI_TRAP]), DO_DISPATCH, PREPARE_FINISH)
m4_define([FPU_GETSTATE_DEFINE], [
INSTR_DEFINE([common.fpu.getstate_$1],
CODE(0x00, 0x05, 0x00, OLB_CODE_$1, 0x00, 0x00, 0x00, 0x00),
ARGS(1), NO_PREPARATION, NO_IMPL_SUFFIX,
IMPL([
SHAREMIND_T_CodeBlock * d;
SHAREMIND_MI_GET_$1(d, SHAREMIND_MI_ARG_AS(1, sizet));
SHAREMIND_MI_BLOCK_AS(d,uint64) = SHAREMIND_MI_FPU_STATE]), DO_DISPATCH, PREPARE_FINISH)])
FPU_GETSTATE_DEFINE([reg])
FPU_GETSTATE_DEFINE([stack])
m4_define([FPU_SETSTATE_DEFINE], [
INSTR_DEFINE([common.fpu.setstate_$1],
CODE(0x00, 0x05, 0x01, OLB_CODE_$1, 0x00, 0x00, 0x00, 0x00),
ARGS(1), NO_PREPARATION, NO_IMPL_SUFFIX,
IMPL([
const SHAREMIND_T_CodeBlock * s;
m4_ifelse($1, [imm],
[s = SHAREMIND_MI_ARG_P(1)],
[SHAREMIND_MI_GET_CONST_$1(s, SHAREMIND_MI_ARG_AS(1, sizet))]);
SHAREMIND_MI_FPU_STATE_SET(SHAREMIND_MI_BLOCK_AS(s,uint64))]), DO_DISPATCH, PREPARE_FINISH)])
FPU_SETSTATE_DEFINE([imm])
FPU_SETSTATE_DEFINE([reg])
FPU_SETSTATE_DEFINE([stack])
# common.mov (imm, reg, stack) >> (reg, stack)
# (1=olbsrc,2=olbdest)
m4_define([_MOV_REGS_TO_REGS_DEFINE], [
INSTR_DEFINE([common.mov_$1_$2],
CODE(0x00, 0x01, OLB_CODE_$1, 0x00, OLB_CODE_$2, 0x00, 0x00, 0x00),
ARGS(2), NO_PREPARATION, NO_IMPL_SUFFIX,
IMPL([
const SHAREMIND_T_CodeBlock * s;
m4_ifelse($1, [imm],
[s = SHAREMIND_MI_ARG_P(1);],
[SHAREMIND_MI_GET_CONST_$1(s, SHAREMIND_MI_ARG_AS(1, sizet));])
SHAREMIND_T_CodeBlock * d;
SHAREMIND_MI_GET_$2(d, SHAREMIND_MI_ARG_AS(2, sizet));
(*d) = *s]),
DO_DISPATCH, PREPARE_FINISH)])
m4_define([MOV_REGS_TO_REGS_DEFINE], [_MOV_REGS_TO_REGS_DEFINE(_ARG1$1, _ARG2$1)])
foreach([MOV_REGS_TO_REGS_DEFINE], (product(([imm], [reg], [stack]), ([reg], [stack]))))
# common.mov (mem) >> (reg, stack)
# (1=olbsrc_part,2=olbsrcoffset,3=olbdest,4=olbnbytes)
m4_define([_MOV_MEM_TO_REGS_DEFINE], [
INSTR_DEFINE([common.mov_mem_$1_$2_$3_$4],
CODE(0x00, 0x01, OLB_CODE_mem_$1, OLB_CODE_$2, OLB_CODE_$3, 0x00, OLB_CODE_$4, 0x00),
ARGS(4),
PREPARATION([
m4_ifelse($1, [imm],
[SHAREMIND_PREPARE_ARGUMENTS_CHECK(SHAREMIND_PREPARE_ARG_AS(1,uint64) >= 1u);
SHAREMIND_PREPARE_ARGUMENTS_CHECK(SHAREMIND_PREPARE_ARG_AS(1,uint64) <= 3u);])
m4_ifelse($4, [imm],
[SHAREMIND_PREPARE_ARGUMENTS_CHECK(SHAREMIND_PREPARE_ARG_AS(4,uint64) > 0u);
SHAREMIND_PREPARE_ARGUMENTS_CHECK(SHAREMIND_PREPARE_ARG_AS(4,uint64) <= 8u);])]),
NO_IMPL_SUFFIX, IMPL([
const SHAREMIND_T_CodeBlock * src;
const SHAREMIND_T_CodeBlock * m4_ifelse($2, [imm], [SHAREMIND_RESTRICT]) srcOffset;
SHAREMIND_T_CodeBlock * dest;
const SHAREMIND_T_CodeBlock * m4_ifelse($4, [imm], [SHAREMIND_RESTRICT]) numBytes;
m4_ifelse($1, [imm],
[src = SHAREMIND_MI_ARG_P(1);],
[SHAREMIND_MI_GET_CONST_$1(src, SHAREMIND_MI_ARG_AS(1, sizet));])
SHAREMIND_MI_MEM_GET_SLOT_OR_EXCEPT(SHAREMIND_MI_BLOCK_AS(src,uint64), srcSlot);
COMMENT([SHAREMIND_MI_TRY_EXCEPT(SHAREMIND_MI_MEM_CAN_READ(srcSlot), SHAREMIND_VM_PROCESS_READ_DENIED);])
m4_ifelse($2, [imm], [],
[SHAREMIND_MI_GET_CONST_$2(srcOffset, SHAREMIND_MI_ARG_AS(2, sizet));])
SHAREMIND_MI_GET_$3(dest, SHAREMIND_MI_ARG_AS(3, sizet));
m4_ifelse($4, [imm], [],
[SHAREMIND_MI_GET_CONST_$4(numBytes, SHAREMIND_MI_ARG_AS(4,sizet));
SHAREMIND_MI_TRY_EXCEPT(SHAREMIND_MI_BLOCK_AS(numBytes,uint64) <= 8u, SHAREMIND_VM_PROCESS_OUT_OF_BOUNDS_WRITE);])
m4_ifelse($2, [imm], [srcOffset = SHAREMIND_MI_ARG_P(2);])
m4_ifelse($4, [imm], [numBytes = SHAREMIND_MI_ARG_P(4);])
SHAREMIND_MI_TRY_MEMRANGE(SHAREMIND_MI_MEM_GET_SIZE_FROM_SLOT(srcSlot), SHAREMIND_MI_BLOCK_AS(srcOffset,uint64), SHAREMIND_MI_BLOCK_AS(numBytes,uint64), SHAREMIND_VM_PROCESS_OUT_OF_BOUNDS_READ);
SHAREMIND_MEMCPY(&(SHAREMIND_MI_BLOCK_AS(dest,uint64)), SHAREMIND_PTRADD(SHAREMIND_MI_MEM_GET_DATA_FROM_SLOT(srcSlot), SHAREMIND_MI_BLOCK_AS(srcOffset,uint64)), SHAREMIND_MI_BLOCK_AS(numBytes,uint64))]),
DO_DISPATCH, PREPARE_FINISH)])
m4_define([MOV_MEM_TO_REGS_DEFINE], [_MOV_MEM_TO_REGS_DEFINE(_ARG1$1, _ARG2$1, _ARG3$1, _ARG4$1)])
foreach([MOV_MEM_TO_REGS_DEFINE], (product(([imm], [reg], [stack]), ([imm], [reg], [stack]), ([reg], [stack]), ([imm], [reg], [stack]))))
# common.mov (imm, reg, stack) >> (mem)
# (1=olbsrc,2=olbdest_part,3=olbdestoffset,4=olbnbytes)
m4_define([_MOV_REGS_TO_MEM_DEFINE], [
INSTR_DEFINE([common.mov_$1_mem_$2_$3_$4],
CODE(0x00, 0x01, OLB_CODE_$1, 0x00, OLB_CODE_mem_$2, OLB_CODE_$3, OLB_CODE_$4, 0x00),
ARGS(4),
PREPARATION([
m4_ifelse($2, [imm],
[SHAREMIND_PREPARE_ARGUMENTS_CHECK(SHAREMIND_PREPARE_ARG_AS(2,uint64) >= 1u);
SHAREMIND_PREPARE_ARGUMENTS_CHECK(SHAREMIND_PREPARE_ARG_AS(2,uint64) <= 3u);])
m4_ifelse($4, [imm],
[SHAREMIND_PREPARE_ARGUMENTS_CHECK(SHAREMIND_PREPARE_ARG_AS(4,uint64) > 0u);
SHAREMIND_PREPARE_ARGUMENTS_CHECK(SHAREMIND_PREPARE_ARG_AS(4,uint64) <= 8u);])]),
NO_IMPL_SUFFIX, IMPL([
const SHAREMIND_T_CodeBlock * m4_ifelse($1, [imm], [SHAREMIND_RESTRICT]) src;
const SHAREMIND_T_CodeBlock * dest;
const SHAREMIND_T_CodeBlock * m4_ifelse($3, [imm], [SHAREMIND_RESTRICT]) destOffset;
const SHAREMIND_T_CodeBlock * m4_ifelse($4, [imm], [SHAREMIND_RESTRICT]) numBytes;
m4_ifelse($1, [imm], [],
[SHAREMIND_MI_GET_CONST_$1(src, SHAREMIND_MI_ARG_AS(1, sizet));])
m4_ifelse($2, [imm],
[dest = SHAREMIND_MI_ARG_P(2);],
[SHAREMIND_MI_GET_CONST_$2(dest, SHAREMIND_MI_ARG_AS(2, sizet));])
SHAREMIND_MI_MEM_GET_SLOT_OR_EXCEPT(SHAREMIND_MI_BLOCK_AS(dest,uint64), destSlot);
SHAREMIND_MI_TRY_EXCEPT(SHAREMIND_MI_MEM_CAN_WRITE(destSlot), SHAREMIND_VM_PROCESS_WRITE_DENIED);
m4_ifelse($3, [imm], [],
[SHAREMIND_MI_GET_CONST_$3(destOffset, SHAREMIND_MI_ARG_AS(3, sizet));])
m4_ifelse($4, [imm], [],
[SHAREMIND_MI_GET_CONST_$4(numBytes, SHAREMIND_MI_ARG_AS(4,sizet));
SHAREMIND_MI_TRY_EXCEPT(SHAREMIND_MI_BLOCK_AS(numBytes,uint64) <= 8u, SHAREMIND_VM_PROCESS_OUT_OF_BOUNDS_READ);])
m4_ifelse($3, [imm], [destOffset = SHAREMIND_MI_ARG_P(3);])
m4_ifelse($4, [imm], [numBytes = SHAREMIND_MI_ARG_P(4);])
SHAREMIND_MI_TRY_MEMRANGE(SHAREMIND_MI_MEM_GET_SIZE_FROM_SLOT(destSlot), SHAREMIND_MI_BLOCK_AS(destOffset,uint64), SHAREMIND_MI_BLOCK_AS(numBytes,uint64), SHAREMIND_VM_PROCESS_OUT_OF_BOUNDS_WRITE);
m4_ifelse($1, [imm], [src = SHAREMIND_MI_ARG_P(1);])
SHAREMIND_MEMCPY(SHAREMIND_PTRADD(SHAREMIND_MI_MEM_GET_DATA_FROM_SLOT(destSlot), SHAREMIND_MI_BLOCK_AS(destOffset,uint64)), &(SHAREMIND_MI_BLOCK_AS(src,uint64)), SHAREMIND_MI_BLOCK_AS(numBytes,uint64))]),
DO_DISPATCH, PREPARE_FINISH)])
m4_define([MOV_REGS_TO_MEM_DEFINE], [_MOV_REGS_TO_MEM_DEFINE(_ARG1$1, _ARG2$1, _ARG3$1, _ARG4$1)])
foreach([MOV_REGS_TO_MEM_DEFINE], (product(([imm], [reg], [stack]), ([imm], [reg], [stack]), ([imm], [reg], [stack]), ([imm], [reg], [stack]))))
# common.mov (mem) >> (mem)
# (1=olbsrc_part,2=olbsrcoffset,3=olbdest_part,4=olbdestoffset,5=olbnbytes)
m4_define([_MOV_MEM_TO_MEM_DEFINE], [
INSTR_DEFINE([common.mov_mem_$1_$2_mem_$3_$4_$5],
CODE(0x00, 0x01, OLB_CODE_mem_$1, OLB_CODE_$2, OLB_CODE_mem_$3, OLB_CODE_$4, OLB_CODE_$5, 0x00),
ARGS(5),
PREPARATION([
m4_ifelse($1, [imm],
[SHAREMIND_PREPARE_ARGUMENTS_CHECK(SHAREMIND_PREPARE_ARG_AS(1,uint64) >= 1u);
SHAREMIND_PREPARE_ARGUMENTS_CHECK(SHAREMIND_PREPARE_ARG_AS(1,uint64) <= 3u);])
m4_ifelse($3, [imm],
[SHAREMIND_PREPARE_ARGUMENTS_CHECK(SHAREMIND_PREPARE_ARG_AS(3,uint64) >= 1u);
SHAREMIND_PREPARE_ARGUMENTS_CHECK(SHAREMIND_PREPARE_ARG_AS(3,uint64) <= 3u);])
m4_ifelse($5, [imm],
[SHAREMIND_PREPARE_ARGUMENTS_CHECK(SHAREMIND_PREPARE_ARG_AS(5,uint64) > 0u);])]),
NO_IMPL_SUFFIX,
IMPL([
const SHAREMIND_T_CodeBlock * src;
const SHAREMIND_T_CodeBlock * m4_ifelse($2, [imm], [SHAREMIND_RESTRICT]) srcOffset;
const SHAREMIND_T_CodeBlock * dest;
const SHAREMIND_T_CodeBlock * m4_ifelse($4, [imm], [SHAREMIND_RESTRICT]) destOffset;
const SHAREMIND_T_CodeBlock * m4_ifelse($5, [imm], [SHAREMIND_RESTRICT]) numBytes;
m4_ifelse($1, [imm],
[src = SHAREMIND_MI_ARG_P(1);],
[SHAREMIND_MI_GET_CONST_$1(src, SHAREMIND_MI_ARG_AS(1, sizet));])
SHAREMIND_MI_MEM_GET_SLOT_OR_EXCEPT(SHAREMIND_MI_BLOCK_AS(src,uint64), srcSlot);
COMMENT([SHAREMIND_MI_TRY_EXCEPT(SHAREMIND_MI_MEM_CAN_READ(srcSlot), SHAREMIND_VM_PROCESS_READ_DENIED);])
m4_ifelse($2, [imm], [],
[SHAREMIND_MI_GET_CONST_$2(srcOffset, SHAREMIND_MI_ARG_AS(2, sizet));])
m4_ifelse($3, [imm],
[dest = SHAREMIND_MI_ARG_P(3);],
[SHAREMIND_MI_GET_CONST_$3(dest, SHAREMIND_MI_ARG_AS(3, sizet));])
SHAREMIND_MI_MEM_GET_SLOT_OR_EXCEPT(SHAREMIND_MI_BLOCK_AS(dest,uint64), destSlot);
SHAREMIND_MI_TRY_EXCEPT(SHAREMIND_MI_MEM_CAN_WRITE(destSlot), SHAREMIND_VM_PROCESS_WRITE_DENIED);
m4_ifelse($4, [imm], [],
[SHAREMIND_MI_GET_CONST_$4(destOffset, SHAREMIND_MI_ARG_AS(4, sizet));])
m4_ifelse($5, [imm], [],
[SHAREMIND_MI_GET_CONST_$5(numBytes, SHAREMIND_MI_ARG_AS(5, sizet));])
m4_ifelse($2, [imm], [srcOffset = SHAREMIND_MI_ARG_P(2);])
m4_ifelse($5, [imm], [numBytes = SHAREMIND_MI_ARG_P(5);])
SHAREMIND_MI_TRY_MEMRANGE(SHAREMIND_MI_MEM_GET_SIZE_FROM_SLOT(srcSlot), SHAREMIND_MI_BLOCK_AS(srcOffset,uint64), SHAREMIND_MI_BLOCK_AS(numBytes,uint64), SHAREMIND_VM_PROCESS_OUT_OF_BOUNDS_READ);
m4_ifelse($4, [imm], [destOffset = SHAREMIND_MI_ARG_P(4);])
SHAREMIND_MI_TRY_MEMRANGE(SHAREMIND_MI_MEM_GET_SIZE_FROM_SLOT(destSlot), SHAREMIND_MI_BLOCK_AS(destOffset,uint64), SHAREMIND_MI_BLOCK_AS(numBytes,uint64), SHAREMIND_VM_PROCESS_OUT_OF_BOUNDS_WRITE);
m4_pushdef([CPY_ARGS], [SHAREMIND_PTRADD(SHAREMIND_MI_MEM_GET_DATA_FROM_SLOT(destSlot), SHAREMIND_MI_BLOCK_AS(destOffset,uint64)),
SHAREMIND_PTRADD(SHAREMIND_MI_MEM_GET_DATA_FROM_SLOT(srcSlot), SHAREMIND_MI_BLOCK_AS(srcOffset,uint64)),
SHAREMIND_MI_BLOCK_AS(numBytes,uint64)])
if (srcSlot != destSlot) {
SHAREMIND_MEMCPY(CPY_ARGS);
} else {
SHAREMIND_MEMMOVE(CPY_ARGS);
}m4_popdef([CPY_ARGS])]),
DO_DISPATCH, PREPARE_FINISH)])
m4_define([MOV_MEM_TO_MEM_DEFINE], [_MOV_MEM_TO_MEM_DEFINE(_ARG1$1, _ARG2$1, _ARG3$1, _ARG4$1, _ARG5$1)])
foreach([MOV_MEM_TO_MEM_DEFINE], (product(([imm], [reg], [stack]), ([imm], [reg], [stack]), ([imm], [reg], [stack]), ([imm], [reg], [stack]), ([imm], [reg], [stack]))))
# common.mov (ref, cref) >> (reg, stack)
# (1=olbsrc,2=olbsrcoffset,3=olbdest,4=olbnbytes)
m4_define([_MOV_REF_TO_REGS_DEFINE], [
INSTR_DEFINE([common.mov_$1_$2_$3_$4],
CODE(0x00, 0x01, OLB_CODE_$1, OLB_CODE_$2, OLB_CODE_$3, 0x00, OLB_CODE_$4, 0x00),
ARGS(4),
m4_ifelse($4, [imm],
[PREPARATION([
SHAREMIND_PREPARE_ARGUMENTS_CHECK(SHAREMIND_PREPARE_ARG_AS(4,uint64) > 0u);
SHAREMIND_PREPARE_ARGUMENTS_CHECK(SHAREMIND_PREPARE_ARG_AS(4,uint64) <= 8u)])],
[NO_PREPARATION]),
NO_IMPL_SUFFIX, IMPL([
const SHAREMIND_T_[]m4_ifelse($1, [cref], [C])[]Reference * SHAREMIND_RESTRICT srcRef;
const SHAREMIND_T_CodeBlock * m4_ifelse($2, [imm], [SHAREMIND_RESTRICT]) srcOffset;
SHAREMIND_T_CodeBlock * dest;
const SHAREMIND_T_CodeBlock * m4_ifelse($4, [imm], [SHAREMIND_RESTRICT]) numBytes;
SHAREMIND_MI_GET_$1(srcRef, SHAREMIND_MI_ARG_AS(1, sizet));
COMMENT([m4_ifelse($1, [ref], [SHAREMIND_MI_TRY_EXCEPT(SHAREMIND_MI_REF_CAN_READ(srcRef), SHAREMIND_VM_PROCESS_READ_DENIED);])])
m4_ifelse($2, [imm], [],
[SHAREMIND_MI_GET_CONST_$2(srcOffset, SHAREMIND_MI_ARG_AS(2, sizet));])
SHAREMIND_MI_GET_$3(dest, SHAREMIND_MI_ARG_AS(3, sizet));
m4_ifelse($4, [imm], [],
[SHAREMIND_MI_GET_CONST_$4(numBytes, SHAREMIND_MI_ARG_AS(4,sizet));
SHAREMIND_MI_TRY_EXCEPT(SHAREMIND_MI_BLOCK_AS(numBytes,uint64) <= 8u, SHAREMIND_VM_PROCESS_OUT_OF_BOUNDS_WRITE);])
m4_ifelse($2, [imm], [srcOffset = SHAREMIND_MI_ARG_P(2);])
m4_ifelse($4, [imm], [numBytes = SHAREMIND_MI_ARG_P(4);])
SHAREMIND_MI_TRY_MEMRANGE(SHAREMIND_MI_REFERENCE_GET_SIZE(srcRef), SHAREMIND_MI_BLOCK_AS(srcOffset,uint64), SHAREMIND_MI_BLOCK_AS(numBytes,uint64), SHAREMIND_VM_PROCESS_OUT_OF_BOUNDS_READ);
m4_pushdef([CPY_ARGS], [&(SHAREMIND_MI_BLOCK_AS(dest,uint64)),
SHAREMIND_PTRADD(SHAREMIND_MI_REFERENCE_GET_CONST_PTR(srcRef), SHAREMIND_MI_BLOCK_AS(srcOffset,uint64)),
SHAREMIND_MI_BLOCK_AS(numBytes,uint64)])
m4_ifelse($3, [stack],
[SHAREMIND_MEMCPY(CPY_ARGS);],
[SHAREMIND_MEMMOVE(CPY_ARGS);])
m4_popdef([CPY_ARGS])]),
DO_DISPATCH, PREPARE_FINISH)])
m4_define([MOV_REF_TO_REGS_DEFINE], [_MOV_REF_TO_REGS_DEFINE(_ARG1$1, _ARG2$1, _ARG3$1, _ARG4$1)])
foreach([MOV_REF_TO_REGS_DEFINE], (product(([cref], [ref]), ([imm], [reg], [stack]), ([reg], [stack]), ([imm], [reg], [stack]))))
# common.mov (imm, reg, stack) >> (ref)
# (1=olbsrc,2=olbdestoffset,3=olbnbytes)
m4_define([_MOV_REGS_TO_REF_DEFINE], [
INSTR_DEFINE([common.mov_$1_ref_$2_$3],
CODE(0x00, 0x01, OLB_CODE_$1, 0x00, OLB_CODE_ref, OLB_CODE_$2, OLB_CODE_$3, 0x00),
ARGS(4),
m4_ifelse($3, [imm],
[PREPARATION([
SHAREMIND_PREPARE_ARGUMENTS_CHECK(SHAREMIND_PREPARE_ARG_AS(4,uint64) > 0u);
SHAREMIND_PREPARE_ARGUMENTS_CHECK(SHAREMIND_PREPARE_ARG_AS(4,uint64) <= 8u)])],
[NO_PREPARATION]),
NO_IMPL_SUFFIX, IMPL([
const SHAREMIND_T_CodeBlock * m4_ifelse($1, [imm], [SHAREMIND_RESTRICT]) src;
const SHAREMIND_T_Reference * SHAREMIND_RESTRICT destRef;
const SHAREMIND_T_CodeBlock * m4_ifelse($2, [imm], [SHAREMIND_RESTRICT]) destOffset;
const SHAREMIND_T_CodeBlock * m4_ifelse($3, [imm], [SHAREMIND_RESTRICT]) numBytes;
m4_ifelse($1, [imm], [],
[SHAREMIND_MI_GET_CONST_$1(src, SHAREMIND_MI_ARG_AS(1, sizet));])
SHAREMIND_MI_GET_ref(destRef, SHAREMIND_MI_ARG_AS(2, sizet));
m4_ifelse($2, [imm], [],
[SHAREMIND_MI_GET_CONST_$2(destOffset, SHAREMIND_MI_ARG_AS(3, sizet));])
m4_ifelse($3, [imm], [],
[SHAREMIND_MI_GET_CONST_$3(numBytes, SHAREMIND_MI_ARG_AS(4,sizet));
SHAREMIND_MI_TRY_EXCEPT(SHAREMIND_MI_BLOCK_AS(numBytes,uint64) <= 8u, SHAREMIND_VM_PROCESS_OUT_OF_BOUNDS_READ);])
m4_ifelse($2, [imm], [destOffset = SHAREMIND_MI_ARG_P(3);])
m4_ifelse($3, [imm], [numBytes = SHAREMIND_MI_ARG_P(4);])
SHAREMIND_MI_TRY_MEMRANGE(SHAREMIND_MI_REFERENCE_GET_SIZE(destRef), SHAREMIND_MI_BLOCK_AS(destOffset,uint64), SHAREMIND_MI_BLOCK_AS(numBytes,uint64), SHAREMIND_VM_PROCESS_OUT_OF_BOUNDS_WRITE);
m4_ifelse($1, [imm], [src = SHAREMIND_MI_ARG_P(1);])
m4_pushdef([CPY_ARGS], [SHAREMIND_PTRADD(SHAREMIND_MI_REFERENCE_GET_PTR(destRef), SHAREMIND_MI_BLOCK_AS(destOffset,uint64)),
&(SHAREMIND_MI_BLOCK_AS(src,uint64)),
SHAREMIND_MI_BLOCK_AS(numBytes,uint64)])
m4_ifelse($1, [reg],
[SHAREMIND_MEMMOVE(CPY_ARGS);],
[SHAREMIND_MEMCPY(CPY_ARGS)])m4_popdef([CPY_ARGS])]),
DO_DISPATCH, PREPARE_FINISH)])
m4_define([MOV_REGS_TO_REF_DEFINE], [_MOV_REGS_TO_REF_DEFINE(_ARG1$1, _ARG2$1, _ARG3$1)])
foreach([MOV_REGS_TO_REF_DEFINE], (product(([imm], [reg], [stack]), ([imm], [reg], [stack]), ([imm], [reg], [stack]))))
# common.mov (cref, ref) >> (ref)
# (1=olbsrc,2=olbsrcoffset,3=olbdestoffset,4=olbnbytes)
m4_define([_MOV_REF_TO_REF_DEFINE], [
INSTR_DEFINE([common.mov_$1_$2_ref_$3_$4],
CODE(0x00, 0x01, OLB_CODE_$1, OLB_CODE_$2, OLB_CODE_ref, OLB_CODE_$3, OLB_CODE_$4, 0x00),
ARGS(5),
m4_ifelse($4, [imm],
[PREPARATION([
SHAREMIND_PREPARE_ARGUMENTS_CHECK(SHAREMIND_PREPARE_ARG_AS(5,uint64) > 0u)])],
[NO_PREPARATION]),
NO_IMPL_SUFFIX,
IMPL([
const SHAREMIND_T_[]m4_ifelse($1, [cref], [C])Reference * srcRef;
const SHAREMIND_T_CodeBlock * m4_ifelse($2, [imm], [SHAREMIND_RESTRICT]) srcOffset;
const SHAREMIND_T_Reference * destRef;
const SHAREMIND_T_CodeBlock * m4_ifelse($3, [imm], [SHAREMIND_RESTRICT]) destOffset;
const SHAREMIND_T_CodeBlock * m4_ifelse($4, [imm], [SHAREMIND_RESTRICT]) numBytes;
SHAREMIND_MI_GET_$1(srcRef, SHAREMIND_MI_ARG_AS(1, sizet));
COMMENT([m4_ifelse($1, [ref], [SHAREMIND_MI_TRY_EXCEPT(SHAREMIND_MI_REF_CAN_READ(srcRef), SHAREMIND_VM_PROCESS_READ_DENIED);])])
m4_ifelse($2, [imm], [],
[SHAREMIND_MI_GET_CONST_$2(srcOffset, SHAREMIND_MI_ARG_AS(2, sizet));])
SHAREMIND_MI_GET_ref(destRef, SHAREMIND_MI_ARG_AS(3, sizet));
m4_ifelse($3, [imm], [],
[SHAREMIND_MI_GET_CONST_$3(destOffset, SHAREMIND_MI_ARG_AS(4, sizet));])
m4_ifelse($4, [imm], [],
[SHAREMIND_MI_GET_CONST_$4(numBytes, SHAREMIND_MI_ARG_AS(5,sizet));])
m4_ifelse($2, [imm], [srcOffset = SHAREMIND_MI_ARG_P(2);])
m4_ifelse($4, [imm], [numBytes = SHAREMIND_MI_ARG_P(5);])
SHAREMIND_MI_TRY_MEMRANGE(SHAREMIND_MI_REFERENCE_GET_SIZE(srcRef), SHAREMIND_MI_BLOCK_AS(srcOffset,uint64), SHAREMIND_MI_BLOCK_AS(numBytes,uint64), SHAREMIND_VM_PROCESS_OUT_OF_BOUNDS_READ);
m4_ifelse($3, [imm], [destOffset = SHAREMIND_MI_ARG_P(4);])
SHAREMIND_MI_TRY_MEMRANGE(SHAREMIND_MI_REFERENCE_GET_SIZE(destRef), SHAREMIND_MI_BLOCK_AS(destOffset,uint64), SHAREMIND_MI_BLOCK_AS(numBytes,uint64), SHAREMIND_VM_PROCESS_OUT_OF_BOUNDS_WRITE);
m4_pushdef([CPY_ARGS], [SHAREMIND_PTRADD(SHAREMIND_MI_REFERENCE_GET_PTR(destRef), SHAREMIND_MI_BLOCK_AS(destOffset,uint64)),
SHAREMIND_PTRADD(SHAREMIND_MI_REFERENCE_GET_CONST_PTR(srcRef), SHAREMIND_MI_BLOCK_AS(srcOffset,uint64)),
SHAREMIND_MI_BLOCK_AS(numBytes,uint64)])
SHAREMIND_MEMMOVE(CPY_ARGS);m4_popdef([CPY_ARGS])]),
DO_DISPATCH, PREPARE_FINISH)])
m4_define([MOV_REF_TO_REF_DEFINE], [_MOV_REF_TO_REF_DEFINE(_ARG1$1, _ARG2$1, _ARG3$1, _ARG4$1)])
foreach([MOV_REF_TO_REF_DEFINE], (product(([cref], [ref]), ([imm], [reg], [stack]), ([imm], [reg], [stack]), ([imm], [reg], [stack]))))
# common.mov (cref, ref) >> (mem)
# (1=olbsrc,2=olbsrcoffset,3=olbdest_part,4=olbdestoffset,5=olbnbytes)
m4_define([_MOV_REF_TO_MEM_DEFINE], [
INSTR_DEFINE([common.mov_$1_$2_mem_$3_$4_$5],
CODE(0x00, 0x01, OLB_CODE_$1, OLB_CODE_$2, OLB_CODE_mem_$3, OLB_CODE_$4, OLB_CODE_$5, 0x00),
ARGS(5),
PREPARATION([
m4_ifelse($3, [imm],
[SHAREMIND_PREPARE_ARGUMENTS_CHECK(SHAREMIND_PREPARE_ARG_AS(3,uint64) >= 1u);
SHAREMIND_PREPARE_ARGUMENTS_CHECK(SHAREMIND_PREPARE_ARG_AS(3,uint64) <= 3u);])
m4_ifelse($5, [imm],
[SHAREMIND_PREPARE_ARGUMENTS_CHECK(SHAREMIND_PREPARE_ARG_AS(5,uint64) > 0u);])]),
NO_IMPL_SUFFIX,
IMPL([
const SHAREMIND_T_[]m4_ifelse($1, [cref], [C])Reference * SHAREMIND_RESTRICT srcRef;
const SHAREMIND_T_CodeBlock * m4_ifelse($2, [imm], [SHAREMIND_RESTRICT]) srcOffset;
const SHAREMIND_T_CodeBlock * SHAREMIND_RESTRICT dest;
const SHAREMIND_T_CodeBlock * m4_ifelse($4, [imm], [SHAREMIND_RESTRICT]) destOffset;
const SHAREMIND_T_CodeBlock * m4_ifelse($5, [imm], [SHAREMIND_RESTRICT]) numBytes;
SHAREMIND_MI_GET_$1(srcRef, SHAREMIND_MI_ARG_AS(1, sizet));
COMMENT([m4_ifelse($1, [ref], [SHAREMIND_MI_TRY_EXCEPT(SHAREMIND_MI_REF_CAN_READ(srcRef), SHAREMIND_VM_PROCESS_READ_DENIED);])])
m4_ifelse($2, [imm], [],
[SHAREMIND_MI_GET_CONST_$2(srcOffset, SHAREMIND_MI_ARG_AS(2, sizet));])
m4_ifelse($3, [imm],
[dest = SHAREMIND_MI_ARG_P(3);],
[SHAREMIND_MI_GET_CONST_$3(dest, SHAREMIND_MI_ARG_AS(3, sizet));])
SHAREMIND_MI_MEM_GET_SLOT_OR_EXCEPT(SHAREMIND_MI_BLOCK_AS(dest,uint64), destSlot);
SHAREMIND_MI_TRY_EXCEPT(SHAREMIND_MI_MEM_CAN_WRITE(destSlot), SHAREMIND_VM_PROCESS_WRITE_DENIED);
m4_ifelse($4, [imm], [],
[SHAREMIND_MI_GET_CONST_$4(destOffset, SHAREMIND_MI_ARG_AS(4, sizet));])
m4_ifelse($5, [imm], [],
[SHAREMIND_MI_GET_CONST_$5(numBytes, SHAREMIND_MI_ARG_AS(5,sizet));])
m4_ifelse($2, [imm], [srcOffset = SHAREMIND_MI_ARG_P(2);])
m4_ifelse($5, [imm], [numBytes = SHAREMIND_MI_ARG_P(5);])
SHAREMIND_MI_TRY_MEMRANGE(SHAREMIND_MI_REFERENCE_GET_SIZE(srcRef), SHAREMIND_MI_BLOCK_AS(srcOffset,uint64), SHAREMIND_MI_BLOCK_AS(numBytes,uint64), SHAREMIND_VM_PROCESS_OUT_OF_BOUNDS_READ);
m4_ifelse($4, [imm], [destOffset = SHAREMIND_MI_ARG_P(4);])
SHAREMIND_MI_TRY_MEMRANGE(SHAREMIND_MI_MEM_GET_SIZE_FROM_SLOT(destSlot), SHAREMIND_MI_BLOCK_AS(destOffset,uint64), SHAREMIND_MI_BLOCK_AS(numBytes,uint64), SHAREMIND_VM_PROCESS_OUT_OF_BOUNDS_WRITE);
m4_pushdef([CPY_ARGS], [SHAREMIND_PTRADD(SHAREMIND_MI_MEM_GET_DATA_FROM_SLOT(destSlot), SHAREMIND_MI_BLOCK_AS(destOffset,uint64)),
SHAREMIND_PTRADD(SHAREMIND_MI_REFERENCE_GET_CONST_PTR(srcRef), SHAREMIND_MI_BLOCK_AS(srcOffset,uint64)),
SHAREMIND_MI_BLOCK_AS(numBytes,uint64)])
SHAREMIND_MEMMOVE(CPY_ARGS);m4_popdef([CPY_ARGS])]),
DO_DISPATCH, PREPARE_FINISH)])
m4_define([MOV_REF_TO_MEM_DEFINE], [_MOV_REF_TO_MEM_DEFINE(_ARG1$1, _ARG2$1, _ARG3$1, _ARG4$1, _ARG5$1)])
foreach([MOV_REF_TO_MEM_DEFINE], (product(([cref], [ref]), ([imm], [reg], [stack]), ([reg], [stack]), ([imm], [reg], [stack]), ([imm], [reg], [stack]))))
# common.mov (mem) >> (ref)
# (1=olbsrc_part,2=olbsrcoffset,3=olbdestoffset,4=olbnbytes)
m4_define([_MOV_MEM_TO_REF_DEFINE], [
INSTR_DEFINE([common.mov_mem_$1_$2_ref_$3_$4],
CODE(0x00, 0x01, OLB_CODE_mem_$1, OLB_CODE_$2, OLB_CODE_ref, OLB_CODE_$3, OLB_CODE_$4, 0x00),
ARGS(5),
PREPARATION([
m4_ifelse($1, [imm],
[SHAREMIND_PREPARE_ARGUMENTS_CHECK(SHAREMIND_PREPARE_ARG_AS(1,uint64) >= 1u);
SHAREMIND_PREPARE_ARGUMENTS_CHECK(SHAREMIND_PREPARE_ARG_AS(1,uint64) <= 3u);])
m4_ifelse($4, [imm],
[SHAREMIND_PREPARE_ARGUMENTS_CHECK(SHAREMIND_PREPARE_ARG_AS(5,uint64) > 0u)])]),
NO_IMPL_SUFFIX,
IMPL([
const SHAREMIND_T_CodeBlock * SHAREMIND_RESTRICT src;
const SHAREMIND_T_CodeBlock * m4_ifelse($2, [imm], [SHAREMIND_RESTRICT]) srcOffset;
const SHAREMIND_T_Reference * SHAREMIND_RESTRICT destRef;
const SHAREMIND_T_CodeBlock * m4_ifelse($3, [imm], [SHAREMIND_RESTRICT]) destOffset;
const SHAREMIND_T_CodeBlock * m4_ifelse($4, [imm], [SHAREMIND_RESTRICT]) numBytes;
m4_ifelse($1, [imm],
[src = SHAREMIND_MI_ARG_P(1);],
[SHAREMIND_MI_GET_CONST_$1(src, SHAREMIND_MI_ARG_AS(1, sizet));])
SHAREMIND_MI_MEM_GET_SLOT_OR_EXCEPT(SHAREMIND_MI_BLOCK_AS(src,uint64), srcSlot);
COMMENT([SHAREMIND_MI_TRY_EXCEPT(SHAREMIND_MI_MEM_CAN_READ(srcSlot), SHAREMIND_VM_PROCESS_READ_DENIED);])
m4_ifelse($2, [imm], [],
[SHAREMIND_MI_GET_CONST_$2(srcOffset, SHAREMIND_MI_ARG_AS(2, sizet));])
SHAREMIND_MI_GET_ref(destRef, SHAREMIND_MI_ARG_AS(3, sizet));
m4_ifelse($3, [imm], [],
[SHAREMIND_MI_GET_CONST_$3(destOffset, SHAREMIND_MI_ARG_AS(4, sizet));])
m4_ifelse($4, [imm], [],
[SHAREMIND_MI_GET_CONST_$4(numBytes, SHAREMIND_MI_ARG_AS(5,sizet));])
m4_ifelse($2, [imm], [srcOffset = SHAREMIND_MI_ARG_P(2);])
m4_ifelse($4, [imm], [numBytes = SHAREMIND_MI_ARG_P(5);])
SHAREMIND_MI_TRY_MEMRANGE(SHAREMIND_MI_MEM_GET_SIZE_FROM_SLOT(srcSlot), SHAREMIND_MI_BLOCK_AS(srcOffset,uint64), SHAREMIND_MI_BLOCK_AS(numBytes,uint64), SHAREMIND_VM_PROCESS_OUT_OF_BOUNDS_READ);
m4_ifelse($3, [imm], [destOffset = SHAREMIND_MI_ARG_P(4);])
SHAREMIND_MI_TRY_MEMRANGE(SHAREMIND_MI_REFERENCE_GET_SIZE(destRef), SHAREMIND_MI_BLOCK_AS(destOffset,uint64), SHAREMIND_MI_BLOCK_AS(numBytes,uint64), SHAREMIND_VM_PROCESS_OUT_OF_BOUNDS_WRITE);
m4_pushdef([CPY_ARGS], [SHAREMIND_PTRADD(SHAREMIND_MI_REFERENCE_GET_PTR(destRef), SHAREMIND_MI_BLOCK_AS(destOffset,uint64)),
SHAREMIND_PTRADD(SHAREMIND_MI_MEM_GET_DATA_FROM_SLOT(srcSlot), SHAREMIND_MI_BLOCK_AS(srcOffset,uint64)),
SHAREMIND_MI_BLOCK_AS(numBytes,uint64)])
SHAREMIND_MEMMOVE(CPY_ARGS);m4_popdef([CPY_ARGS])]),
DO_DISPATCH, PREPARE_FINISH)])
m4_define([MOV_MEM_TO_REF_DEFINE], [_MOV_MEM_TO_REF_DEFINE(_ARG1$1, _ARG2$1, _ARG3$1, _ARG4$1)])
foreach([MOV_MEM_TO_REF_DEFINE], (product(([reg], [stack]), ([imm], [reg], [stack]), ([imm], [reg], [stack]), ([imm], [reg], [stack]))))
m4_define([CHECK_CALL_TARGET], [SHAREMIND_PREPARE_ARGUMENTS_CHECK(SHAREMIND_PREPARE_IS_INSTR($1));])
# common.proc.call
m4_define([_CALL_DEFINE], [
INSTR_DEFINE([common.proc.call_$1_$2],
CODE(0x00, 0x02, 0x00, OLB_CODE_$1, OLB_CODE_$2, 0x00, 0x00, 0x00),
ARGS(m4_ifelse($2, [imm], 1, 2)),
m4_ifelse($1, [imm], CHECK_CALL_TARGET(SHAREMIND_PREPARE_ARG_AS(1,sizet)), NO_PREPARATION),
NO_IMPL_SUFFIX,
IMPL([
const SHAREMIND_T_CodeBlock * m4_ifelse($1, [imm], [SHAREMIND_RESTRICT]) addr;
m4_ifelse($2, [imm], [], [SHAREMIND_T_CodeBlock * rv;])
m4_ifelse($1, [imm], [],
[SHAREMIND_MI_GET_CONST_$1(addr, SHAREMIND_MI_ARG_AS(1, sizet));])
m4_ifelse($2, [imm], [],
[SHAREMIND_MI_GET_$2(rv, SHAREMIND_MI_ARG_AS(2, sizet));])
m4_ifelse($1, [imm], [addr = SHAREMIND_MI_ARG_P(1);])
m4_ifelse($1, [imm],
[SHAREMIND_MI_CALL(SHAREMIND_MI_BLOCK_AS(addr, sizet),m4_ifelse($2, [imm], [SHAREMIND_NULL], [rv]), m4_ifelse($2, [imm], [1], [2]))],
[SHAREMIND_MI_CHECK_CALL(addr,m4_ifelse($2, [imm], [SHAREMIND_NULL], [rv]), m4_ifelse($2, [imm], [1], [2]))])]),
NO_DISPATCH, PREPARE_FINISH)
])
m4_define([CALL_DEFINE], [_CALL_DEFINE(_ARG1$1, _ARG2$1)])
foreach([CALL_DEFINE], (product(([[imm]], [[reg]], [[stack]]),([[imm]], [[reg]], [[stack]]))))
# common.proc.syscall
m4_define([_SYSCALL_DEFINE], [
INSTR_DEFINE([common.proc.syscall_$1_$2],
CODE(0x00, 0x02, 0x02, OLB_CODE_$1, OLB_CODE_$2, 0x00, 0x00, 0x00),
ARGS(m4_ifelse($2, [imm], 1, 2)),
m4_ifelse($1, [imm],
[SHAREMIND_PREPARE_SYSCALL(1);],
NO_PREPARATION),
NO_IMPL_SUFFIX,
IMPL([
const SHAREMIND_T_CodeBlock * m4_ifelse($1, [imm], [SHAREMIND_RESTRICT]) addr;
m4_ifelse($2, [imm], [], [SHAREMIND_T_CodeBlock * rv;])
m4_ifelse($1, [imm], [],
[SHAREMIND_MI_GET_CONST_$1(addr, SHAREMIND_MI_ARG_AS(1, sizet));])
m4_ifelse($2, [imm], [],
[SHAREMIND_MI_GET_$2(rv, SHAREMIND_MI_ARG_AS(2, sizet));])
m4_ifelse($1, [imm], [addr = SHAREMIND_MI_ARG_P(1);])
m4_ifelse($1, [imm],
[SHAREMIND_MI_SYSCALL(addr,m4_ifelse($2, [imm], [SHAREMIND_NULL], [rv]))],
[SHAREMIND_MI_CHECK_SYSCALL(addr,m4_ifelse($2, [imm], [SHAREMIND_NULL], [rv]))])]),
DO_DISPATCH, PREPARE_FINISH)
])
m4_define([SYSCALL_DEFINE], [_SYSCALL_DEFINE(_ARG1$1, _ARG2$1)])
foreach([SYSCALL_DEFINE], (product(([[imm]], [[reg]], [[stack]]),([[imm]], [[reg]], [[stack]]))))
# common.proc.return
m4_define([RETURN_DEFINE], [
INSTR_DEFINE([common.proc.return_$1],
CODE(0x00, 0x02, 0x03, OLB_CODE_$1, 0x00, 0x00, 0x00, 0x00),
ARGS(1), NO_PREPARATION, NO_IMPL_SUFFIX,
IMPL([
const SHAREMIND_T_CodeBlock * SHAREMIND_RESTRICT v;
m4_ifelse($1, [imm],
[v = SHAREMIND_MI_ARG_P(1);],
[SHAREMIND_MI_GET_CONST_$1(v, SHAREMIND_MI_ARG_AS(1, sizet));])
SHAREMIND_MI_RETURN(*v);]),
NO_DISPATCH, PREPARE_FINISH)])
RETURN_DEFINE([imm])
RETURN_DEFINE([reg])
RETURN_DEFINE([stack])
# common.proc.push
m4_define([PUSH_DEFINE], [
INSTR_DEFINE([common.proc.push_$1],
CODE(0x00, 0x02, 0x04, OLB_CODE_$1, 0x00, 0x00, 0x00, 0x00),
ARGS(1), NO_PREPARATION, NO_IMPL_SUFFIX,
IMPL([
const SHAREMIND_T_CodeBlock * SHAREMIND_RESTRICT v;
m4_ifelse($1, [imm],
[v = SHAREMIND_MI_ARG_P(1);],
[SHAREMIND_MI_GET_CONST_$1(v, SHAREMIND_MI_ARG_AS(1, sizet));])
SHAREMIND_MI_PUSH(*v);]),
DO_DISPATCH, PREPARE_FINISH)])
PUSH_DEFINE([imm])
PUSH_DEFINE([reg])
PUSH_DEFINE([stack])
# common.proc.pushref (reg, stack) + common.proc.pushcref (imm, reg, stack)
# (1=ref_or_cref,2=olbsrc)
m4_define([_PUSHREF_BLOCK_DEFINE], [
INSTR_DEFINE([common.proc.push$1_$2],
CODE(0x00, 0x02, m4_ifelse($1, [ref], [0x05], [0x07]), OLB_CODE_$2, 0x00, 0x00, 0x00, 0x00),
ARGS(1), NO_PREPARATION, NO_IMPL_SUFFIX,
IMPL([
m4_ifelse($1, [cref], [const]) SHAREMIND_T_CodeBlock * SHAREMIND_RESTRICT b;
m4_ifelse($2, [imm],
[b = SHAREMIND_MI_ARG_P(1);],
$1, [cref],
[SHAREMIND_MI_GET_CONST_$2(b, SHAREMIND_MI_ARG_AS(1, sizet));],
[SHAREMIND_MI_GET_$2(b, SHAREMIND_MI_ARG_AS(1, sizet));])
SHAREMIND_MI_PUSHREF_BLOCK_$1(b)]),
DO_DISPATCH, PREPARE_FINISH)])
m4_define([PUSHREF_BLOCK_DEFINE], [_PUSHREF_BLOCK_DEFINE(_ARG1$1, _ARG2$1)])
foreach([PUSHREF_BLOCK_DEFINE], (product(([cref], [ref]), ([reg], [stack]))))
_PUSHREF_BLOCK_DEFINE([cref], [imm])
# common.proc.pushref (ref) + common.proc.pushcref (ref, cref)
# (1=ref_or_cref,2=olbsrc)
m4_define([PUSHREF_REF_DEFINE], [
INSTR_DEFINE([common.proc.push$1_$2],
CODE(0x00, 0x02, m4_ifelse($1, [ref], [0x05], [0x07]), OLB_CODE_$2, 0x00, 0x00, 0x00, 0x00),
ARGS(1), NO_PREPARATION, NO_IMPL_SUFFIX,
IMPL([
const SHAREMIND_T_[]m4_ifelse($2, [cref], [C])Reference * SHAREMIND_RESTRICT srcRef;
SHAREMIND_MI_GET_$2(srcRef, SHAREMIND_MI_ARG_AS(1, sizet));
COMMENT([
m4_ifelse($1, [ref], [], $2, [cref], [],
[SHAREMIND_MI_TRY_EXCEPT(SHAREMIND_MI_REF_CAN_READ(srcRef),
SHAREMIND_VM_PROCESS_INVALID_ARGUMENT);])
])
SHAREMIND_MI_PUSHREF_REF_$1(*srcRef)]),
DO_DISPATCH, PREPARE_FINISH)])
PUSHREF_REF_DEFINE([cref], [cref])
PUSHREF_REF_DEFINE([cref], [ref])
PUSHREF_REF_DEFINE([ref], [ref])
# common.proc.pushref (mem) + common.proc.pushcref (mem)
# (1=ref_or_cref,2=olbsrc_part)
m4_define([_PUSHREF_MEM_DEFINE], [
INSTR_DEFINE([common.proc.push$1_mem_$2],
CODE(0x00, 0x02, m4_ifelse($1, [ref], [0x05], [0x07]), OLB_CODE_mem_$2, 0x00, 0x00, 0x00, 0x00),
ARGS(1), NO_PREPARATION, NO_IMPL_SUFFIX,
IMPL([
const SHAREMIND_T_CodeBlock * SHAREMIND_RESTRICT srcPtr;
SHAREMIND_MI_GET_CONST_$2(srcPtr, SHAREMIND_MI_ARG_AS(1, sizet));
SHAREMIND_MI_MEM_GET_SLOT_OR_EXCEPT(SHAREMIND_MI_BLOCK_AS(srcPtr,uint64), srcSlot);
COMMENT([
SHAREMIND_MI_TRY_EXCEPT(
SHAREMIND_MI_MEM_CAN_[]m4_ifelse($1, [cref], [READ], [WRITE])(
srcSlot),
SHAREMIND_VM_PROCESS_INVALID_ARGUMENT);
])
m4_ifelse($1, [ref], [SHAREMIND_MI_TRY_EXCEPT(SHAREMIND_MI_MEM_CAN_WRITE(srcSlot), SHAREMIND_VM_PROCESS_INVALID_ARGUMENT);])
SHAREMIND_MI_PUSHREF_MEM_$1(srcSlot)]),
DO_DISPATCH, PREPARE_FINISH)])
m4_define([PUSHREF_MEM_DEFINE], [_PUSHREF_MEM_DEFINE(_ARG1$1, _ARG2$1)])
foreach([PUSHREF_MEM_DEFINE], (product(([cref], [ref]), ([reg], [stack]))))
# common.proc.pushrefpart (reg, stack) + common.proc.pushcrefpart (imm, reg, stack)
# (1=ref_or_cref,2=olbsrc,3=olbsrcoffset,4=olblength)
m4_define([_PUSHREFPART_BLOCK_DEFINE], [
INSTR_DEFINE([common.proc.push$1part_$2_$3_$4],
CODE(0x00, 0x02, m4_ifelse($1, [ref], [0x06], [0x08]), OLB_CODE_$2, OLB_CODE_$3, OLB_CODE_$4, 0x00, 0x00),
ARGS(3),
m4_ifelse($3_$4, [imm_imm],
PREPARATION([
SHAREMIND_PREPARE_ARGUMENTS_CHECK(SHAREMIND_PREPARE_ARG_AS(2,uint64) < 7u);
SHAREMIND_PREPARE_ARGUMENTS_CHECK(SHAREMIND_PREPARE_ARG_AS(3,uint64) <= 8u);
SHAREMIND_PREPARE_ARGUMENTS_CHECK(SHAREMIND_PREPARE_ARG_AS(2,uint64) + SHAREMIND_PREPARE_ARG_AS(3,uint64) <= 8u)]),
$3, [imm],
PREPARATION([
SHAREMIND_PREPARE_ARGUMENTS_CHECK(SHAREMIND_PREPARE_ARG_AS(2,uint64) < 7u)]),
$4, [imm],
PREPARATION([
SHAREMIND_PREPARE_ARGUMENTS_CHECK(SHAREMIND_PREPARE_ARG_AS(3,uint64) <= 8u)]),
NO_PREPARATION),
NO_IMPL_SUFFIX,
IMPL([
m4_ifelse($1, [cref], [const]) SHAREMIND_T_CodeBlock * m4_ifelse($2, [imm], [SHAREMIND_RESTRICT]) b;
const SHAREMIND_T_CodeBlock * m4_ifelse($3, [imm], [SHAREMIND_RESTRICT]) offset;
const SHAREMIND_T_CodeBlock * m4_ifelse($4, [imm], [SHAREMIND_RESTRICT]) nBytes;
m4_ifelse($2, [imm],
[b = SHAREMIND_MI_ARG_P(1);],
$1, [cref],
[SHAREMIND_MI_GET_CONST_$2(b, SHAREMIND_MI_ARG_AS(1, sizet));],
[SHAREMIND_MI_GET_$2(b, SHAREMIND_MI_ARG_AS(1, sizet));])
m4_ifelse($3, [imm],
[offset = SHAREMIND_MI_ARG_P(2);],
[SHAREMIND_MI_GET_CONST_$3(offset, SHAREMIND_MI_ARG_AS(2, sizet));
SHAREMIND_MI_TRY_EXCEPT(SHAREMIND_MI_BLOCK_AS(offset, uint64) < 7u,
SHAREMIND_VM_PROCESS_OUT_OF_BOUNDS_REFERENCE_INDEX);])
m4_ifelse($4, [imm],
[nBytes = SHAREMIND_MI_ARG_P(3);],
[SHAREMIND_MI_GET_CONST_$4(nBytes, SHAREMIND_MI_ARG_AS(3, sizet));
SHAREMIND_MI_TRY_EXCEPT(SHAREMIND_MI_BLOCK_AS(nBytes, uint64) <= 8u,
SHAREMIND_VM_PROCESS_OUT_OF_BOUNDS_REFERENCE_SIZE);])
m4_ifelse($3_$4, [imm_imm], [],
[SHAREMIND_MI_TRY_EXCEPT(SHAREMIND_MI_BLOCK_AS(offset, uint64) + SHAREMIND_MI_BLOCK_AS(nBytes, uint64) <= 8u,
SHAREMIND_VM_PROCESS_OUT_OF_BOUNDS_REFERENCE_SIZE);])
SHAREMIND_MI_PUSHREFPART_BLOCK_$1(b,SHAREMIND_MI_BLOCK_AS(offset,uint64),SHAREMIND_MI_BLOCK_AS(nBytes,uint64))]),
DO_DISPATCH, PREPARE_FINISH)])
m4_define([PUSHREFPART_BLOCK_DEFINE], [_PUSHREFPART_BLOCK_DEFINE(_ARG1$1, _ARG2$1, _ARG3$1, _ARG4$1)])
foreach([PUSHREFPART_BLOCK_DEFINE], (product(([cref], [ref]), ([reg], [stack]), ([imm], [reg], [stack]), ([imm], [reg], [stack]))))
foreach([PUSHREFPART_BLOCK_DEFINE], (product(([cref]), ([imm]), ([imm], [reg], [stack]), ([imm], [reg], [stack]))))
# common.proc.pushrefpart (ref) + common.proc.pushcrefpart (ref, cref)
# (1=ref_or_cref,2=olbsrc,3=olbsrcoffset,4=olblength)
m4_define([_PUSHREFPART_REF_DEFINE], [
INSTR_DEFINE([common.proc.push$1part_$2_$3_$4],
CODE(0x00, 0x02, m4_ifelse($1, [ref], [0x06], [0x08]), OLB_CODE_$2, OLB_CODE_$3, OLB_CODE_$4, 0x00, 0x00),
ARGS(3),
NO_PREPARATION,
NO_IMPL_SUFFIX,
IMPL([
const SHAREMIND_T_[]m4_ifelse($2, [cref], [C])Reference * SHAREMIND_RESTRICT srcRef;
const SHAREMIND_T_CodeBlock * m4_ifelse($3, [imm], [SHAREMIND_RESTRICT]) offset;
const SHAREMIND_T_CodeBlock * m4_ifelse($3, [imm], [SHAREMIND_RESTRICT]) nBytes;
SHAREMIND_MI_GET_$2(srcRef, SHAREMIND_MI_ARG_AS(1, sizet));
COMMENT([
m4_ifelse($1, [ref], [], $2, [cref], [],
[SHAREMIND_MI_TRY_EXCEPT(SHAREMIND_MI_REF_CAN_READ(srcRef),
SHAREMIND_VM_PROCESS_INVALID_ARGUMENT);])
])
m4_ifelse($3, [imm],
[offset = SHAREMIND_MI_ARG_P(2);],
[SHAREMIND_MI_GET_CONST_$3(offset, SHAREMIND_MI_ARG_AS(2, sizet));])
SHAREMIND_MI_TRY_EXCEPT(SHAREMIND_MI_BLOCK_AS(offset,sizet) < SHAREMIND_MI_REFERENCE_GET_SIZE(srcRef),
SHAREMIND_VM_PROCESS_OUT_OF_BOUNDS_REFERENCE_INDEX);
m4_ifelse($4, [imm],
[nBytes = SHAREMIND_MI_ARG_P(3);],
[SHAREMIND_MI_GET_CONST_$4(nBytes, SHAREMIND_MI_ARG_AS(3, sizet));])
SHAREMIND_MI_TRY_EXCEPT(SHAREMIND_MI_BLOCK_AS(nBytes,uint64) <= SHAREMIND_MI_REFERENCE_GET_SIZE(srcRef),
SHAREMIND_VM_PROCESS_OUT_OF_BOUNDS_REFERENCE_SIZE);
SHAREMIND_MI_TRY_EXCEPT(SHAREMIND_MI_BLOCK_AS(offset,uint64) <= SHAREMIND_MI_REFERENCE_GET_SIZE(srcRef) - SHAREMIND_MI_BLOCK_AS(nBytes,uint64),
SHAREMIND_VM_PROCESS_OUT_OF_BOUNDS_REFERENCE_SIZE);
SHAREMIND_MI_PUSHREFPART_REF_$1(srcRef, SHAREMIND_MI_BLOCK_AS(offset,uint64), SHAREMIND_MI_BLOCK_AS(nBytes,uint64))]),
DO_DISPATCH, PREPARE_FINISH)])
m4_define([PUSHREFPART_REF_DEFINE], [_PUSHREFPART_REF_DEFINE(_ARG1$1, _ARG2$1, _ARG3$1, _ARG4$1)])
foreach([PUSHREFPART_REF_DEFINE], (product(([cref], [ref]), ([ref]), ([imm], [reg], [stack]), ([imm], [reg], [stack]))))
foreach([PUSHREFPART_REF_DEFINE], (product(([cref]), ([cref]), ([imm], [reg], [stack]), ([imm], [reg], [stack]))))
# common.proc.pushrefpart (mem) + common.proc.pushcrefpart (mem)
# (1=ref_or_cref,2=olbsrc_part,3=olbsrcoffset,4=olblength)
m4_define([_PUSHREFPART_MEM_DEFINE], [
INSTR_DEFINE([common.proc.push$1part_mem_$2_$3_$4],
CODE(0x00, 0x02, m4_ifelse($1, [ref], [0x06], [0x08]), OLB_CODE_mem_$2, OLB_CODE_$3, OLB_CODE_$4, 0x00, 0x00),
ARGS(3),
NO_PREPARATION,
NO_IMPL_SUFFIX,
IMPL([
const SHAREMIND_T_CodeBlock * srcPtr;
const SHAREMIND_T_CodeBlock * m4_ifelse($2, [imm], [SHAREMIND_RESTRICT]) offset;
const SHAREMIND_T_CodeBlock * m4_ifelse($2, [imm], [SHAREMIND_RESTRICT]) nBytes;
SHAREMIND_MI_GET_CONST_$2(srcPtr, SHAREMIND_MI_ARG_AS(1, sizet));
SHAREMIND_MI_MEM_GET_SLOT_OR_EXCEPT(SHAREMIND_MI_BLOCK_AS(srcPtr,uint64), srcSlot);
COMMENT([
SHAREMIND_MI_TRY_EXCEPT(
SHAREMIND_MI_MEM_CAN_[]m4_ifelse($1, [cref], [READ], [WRITE])(
srcSlot),
SHAREMIND_VM_PROCESS_INVALID_ARGUMENT);
])
m4_ifelse($1, [ref], [SHAREMIND_MI_TRY_EXCEPT(SHAREMIND_MI_MEM_CAN_WRITE(srcSlot), SHAREMIND_VM_PROCESS_INVALID_ARGUMENT);])
m4_ifelse($3, [imm],
[offset = SHAREMIND_MI_ARG_P(2);],
[SHAREMIND_MI_GET_CONST_$3(offset, SHAREMIND_MI_ARG_AS(2, sizet));])
SHAREMIND_MI_TRY_EXCEPT(SHAREMIND_MI_BLOCK_AS(offset,sizet) < SHAREMIND_MI_MEM_GET_SIZE_FROM_SLOT(srcSlot),
SHAREMIND_VM_PROCESS_OUT_OF_BOUNDS_REFERENCE_INDEX);
m4_ifelse($4, [imm],
[nBytes = SHAREMIND_MI_ARG_P(3);],
[SHAREMIND_MI_GET_CONST_$4(nBytes, SHAREMIND_MI_ARG_AS(3, sizet));])
SHAREMIND_MI_TRY_EXCEPT(SHAREMIND_MI_BLOCK_AS(nBytes,uint64) <= SHAREMIND_MI_MEM_GET_SIZE_FROM_SLOT(srcSlot),
SHAREMIND_VM_PROCESS_OUT_OF_BOUNDS_REFERENCE_SIZE);
SHAREMIND_MI_TRY_EXCEPT(SHAREMIND_MI_BLOCK_AS(offset,uint64) <= SHAREMIND_MI_MEM_GET_SIZE_FROM_SLOT(srcSlot) - SHAREMIND_MI_BLOCK_AS(nBytes,uint64),
SHAREMIND_VM_PROCESS_OUT_OF_BOUNDS_REFERENCE_SIZE);
SHAREMIND_MI_PUSHREFPART_MEM_$1(srcSlot, SHAREMIND_MI_BLOCK_AS(offset,uint64), SHAREMIND_MI_BLOCK_AS(nBytes,uint64))]),
DO_DISPATCH, PREPARE_FINISH)])
m4_define([PUSHREFPART_MEM_DEFINE], [_PUSHREFPART_MEM_DEFINE(_ARG1$1, _ARG2$1, _ARG3$1, _ARG4$1)])
foreach([PUSHREFPART_MEM_DEFINE], (product(([cref], [ref]), ([reg], [stack]), ([imm], [reg], [stack]), ([imm], [reg], [stack]))))
INSTR_DEFINE([common.proc.clearstack],
CODE(0x00, 0x02, 0x09, 0x00, 0x00, 0x00, 0x00, 0x00),
NO_ARGS, NO_PREPARATION, NO_IMPL_SUFFIX,
IMPL([
if (likely(SHAREMIND_MI_HAS_STACK)) {
SHAREMIND_MI_CLEAR_STACK;
}]),
DO_DISPATCH, PREPARE_FINISH)
INSTR_DEFINE([common.proc.resizestack],
CODE(0x00, 0x02, 0x0a, 0x00, 0x00, 0x00, 0x00, 0x00),
ARGS(1), NO_PREPARATION, NO_IMPL_SUFFIX, IMPL([SHAREMIND_MI_RESIZE_STACK(SHAREMIND_MI_ARG_AS(1, uint64))]), DO_DISPATCH, PREPARE_FINISH)
# common.proc.get(c)refsize
# (1=ref/cref,2=olbsrc,3=olbnbytes)
m4_define([_PROC_GETREFSIZE], [
INSTR_DEFINE([common.proc.get$1size_$2_$3],
CODE(0x00, 0x02, m4_ifelse($1, [ref], [0x0c], [0x0d]), OLB_CODE_$2, OLB_CODE_$3, 0x00, 0x00, 0x00),
ARGS(2),
NO_PREPARATION,
NO_IMPL_SUFFIX, IMPL([
const SHAREMIND_T_[]m4_ifelse($1, [cref], [C])[]Reference * SHAREMIND_RESTRICT srcRef;
m4_ifelse($2, [imm], [], [const SHAREMIND_T_CodeBlock * src;])
SHAREMIND_T_CodeBlock * m4_ifelse($2, [imm], [SHAREMIND_RESTRICT]) dest;
m4_ifelse($2, [imm],
[SHAREMIND_MI_GET_$1(srcRef, SHAREMIND_MI_ARG_AS(1, sizet));],
[SHAREMIND_MI_GET_CONST_$2(src, SHAREMIND_MI_ARG_AS(1,sizet));
SHAREMIND_MI_GET_$1(srcRef, SHAREMIND_MI_BLOCK_AS(src, sizet));])
SHAREMIND_MI_GET_$3(dest, SHAREMIND_MI_ARG_AS(2, sizet));
SHAREMIND_MI_BLOCK_AS(dest,sizet) = SHAREMIND_MI_REFERENCE_GET_SIZE(srcRef)]),
DO_DISPATCH, PREPARE_FINISH)])
m4_define([PROC_GETREFSIZE_DEFINE], [_PROC_GETREFSIZE(_ARG1$1, _ARG2$1, _ARG3$1)])
foreach([PROC_GETREFSIZE_DEFINE], (product(([cref], [ref]), ([imm], [reg], [stack]), ([reg], [stack]))))
# common.mem.alloc
m4_define([_MEM_ALLOC_DEFINE], [
INSTR_DEFINE([common.mem.alloc_$1_$2],
CODE(0x00, 0x03, 0x00, OLB_CODE_$1, OLB_CODE_$2, 0x00, 0x00, 0x00),
ARGS(2), NO_PREPARATION, NO_IMPL_SUFFIX,
IMPL([
SHAREMIND_T_CodeBlock * m4_ifelse($2, [imm], [SHAREMIND_RESTRICT]) ptrDest;
SHAREMIND_MI_GET_$1(ptrDest, SHAREMIND_MI_ARG_AS(1, sizet));
m4_ifelse($2, [imm],,
[const SHAREMIND_T_CodeBlock * sizeReg;
SHAREMIND_MI_GET_CONST_$2(sizeReg, SHAREMIND_MI_ARG_AS(2, sizet));])
SHAREMIND_MI_MEM_ALLOC(ptrDest,m4_ifelse($2, [imm], [SHAREMIND_MI_ARG_P(2)], [sizeReg]))]),
DO_DISPATCH, PREPARE_FINISH)])
m4_define([MEM_ALLOC_DEFINE], [_MEM_ALLOC_DEFINE(_ARG1$1, _ARG2$1)])
foreach([MEM_ALLOC_DEFINE], (product(([[reg]], [[stack]]),([[imm]], [[reg]], [[stack]]))))
# common.mem.free
m4_define([MEM_FREE_DEFINE], [
INSTR_DEFINE([common.mem.free_$1],
CODE(0x00, 0x03, 0x01, OLB_CODE_$1, 0x00, 0x00, 0x00, 0x00),
ARGS(1), NO_PREPARATION, NO_IMPL_SUFFIX,
IMPL([
const SHAREMIND_T_CodeBlock * SHAREMIND_RESTRICT ptr;
SHAREMIND_MI_GET_CONST_$1(ptr, SHAREMIND_MI_ARG_AS(1, sizet));
SHAREMIND_MI_MEM_FREE(ptr)]),
DO_DISPATCH, PREPARE_FINISH)])
MEM_FREE_DEFINE([reg])
MEM_FREE_DEFINE([stack])
# common.mem.getmemsize
m4_define([MEM_GETMEMSIZE_DEFINE], [
INSTR_DEFINE([common.mem.getmemsize_$1_$2],
CODE(0x00, 0x03, 0x02, OLB_CODE_$1, OLB_CODE_$2, 0x00, 0x00, 0x00),
ARGS(2), NO_PREPARATION, NO_IMPL_SUFFIX,
IMPL([
m4_ifelse($1, [imm],
[const SHAREMIND_T_CodeBlock * const ptr = SHAREMIND_MI_ARG_P(1);],
[const SHAREMIND_T_CodeBlock * ptr;
SHAREMIND_MI_GET_CONST_$1(ptr, SHAREMIND_MI_ARG_AS(1, sizet));])
SHAREMIND_T_CodeBlock * sizedest;
SHAREMIND_MI_GET_$2(sizedest, SHAREMIND_MI_ARG_AS(2, sizet));
SHAREMIND_MI_MEM_GET_SIZE(ptr,sizedest);]),
DO_DISPATCH, PREPARE_FINISH
)])
MEM_GETMEMSIZE_DEFINE([imm],[reg])
MEM_GETMEMSIZE_DEFINE([imm],[stack])
MEM_GETMEMSIZE_DEFINE([reg],[reg])
MEM_GETMEMSIZE_DEFINE([reg],[stack])
MEM_GETMEMSIZE_DEFINE([stack],[reg])
MEM_GETMEMSIZE_DEFINE([stack],[stack])
# common.convert
m4_define([_CONVERT_DEFINE], [m4_ifelse($1, $3, [], [
INSTR_DEFINE([common.convert_$1_$2_$3_$4],
CODE(0x00, 0x04, DTB_CODE_$1, OLB_CODE_$2, DTB_CODE_$3, OLB_CODE_$4, 0x00, 0x00),
ARGS(2), NO_PREPARATION, NO_IMPL_SUFFIX,
IMPL([
const SHAREMIND_T_CodeBlock * s;
SHAREMIND_MI_GET_CONST_$2(s, SHAREMIND_MI_ARG_AS(1, sizet));
SHAREMIND_T_CodeBlock * d;
SHAREMIND_MI_GET_$4(d, SHAREMIND_MI_ARG_AS(2, sizet));
m4_ifelse(DTB_CAT_$1, [float],
[SHAREMIND_MI_CONVERT_$1_TO_$3(SHAREMIND_MI_BLOCK_AS(d,$3), SHAREMIND_MI_BLOCK_AS(s,$1))],
DTB_CAT_$3, [float],
[SHAREMIND_MI_CONVERT_$1_TO_$3(SHAREMIND_MI_BLOCK_AS(d,$3), SHAREMIND_MI_BLOCK_AS(s,$1))],
[SHAREMIND_MI_BLOCK_AS(d,$3) = SHAREMIND_VM_STATIC_CAST(DTB_TYPE_$3, SHAREMIND_MI_BLOCK_AS(s,$1))])]),
DO_DISPATCH, PREPARE_FINISH
)])])
m4_define([CONVERT_DEFINE], [_$0(_ARG1$1, _ARG2$1, _ARG3$1, _ARG4$1)])
foreach([CONVERT_DEFINE], (product(([uint8], [uint16], [uint32], [uint64], [int8], [int16], [int32], [int64], [float32], [float64]),
([reg], [stack]),
([uint8], [uint16], [uint32], [uint64], [int8], [int16], [int32], [int64], [float32], [float64]),
([reg], [stack]))))
# common.halt
m4_define([HALT_DEFINE], [
INSTR_DEFINE([common.halt_$1],
CODE(0x00, 0xff, 0x00, OLB_CODE_$1, 0x00, 0x00, 0x00, 0x00),
ARGS(1), NO_PREPARATION, NO_IMPL_SUFFIX,
IMPL([
const SHAREMIND_T_CodeBlock * SHAREMIND_RESTRICT c;
m4_ifelse($1, [imm],
[c = SHAREMIND_MI_ARG_P(1);],
[SHAREMIND_MI_GET_CONST_$1(c, SHAREMIND_MI_ARG_AS(1, sizet));])
SHAREMIND_MI_HALT(*c)]),
NO_DISPATCH, PREPARE_FINISH)])
HALT_DEFINE([imm])
HALT_DEFINE([reg])
HALT_DEFINE([stack])
INSTR_DEFINE([common.except],
CODE(0x00, 0xff, 0x01, 0x00, 0x00, 0x00, 0x00, 0x00),
ARGS(1), NO_PREPARATION, NO_IMPL_SUFFIX, IMPL([SHAREMIND_MI_DO_USER_EXCEPT(SHAREMIND_MI_ARG_AS(1,uint64))]), NO_DISPATCH, PREPARE_FINISH)
INSTR_DEFINE([common.user_except],
CODE(0x00, 0xff, 0x01, 0x01, 0x00, 0x00, 0x00, 0x00),
ARGS(0), NO_PREPARATION, NO_IMPL_SUFFIX, IMPL([SHAREMIND_MI_DO_USER_EXCEPT_WITH_MESSAGE]), NO_DISPATCH, PREPARE_FINISH)
# (1=name,2=namespace,3=class,4=dtb,5=olb,6=prepare,7=impl)
m4_define([UBI_D_DEFINE], [
INSTR_DEFINE($1_$4_$5,
CODE($2, $3, DTB_CODE_$4, OLB_CODE_$5, 0x00, 0x00, 0x00, 0x00),
ARGS(1), $6, NO_IMPL_SUFFIX,
IMPL([
SHAREMIND_T_CodeBlock * SHAREMIND_RESTRICT bd;
SHAREMIND_MI_GET_$5(bd, SHAREMIND_MI_ARG_AS(1, sizet));
{
DTB_TYPE_$4 * SHAREMIND_RESTRICT d = SHAREMIND_MI_BLOCK_AS_P(bd,$4);
$7;
}]),
DO_DISPATCH, PREPARE_FINISH)])
# (1=name,2=namespace,3=class,4=dtb,5=olb_d,6=olb_s,7=prepare,8=impl)
m4_define([UBI_DS_DEFINE], [
INSTR_DEFINE($1_$4_$5_$6,
CODE($2, $3, DTB_CODE_$4, OLB_CODE_$5, OLB_CODE_$6, 0x00, 0x00, 0x00),
ARGS(2), $7, NO_IMPL_SUFFIX,
IMPL([
SHAREMIND_T_CodeBlock * m4_ifelse($6, [imm], [SHAREMIND_RESTRICT]) bd;
const SHAREMIND_T_CodeBlock * m4_ifelse($6, [imm], [SHAREMIND_RESTRICT]) bs;
SHAREMIND_MI_GET_$5(bd, SHAREMIND_MI_ARG_AS(1, sizet));
m4_ifelse($6, [imm], [bs = SHAREMIND_MI_ARG_P(2)], [SHAREMIND_MI_GET_CONST_$6(bs, SHAREMIND_MI_ARG_AS(2, sizet))]);
{
DTB_TYPE_$4 * m4_ifelse($6, [imm], [SHAREMIND_RESTRICT]) d = SHAREMIND_MI_BLOCK_AS_P(bd,$4);
const DTB_TYPE_$4 * m4_ifelse($6, [imm], [SHAREMIND_RESTRICT]) s = SHAREMIND_MI_BLOCK_AS_P(bs,$4);
$8;
}]),
DO_DISPATCH, PREPARE_FINISH)])
# (1=name,2=namespace,3=class,4=dtb,5=olb_d,6=olb_s1,7=olb_s2,8=prepare,9=impl)
m4_define([UBI_DSS_DEFINE], [m4_ifelse($6, $7, m4_ifelse($6, [imm], [], [_$0($@)]))])
m4_define([_UBI_DSS_DEFINE], [
INSTR_DEFINE($1_$4_$5_$6_$7,
CODE($2, $3, DTB_CODE_$4, OLB_CODE_$5, OLB_CODE_$6, OLB_CODE_$7, 0x00, 0x00),
ARGS(3), $8, NO_IMPL_SUFFIX,
IMPL([
SHAREMIND_T_CodeBlock * m4_ifelse($6, [imm], m4_ifelse($7, [imm], [SHAREMIND_RESTRICT])) bd;
const SHAREMIND_T_CodeBlock * m4_ifelse($6, [imm], [SHAREMIND_RESTRICT]) bs1;
const SHAREMIND_T_CodeBlock * m4_ifelse($7, [imm], [SHAREMIND_RESTRICT]) bs2;
SHAREMIND_MI_GET_$5(bd, SHAREMIND_MI_ARG_AS(1, sizet));
m4_ifelse($6, [imm], [bs1 = SHAREMIND_MI_ARG_P(2);], [SHAREMIND_MI_GET_CONST_$6(bs1, SHAREMIND_MI_ARG_AS(2, sizet));])
m4_ifelse($7, [imm], [bs2 = SHAREMIND_MI_ARG_P(3);], [SHAREMIND_MI_GET_CONST_$7(bs2, SHAREMIND_MI_ARG_AS(3, sizet));])
{
DTB_TYPE_$4 * m4_ifelse($6, [imm], m4_ifelse($7, [imm], [SHAREMIND_RESTRICT])) d = SHAREMIND_MI_BLOCK_AS_P(bd,$4);
const DTB_TYPE_$4 * m4_ifelse($6, [imm], [SHAREMIND_RESTRICT]) s1 = SHAREMIND_MI_BLOCK_AS_P(bs1,$4);
const DTB_TYPE_$4 * m4_ifelse($7, [imm], [SHAREMIND_RESTRICT]) s2 = SHAREMIND_MI_BLOCK_AS_P(bs2,$4);
m4_ifelse(DTB_CAT_$4, [float], [], [
m4_ifelse($1, [arith.tdiv], [
if ((*s2) == 0) { SHAREMIND_MI_DO_EXCEPT(SHAREMIND_VM_PROCESS_INTEGER_DIVIDE_BY_ZERO); }
m4_ifelse(DTB_CAT_$4, [signed], [else if ((*s2) == -1 && (*s1) == DTB_MIN_$4) { SHAREMIND_MI_DO_EXCEPT(SHAREMIND_VM_PROCESS_INTEGER_OVERFLOW); }])])])
$9;
}]),
DO_DISPATCH, PREPARE_FINISH)])
# See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=50865
m4_define([GCC_BUG_50865_WORKAROUND], [if (($4) == -1) { ($1) = SHAREMIND_VM_STATIC_CAST($2, ($3) % 1); } else { ($1) = SHAREMIND_VM_STATIC_CAST($2, ($3) % -($4)); }])
# arith.uneg
m4_define([ARITH_UNEG_OP], [m4_ifelse(DTB_CAT_$1, [float], [SHAREMIND_MI_UNEG_FLOAT]DTB_BITS_$1[(*d)], [(*d) = SHAREMIND_VM_STATIC_CAST(DTB_TYPE_$1, -(*d))])])
m4_define([ARITH_UNEG_DEFINE], [UBI_D_DEFINE([[arith.uneg]], 0x1, 0x00, _ARG1$1, _ARG2$1, NO_PREPARATION, ARITH_UNEG_OP(_ARG1$1))])
foreach([ARITH_UNEG_DEFINE], (product(([uint8], [uint16], [uint32], [uint64], [int8], [int16], [int32], [int64], [float32], [float64]), ([reg], [stack]))))
# arith.uinc
m4_define([ARITH_UINC_OP], [m4_ifelse(DTB_CAT_$1, [float], [SHAREMIND_MI_UINC_FLOAT]DTB_BITS_$1[(*d)], [(*d)++])])
m4_define([ARITH_UINC_DEFINE], [UBI_D_DEFINE([[arith.uinc]], 0x1, 0x01, _ARG1$1, _ARG2$1, NO_PREPARATION, ARITH_UINC_OP(_ARG1$1))])
foreach([ARITH_UINC_DEFINE], (product(([uint8], [uint16], [uint32], [uint64], [int8], [int16], [int32], [int64], [float32], [float64]), ([reg], [stack]))))
# arith.udec
m4_define([ARITH_UDEC_OP], [m4_ifelse(DTB_CAT_$1, [float], [SHAREMIND_MI_UDEC_FLOAT]DTB_BITS_$1[(*d)], [(*d)--])])
m4_define([ARITH_UDEC_DEFINE], [UBI_D_DEFINE([[arith.udec]], 0x1, 0x02, _ARG1$1, _ARG2$1, NO_PREPARATION, ARITH_UDEC_OP(_ARG1$1))])
foreach([ARITH_UDEC_DEFINE], (product(([uint8], [uint16], [uint32], [uint64], [int8], [int16], [int32], [int64], [float32], [float64]), ([reg], [stack]))))
# arith.bneg
m4_define([ARITH_BNEG_OP], [m4_ifelse(DTB_CAT_$1, [float], [SHAREMIND_MI_BNEG_FLOAT]DTB_BITS_$1[(*d,*s)], [(*d) = SHAREMIND_VM_STATIC_CAST(DTB_TYPE_$1, -(*s))])])
m4_define([ARITH_BNEG_DEFINE], [UBI_DS_DEFINE([[arith.bneg]], 0x1, 0x40, _ARG1$1, _ARG2$1, _ARG3$1, NO_PREPARATION, ARITH_BNEG_OP(_ARG1$1))])
foreach([ARITH_BNEG_DEFINE], (product(([uint8], [uint16], [uint32], [uint64], [int8], [int16], [int32], [int64], [float32], [float64]),
([reg], [stack]),
([reg], [stack]))))
# arith.binc
m4_define([ARITH_BINC_OP], [m4_ifelse(DTB_CAT_$1, [float], [SHAREMIND_MI_BINC_FLOAT]DTB_BITS_$1[(*d,*s)], [(*d) = SHAREMIND_VM_STATIC_CAST(DTB_TYPE_$1, (*s) + 1)])])
m4_define([ARITH_BINC_DEFINE], [UBI_DS_DEFINE([[arith.binc]], 0x1, 0x41, _ARG1$1, _ARG2$1, _ARG3$1, NO_PREPARATION, ARITH_BINC_OP(_ARG1$1))])
foreach([ARITH_BINC_DEFINE], (product(([uint8], [uint16], [uint32], [uint64], [int8], [int16], [int32], [int64], [float32], [float64]),
([reg], [stack]),
([reg], [stack]))))
# arith.bdec
m4_define([ARITH_BDEC_OP], [m4_ifelse(DTB_CAT_$1, [float], [SHAREMIND_MI_BDEC_FLOAT]DTB_BITS_$1[(*d,*s)], [(*d) = SHAREMIND_VM_STATIC_CAST(DTB_TYPE_$1, (*s) - 1)])])