build.gradle

buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath 'com.bmuschko:gradle-nexus-plugin:2.3.1'
    }
}

plugins {
    id 'java'
    id 'jacoco'
    id "org.sonarqube" version "3.3"
    id 'com.bmuschko.nexus' version '2.3.1'
}

archivesBaseName = 'apache-sseclient'
group = "dev.manpreet"
version = "1.0"

repositories {
    mavenCentral()
}

dependencies {
    compile group: 'org.apache.httpcomponents', name: 'httpclient', version: '4.5.12'
    compile group: 'org.apache.httpcomponents', name: 'httpclient-cache', version: '4.5.12'
    compile group: 'org.apache.httpcomponents', name: 'httpasyncclient', version: '4.1.4'
    testCompile group: 'com.fasterxml.jackson.core', name: 'jackson-core', version: '2.10.2'
    testCompile group: 'com.fasterxml.jackson.core', name: 'jackson-databind', version: '2.10.2'
    testCompile group: 'com.fasterxml.jackson.datatype', name: 'jackson-datatype-jsr310', version: '2.10.2'
    testCompile group: 'commons-io', name: 'commons-io', version: '2.8.0'
    testCompile group: 'org.testng', name: 'testng', version: '7.1.0'
    testCompile group: 'org.slf4j', name: 'slf4j-api', version: '1.7.30'
    testCompile group: 'ch.qos.logback', name: 'logback-classic', version: '1.2.3'
    testCompile group: 'org.projectlombok', name: 'lombok', version: '1.18.12'
    testAnnotationProcessor group: 'org.projectlombok', name: 'lombok', version: '1.18.12'
}

jar {
    manifest {
        attributes 'Implementation-Title': 'Apache SSE client',
                'Implementation-Version': '1.0'
    }
}

task fatJar(type: Jar) {
    version("1.0-uber")
    manifest {
        attributes 'Implementation-Title': 'Apache SSE client',
                'Implementation-Version': '1.0'
    }
    from { configurations.compile.collect { it.isDirectory() ? it : zipTree(it) } }
    with jar
}

test {
    useTestNG() {
        def builder = suiteXmlBuilder();
        builder.suite(name: 'sse-tests') {
            test(name: 'sse-tests') {
                builder.packages { 'package'(name: 'dev.manpreet.apache.sseclient.*') {} }
            }
        }
    }
    finalizedBy jacocoTestReport
}

jacocoTestReport {
    additionalSourceDirs.from = files(sourceSets.main.allSource.srcDirs)
    sourceDirectories.from = files(sourceSets.main.allSource.srcDirs)
    classDirectories.from = files(sourceSets.main.output)
    reports {
        html.enabled = false
        xml.enabled = true
        xml.destination = file("${buildDir}/jacoco/test.xml")
        csv.enabled = false
    }
}

sonarqube {
    properties {
        property "sonar.projectKey", "autopreet_apache-sseclient"
        property "sonar.organization", "autopreet"
        property "sonar.host.url", "https://sonarcloud.io"
        property "sonar.language", "java"
    }
}

modifyPom {
    project {
        name 'apache-sseclient'
        description 'SSE client for apache HTTP client'
        url 'https://github.com/autopreet/apache-sseclient'
        inceptionYear '2020'

        scm {
            url 'https://github.com/autopreet/apache-sseclient'
            connection 'scm:https://github.com/autopreet/apache-sseclient.git'
            developerConnection 'scm:https://github.com/autopreet/apache-sseclient.git'
        }

        licenses {
            license {
                name 'The Apache Software License, Version 2.0'
                url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                distribution 'repo'
            }
        }

        developers {
            developer {
                id 'autopreet'
                name 'Manpreet'
                email 'manpreet.333@gmail.com'
            }
        }
    }
}

extraArchive {
    sources = true
}

nexus {
    sign = true
    repositoryUrl = 'https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/'
    snapshotRepositoryUrl = 'https://s01.oss.sonatype.org/content/repositories/snapshots/'
}