build.gradle

plugins {
    id 'java'
    id 'maven-publish'
    id 'io.papermc.paperweight.userdev' version '1.7.1'
}

repositories {
    mavenLocal()

    maven {
        name 'Paper Repository'
        url 'https://papermc.io/repo/repository/maven-public/'
    }
}

dependencies {
    paperweightDevelopmentBundle 'io.papermc.paper:dev-bundle:1.21-R0.1-SNAPSHOT'
}

group = 'gg.packetloss'
version = '1.21.0.0'

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(21)
    }
}

tasks {
    build {
        dependsOn(reobfJar)
    }
}

// Butcher the dev jar so as to publish a properly obfuscated jar
def javaComponent = components.java as AdhocComponentWithVariants
javaComponent.withVariantsFromConfiguration(configurations.apiElements) {
    skip()
}
javaComponent.withVariantsFromConfiguration(configurations.runtimeElements) {
    skip()
}
javaComponent.addVariantsFromConfiguration(configurations.reobf) {
    mapToMavenScope("compile")
}

publishing {
    publications {
        maven(MavenPublication) {
            from javaComponent
        }
    }

    repositories {
        maven {
            url = System.getProperty("deploy-url")
            credentials {
                username = System.getProperty("deploy-username")
                password = System.getProperty("deploy-password")
            }
        }
    }
}