How can I attach an EIP to an ECS using the terraform provider?

[TobiWo]

Hi, I can't figure out how I can attach an EIP to an ECS.
As I only found one EIP resource I guess this is what I need. But how can I connect this to an ecs v1?

Checking the ui an ecs has an nic parameter where private and public IPs are attached to. Ok, but when I check the network resource I see that there is no way to add an eip. Maybe somehow to the value_specs? I have no clue. Any help is highly appreciated.

[artem-lifshits]

Here's example config:

resource "opentelekomcloud_networking_floatingip_v2" "this" {
  pool = "admin_external_net"
}

resource "opentelekomcloud_ecs_instance_v1" "instance_1" {
  name     = "server_1"
  image_id = var.image_id
  flavor   = "s2.medium.1"
  vpc_id   = var.vpc_id

  nics {
    network_id = var.network_id
  }

  data_disks {
    size = 10
    type = "SSD"
  }

  password                    = "Password@123"
  security_groups             = [var.security_group_id]
  availability_zone           = "eu-de-01"
  auto_recovery               = false
  delete_disks_on_termination = true
}

resource "opentelekomcloud_networking_floatingip_associate_v2" "this" {
  floating_ip = opentelekomcloud_networking_floatingip_v2.this.address
  port_id     = opentelekomcloud_ecs_instance_v1.instance_1.nics.0.port_id
}