procon.dnh

#include "./sound.dnh"
#include "./itsb.dnh"
#include "./ww.dnh"
#include "./language.dnh"
#include "./textf.dnh"

function getCharacter {
	return GetAreaCommonData("Replay", "Character", 0);
}

task setCharacter(c) {
	SetAreaCommonData("Replay", "Character", c);
}

function getDifficulty {
	return GetAreaCommonData("Replay", "Difficulty", 1);
}

task setDifficulty(d) {
	SetAreaCommonData("Replay", "Difficulty", d);
}

let MODE_ALL = 0;
let MODE_SPELL_OFF = 100;

function getMode {
	return GetAreaCommonData("Replay", "Mode", MODE_ALL);
}

task setMode(m) {
	SetAreaCommonData("Replay", "Mode", m);
}

function exists(o) {return !Obj_IsDeleted(o);}
function nexists(o) {return Obj_IsDeleted(o);}
function delete(o) {return Obj_Delete(o);}

function flush(vk) {
	while (GetVirtualKeyState(vk) != KEY_FREE) {yield;}
}
function flushZ {flush(VK_OK);}
function flushX {flush(VK_CANCEL);}

function wait(t) {
	loop (t) {yield;}
}

function getEffectCut {
	return GetAreaCommonData("Cy06", "EffCut", 1);
}

function randIntH(l, h) {
	return trunc(rand(l, h));
}

function runScript(path, args) {
	let sc = LoadScript(path);
	let l = length(args);
	ascent (i in 0 .. l) {
		SetScriptArgument(sc, i, args[i]);
	}
	StartScript(sc);
	while (!IsCloseScript(sc)) {yield;}
	return GetScriptResult(sc);
}

let MODE_STAGE = 0;
let MODE_SPELL = 100;

function getHistory(spellID) {
	return GetAreaCommonData("Cy06", "H-" ~ IntToString(getCharacter) ~ "/" ~ IntToString(spellID) ~ "/" ~ IntToString(getDifficulty), [0, 0]);
}

task setHistory(spellID, history) {
	SetAreaCommonData("Cy06", "H-" ~ IntToString(getCharacter) ~ "/" ~ IntToString(spellID) ~ "/" ~ IntToString(getDifficulty), history);
}

task saveHistoryPre(spellID) {
	let old = getHistory(spellID);
	setHistory(spellID, [old[0], old[1] + 1]);
}

task saveHistoryPost(spellID, success) {
	let old = getHistory(spellID);
	setHistory(spellID, [old[0] + success, old[1]]);
}

function getLastStage(chara, diff) {
	return GetAreaCommonData("Cy06", "gls" ~ IntToString(chara) ~ IntToString(diff), 1);
}

task setLastStage(chara, diff, stage) {
	SetAreaCommonData("Cy06", "gls" ~ IntToString(chara) ~ IntToString(diff), stage);
}

function inDialogue {
	return GetCommonData("InDialogue", false);
}

function toggleDialogue {
	SetCommonData("InDialogue", !inDialogue);
}

function isCharacterUnlocked(id) {
	return GetAreaCommonData("Cy06", "Unlocked" ~ IntToString(id), false);
}

task unlockCharacter(id) {
	SetAreaCommonData("Cy06", "Unlocked" ~ IntToString(id), true);
}

function randomSign {
	return 1 - 2 * round(rand(0, 1));
}

let EV_SUBMIT = EV_USER + 6;
let EV_DEDZ = EV_USER + 5;