build.gradle

group = "${rootProject.group}.testkit"

project.ext {
    artifactDisplayName = "Abort Mission - Booster Test Kit"
    artifactDescription = "A collection of classes we can use to test Abort Mission Boosters."
}

dependencies {
    implementation project(":mission-control")
    implementation libs.spring.boot.starter
    implementation libs.spring.boot.starter.test
    implementation libs.bundles.logback.test
    testImplementation libs.jupiter.api
    testImplementation libs.jupiter.core
    testRuntimeOnly("org.junit.platform:junit-platform-launcher")
    constraints {
        implementation libs.bundles.spring.test
    }
}

test {
    useJUnitPlatform()
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java
            artifactId = "abort.${project.name}"
            pom {
                name = "${project.artifactDisplayName}"
                description = "${project.artifactDescription}"
                url = rootProject.ext.repoUrl
                licenses {
                    license {
                        name = rootProject.ext.licenseName
                        url = rootProject.ext.licenseUrl
                    }
                }
                developers {
                    developer {
                        id = rootProject.ext.maintainerId
                        name = rootProject.ext.maintainerName
                        url = rootProject.ext.maintainerUrl
                    }
                }
                scm {
                    connection = rootProject.ext.scmConnection
                    developerConnection = rootProject.ext.scmConnection
                    url = rootProject.ext.scmProjectUrl
                }
                withXml {
                    asNode().dependencies.'*'.findAll() {
                        it.scope.text() == 'runtime'
                    }.each { it.scope*.value = 'compile' }
                }
            }
        }
    }
}

signing {
    sign publishing.publications.mavenJava
}