-
Notifications
You must be signed in to change notification settings - Fork 1
/
grammar.bnf
306 lines (306 loc) · 14.7 KB
/
grammar.bnf
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
<translation_unit> : <external_decl>
| <translation_unit> <external_decl>
;
<external_decl> : <function_definition>
| <decl>
;
<function_definition> : <decl_specs> <declarator> <decl_list> <compound_stat>
| <declarator> <decl_list> <compound_stat>
| <decl_specs> <declarator> <compound_stat>
| <declarator> <compound_stat>
;
<decl> : <decl_specs> <init_declarator_list> ';'
| <decl_specs> ';'
;
<decl_list> : <decl>
| <decl_list> <decl>
;
<decl_specs> : <storage_class_spec> <decl_specs>
| <storage_class_spec>
| <type_spec> <decl_specs>
| <type_spec>
| <type_qualifier> <decl_specs>
| <type_qualifier>
;
<storage_class_spec> : 'auto'
| 'register'
| 'static'
| 'extern'
| 'typedef'
;
<type_spec> : 'void'
| 'char'
| 'short'
| 'int'
| 'long'
| 'float'
| 'double'
| 'signed'
| 'unsigned'
| 'typedef_name'
| <struct_or_union_spec>
| <enum_spec>
;
<type_qualifier> : 'const'
| 'volatile'
;
<struct_or_union_spec> : <struct_or_union> 'id' '{' <struct_decl_list> '}'
| <struct_or_union> '{' <struct_decl_list> '}'
| <struct_or_union> 'id'
;
<struct_or_union> : 'struct'
| 'union'
;
<struct_decl_list> : <struct_decl>
| <struct_decl_list> <struct_decl>
;
<init_declarator_list> : <init_declarator>
| <init_declarator_list> ',' <init_declarator>
;
<init_declarator> : <declarator>
| <declarator> '=' <initializer>
;
<struct_decl> : <spec_qualifier_list> <struct_declarator_list> ';'
;
<spec_qualifier_list> : <type_spec> <spec_qualifier_list>
| <type_spec>
| <type_qualifier> <spec_qualifier_list>
| <type_qualifier>
;
<struct_declarator_list> : <struct_declarator>
| <struct_declarator_list> ',' <struct_declarator>
;
<struct_declarator> : <declarator>
| <declarator> ':' <const_exp>
| ':' <const_exp>
;
<enum_spec> : 'enum' 'id' '{' <enumerator_list> '}'
| 'enum' '{' <enumerator_list> '}'
| 'enum' 'id'
;
<enumerator_list> : <enumerator>
| <enumerator_list> ',' <enumerator>
;
<enumerator> : 'id'
| 'id' '=' <const_exp>
;
<declarator> : <pointer> <direct_declarator>
| <direct_declarator>
;
<direct_declarator> : 'id'
| '(' <declarator> ')'
| <direct_declarator> '[' <const_exp> ']'
| <direct_declarator> '[' ']'
| <direct_declarator> '(' <param_type_list> ')'
| <direct_declarator> '(' <id_list> ')'
| <direct_declarator> '(' ')'
;
<pointer> : '*' <type_qualifier_list>
| '*'
| '*' <type_qualifier_list> <pointer>
| '*' <pointer>
;
<type_qualifier_list> : <type_qualifier>
| <type_qualifier_list> <type_qualifier>
;
<param_type_list> : <param_list>
| <param_list> ',' '...'
;
<param_list> : <param_decl>
| <param_list> ',' <param_decl>
;
<param_decl> : <decl_specs> <declarator>
| <decl_specs> <abstract_declarator>
| <decl_specs>
;
<id_list> : 'id'
| <id_list> ',' 'id'
;
<initializer> : <assignment_exp>
| '{' <initializer_list> '}'
| '{' <initializer_list> ',' '}'
;
<initializer_list> : <initializer>
| <initializer_list> ',' <initializer>
;
<type_name> : <spec_qualifier_list> <abstract_declarator>
| <spec_qualifier_list>
;
<abstract_declarator> : <pointer>
| <pointer> <direct_abstract_declarator>
| <direct_abstract_declarator>
;
<direct_abstract_declarator> : '(' <abstract_declarator> ')'
| <direct_abstract_declarator> '[' <const_exp> ']'
| '[' <const_exp> ']'
| <direct_abstract_declarator> '[' ']'
| '[' ']'
| <direct_abstract_declarator> '(' <param_type_list> ')'
| '(' <param_type_list> ')'
| <direct_abstract_declarator> '(' ')'
| '(' ')'
;
<stat> : <matched>
| <unmatched>
;
<matched> : 'if' '(' <exp> ')' <matched> 'else' <matched>
| 'switch' '(' <exp> ')' <matched>
| <labeled_stat_matched>
| <iteration_stat_matched>
| <exp_stat>
| <compound_stat>
| <jump_stat>
;
<unmatched> : 'if' '(' <exp> ')' <stat>
| 'if' '(' <exp> ')' <matched> 'else' <unmatched>
| 'switch' '(' <exp> ')' <unmatched>
| <labeled_stat_unmatched>
| <iteration_stat_unmatched>
;
<labeled_stat_matched> : 'id' ':' <matched>
| 'case' <const_exp> ':' <matched>
| 'default' ':' <matched>
;
<labeled_stat_unmatched> : 'id' ':' <unmatched>
| 'case' <const_exp> ':' <unmatched>
| 'default' ':' <unmatched>
;
<exp_stat> : <exp> ';'
| ';'
;
<compound_stat> : '{' <decl_list> <stat_list> '}'
| '{' <stat_list> '}'
| '{' <decl_list> '}'
| '{' '}'
;
<stat_list> : <stat>
| <stat_list> <stat>
;
<iteration_stat_matched> : 'while' '(' <exp> ')' <matched>
| 'do' <matched> 'while' '(' <exp> ')' ';'
| 'for' '(' <exp> ';' <exp> ';' <exp> ')' <matched>
| 'for' '(' <exp> ';' <exp> ';' ')' <matched>
| 'for' '(' <exp> ';' ';' <exp> ')' <matched>
| 'for' '(' <exp> ';' ';' ')' <matched>
| 'for' '(' ';' <exp> ';' <exp> ')' <matched>
| 'for' '(' ';' <exp> ';' ')' <matched>
| 'for' '(' ';' ';' <exp> ')' <matched>
| 'for' '(' ';' ';' ')' <matched>
;
<iteration_stat_unmatched> : 'while' '(' <exp> ')' <unmatched>
| 'do' <unmatched> 'while' '(' <exp> ')' ';'
| 'for' '(' <exp> ';' <exp> ';' <exp> ')' <unmatched>
| 'for' '(' <exp> ';' <exp> ';' ')' <unmatched>
| 'for' '(' <exp> ';' ';' <exp> ')' <unmatched>
| 'for' '(' <exp> ';' ';' ')' <unmatched>
| 'for' '(' ';' <exp> ';' <exp> ')' <unmatched>
| 'for' '(' ';' <exp> ';' ')' <unmatched>
| 'for' '(' ';' ';' <exp> ')' <unmatched>
| 'for' '(' ';' ';' ')' <unmatched>
;
<jump_stat> : 'goto' 'id' ';'
| 'continue' ';'
| 'break' ';'
| 'return' <exp> ';'
| 'return' ';'
;
<exp> : <assignment_exp>
| <exp> ',' <assignment_exp>
;
<assignment_exp> : <conditional_exp>
| <unary_exp> <assignment_operator> <assignment_exp>
;
<assignment_operator> : '='
| '*='
| '/='
| '%='
| '+='
| '-='
| '<<='
| '>>='
| '&='
| '^='
| '|='
;
<conditional_exp> : <logical_or_exp>
| <logical_or_exp> '?' <exp> ':' <conditional_exp>
;
<const_exp> : <conditional_exp>
;
<logical_or_exp> : <logical_and_exp>
| <logical_or_exp> '||' <logical_and_exp>
;
<logical_and_exp> : <inclusive_or_exp>
| <logical_and_exp> '&&' <inclusive_or_exp>
;
<inclusive_or_exp> : <exclusive_or_exp>
| <inclusive_or_exp> '|' <exclusive_or_exp>
;
<exclusive_or_exp> : <and_exp>
| <exclusive_or_exp> '^' <and_exp>
;
<and_exp> : <equality_exp>
| <and_exp> '&' <equality_exp>
;
<equality_exp> : <relational_exp>
| <equality_exp> '==' <relational_exp>
| <equality_exp> '!=' <relational_exp>
;
<relational_exp> : <shift_expression>
| <relational_exp> '<' <shift_expression>
| <relational_exp> '>' <shift_expression>
| <relational_exp> '<=' <shift_expression>
| <relational_exp> '>=' <shift_expression>
;
<shift_expression> : <additive_exp>
| <shift_expression> '<<' <additive_exp>
| <shift_expression> '>>' <additive_exp>
;
<additive_exp> : <mult_exp>
| <additive_exp> '+' <mult_exp>
| <additive_exp> '-' <mult_exp>
;
<mult_exp> : <cast_exp>
| <mult_exp> '*' <cast_exp>
| <mult_exp> '/' <cast_exp>
| <mult_exp> '%' <cast_exp>
;
<cast_exp> : <unary_exp>
| '(' <type_name> ')' <cast_exp>
;
<unary_exp> : <postfix_exp>
| '++' <unary_exp>
| '--' <unary_exp>
| <unary_operator> <cast_exp>
| 'sizeof' <unary_exp>
| 'sizeof' '(' <type_name> ')'
;
<unary_operator> : '&'
| '*'
| '+'
| '-'
| '~'
| '!'
;
<postfix_exp> : <primary_exp>
| <postfix_exp> '[' <exp> ']'
| <postfix_exp> '(' <argument_exp_list> ')'
| <postfix_exp> '(' ')'
| <postfix_exp> '.' 'id'
| <postfix_exp> '->' 'id'
| <postfix_exp> '++'
| <postfix_exp> '--'
;
<primary_exp> : 'id'
| <const>
| 'string'
| '(' <exp> ')'
;
<argument_exp_list> : <assignment_exp>
| <argument_exp_list> ',' <assignment_exp>
;
<const> : 'int_const'
| 'char_const'
| 'float_const'
| 'enumeration_const'
;