-
Notifications
You must be signed in to change notification settings - Fork 3
/
complex.pas
595 lines (528 loc) · 19 KB
/
complex.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
UNIT complex;
{$MACRO ON}
INTERFACE
USES sysutils,math;
TYPE
T_Complex =record re,im:double; end;
P_Complex =^T_Complex;
T_arrayOfComplex=array of T_Complex;
CONST
II:T_Complex=(re:0; im:1);
C_invalidComplex:T_Complex=(re:Nan; im:Nan);
TYPE
T_boundingBox=record
x0,y0,x1,y1:double;
end;
T_scaler=object
private
//input
relativeZoom,
rotation:double;
worldCenter:T_Complex;
screenWidth ,screenHeight:longint;
//derived:
zoomRot,invZoomRot:T_Complex;
screenCenter:T_Complex;
PROCEDURE recalc;
public
FUNCTION getCenterX:double;
PROCEDURE setCenterX(CONST value:double);
FUNCTION getCenterY:double;
PROCEDURE setCenterY(CONST value:double);
FUNCTION getZoom:double;
PROCEDURE setZoom(CONST value:double);
FUNCTION getRotation:double;
PROCEDURE setRotation(CONST value:double);
CONSTRUCTOR create (CONST width,height:longint; CONST centerX,centerY,zoom,rotationInDegrees:double);
PROCEDURE recreate(CONST width,height:longint; CONST centerX,centerY,zoom,rotationInDegrees:double);
DESTRUCTOR destroy;
FUNCTION transform(CONST x,y:double ):T_Complex;
FUNCTION mrofsnart(CONST x,y:double ):T_Complex;
PROCEDURE rescale (CONST newWidth,newHeight:longint);
PROCEDURE recenter(CONST newCenter:T_Complex);
PROCEDURE moveCenter(CONST dx,dy:double);
PROCEDURE rotateToHorizontal(CONST screenDx,screenDy:longint);
FUNCTION getAbsoluteZoom:T_Complex;
FUNCTION getPositionString(CONST x,y:double; CONST Separator:ansistring='+i*'):ansistring;
FUNCTION getPixelsBoundingBox:T_boundingBox;
FUNCTION getWorldBoundingBox:T_boundingBox;
end;
OPERATOR :=(CONST x:double):T_Complex; inline;
OPERATOR +(CONST x,y:T_Complex):T_Complex; inline;
OPERATOR -(CONST x,y:T_Complex):T_Complex; inline;
OPERATOR *(CONST x,y:T_Complex):T_Complex; inline;
FUNCTION inverse(CONST x:T_Complex):T_Complex; inline;
OPERATOR /(CONST x,y:T_Complex):T_Complex; inline;
OPERATOR **(x:T_Complex; y:longint):T_Complex; inline;
OPERATOR **(x:T_Complex; CONST y:double):T_Complex; inline;
OPERATOR **(x:T_Complex; CONST y:T_Complex):T_Complex; inline;
FUNCTION abs(CONST x:double):double; inline;
FUNCTION abs(CONST x:T_Complex):double; inline;
FUNCTION arg(CONST x:T_Complex):double; inline;
FUNCTION sqr(CONST x:T_Complex):T_Complex; inline;
FUNCTION sqrabs(CONST x:T_Complex):double; inline;
FUNCTION exp(CONST x:double):double; inline;
FUNCTION exp(CONST x:T_Complex):T_Complex; inline;
FUNCTION ln (CONST x:T_Complex):T_Complex; inline;
FUNCTION sin(x:T_Complex):T_Complex; inline;
FUNCTION cos(x:T_Complex):T_Complex; inline;
FUNCTION tan(CONST x:T_Complex):T_Complex; inline;
FUNCTION isValid(CONST c:T_Complex):boolean; inline;
FUNCTION bbIntersect(CONST b1,b2:T_boundingBox):T_boundingBox;
FUNCTION allOutside(CONST b:T_boundingBox; CONST p0,p1,p2 :T_Complex):boolean;
FUNCTION allOutside(CONST b:T_boundingBox; CONST p0,p1,p2,p3 :T_Complex):boolean;
FUNCTION allOutside(CONST b:T_boundingBox; CONST p0,p1,p2,p3,p4,p5:T_Complex):boolean;
FUNCTION DiscreteFourierTransform(CONST X:T_arrayOfComplex; CONST inverse:boolean):T_arrayOfComplex;
FUNCTION FastFourierTransform(CONST X:T_arrayOfComplex; CONST inverse:boolean):T_arrayOfComplex;
IMPLEMENTATION
FUNCTION abs(CONST x:double):double;
begin
if x>0 then result:=x else result:=-x;
end;
OPERATOR :=(CONST x:double):T_Complex;
begin
result.re:=x; result.im:=0;
end;
OPERATOR +(CONST x,y:T_Complex):T_Complex;
begin
result.re:=x.re+y.re;
result.im:=x.im+y.im;
end;
OPERATOR -(CONST x,y:T_Complex):T_Complex;
begin
result.re:=x.re-y.re;
result.im:=x.im-y.im;
end;
OPERATOR *(CONST x,y:T_Complex):T_Complex;
begin
result.re:=x.re*y.re-x.im*y.im;
result.im:=x.re*y.im+x.im*y.re;
end;
FUNCTION inverse(CONST x:T_Complex):T_Complex;
begin
result.im:=1/(x.re*x.re+x.im*x.im);
result.re:= x.re*result.im;
result.im:=-x.im*result.im;
end;
OPERATOR /(CONST x,y:T_Complex):T_Complex;
begin
result.im:=1/(y.re*y.re+y.im*y.im);
result.re:=(x.re*y.re+x.im*y.im)*result.im;
result.im:=(x.im*y.re-x.re*y.im)*result.im;
end;
FUNCTION exp(CONST x:double):double; inline;
begin
{$ifdef CPU32}
result:=system.exp(x);
{$else}
if x<-745.133219101925 then result:=0
else if x> 709.782712893375 then result:=infinity
else result:=system.exp(x);
{$endif}
end;
OPERATOR **(x:T_Complex; CONST y:T_Complex):T_Complex;
begin
//result:=exp(ln(x)*y);
result.re:=x.re*x.re+x.im*x.im;
result.re:=0.5*system.ln(result.re);
result.im:=arctan2(x.im,x.re);
x.re:=result.re*y.re-result.im*y.im;
x.im:=result.im*y.re+result.re*y.im;
result.im:=exp(x.re);
result.re:=system.cos(x.im)*result.im;
result.im:=system.sin(x.im)*result.im;
end;
OPERATOR **(x:T_Complex; CONST y:double):T_Complex;
begin
//result:=exp(ln(x)*y);
result.re:=x.re*x.re+x.im*x.im;
result.re:=0.5*system.ln(result.re);
result.im:=arctan2(x.im,x.re);
x.re:=result.re*y;
x.im:=result.im*y;
result.im:=exp(x.re);
result.re:=system.cos(x.im)*result.im;
result.im:=system.sin(x.im)*result.im;
end;
OPERATOR **(x:T_Complex; y:longint):T_Complex;
//Note: This implementation is 100% equivalent to the
// academical recursive implementation, but it
// avoids the recursion, thus reducing both stack
// usage and overhead due to function calls.
// Computational cost is in log(y)
VAR k :longint;
begin
if y=0 then result:=1
else begin
if y<0 then begin x:=1/x; y:=-y; end;
result:=1;
k:=1;
while y>0 do begin
if (y and k)=k then begin
result:=result*x;
dec(y,k);
end;
k:=k+k;
x:=sqr(x);
end;
end;
end;
FUNCTION abs(CONST x:T_Complex):double;
begin
result:=sqrt(x.re*x.re+x.im*x.im);
end;
FUNCTION arg(CONST x:T_Complex):double ;
begin
result:=arctan2(x.im,x.re);
end;
FUNCTION sqr(CONST x:T_Complex):T_Complex;
begin
result.re:=x.re*x.re-x.im*x.im;
result.im:=2*x.re*x.im;
end;
FUNCTION sqrabs(CONST x:T_Complex):double; inline;
begin result:=x.re*x.re+x.im*x.im; if isNan(result) then result:=infinity; end;
FUNCTION exp(CONST x:T_Complex):T_Complex;
begin
result.im:=exp(x.re);
result.re:=system.cos(x.im)*result.im;
result.im:=system.sin(x.im)*result.im;
end;
FUNCTION ln (CONST x:T_Complex):T_Complex;
begin
result.re:=0.5*system.ln(x.re*x.re+x.im*x.im);
result.im:=arctan2(x.im,x.re);
end;
FUNCTION sin(x:T_Complex):T_Complex;
begin
//result:=exp(i*x) --------------------//
result.im:=exp(-x.im);
result.re:=system.cos( x.re)*result.im;//
result.im:=system.sin( x.re)*result.im;//
//-------------------------------------//
//result:=result-1/result ------------------------//
x.im:=1/(result.re*result.re+result.im*result.im);//
result.re:=result.re-result.re*x.im; //
result.im:=result.im+result.im*x.im; //
//------------------------------------------------//
//result:=result/(2*i)=-0.5*i*result //
x.re:= 0.5*result.im; //
result.im:=-0.5*result.re; //
result.re:=x.re; //
//-----------------------------------//
end;
FUNCTION cos(x:T_Complex):T_Complex;
begin
//result:=exp(i*x) --------------------//
result.im:=exp(-x.im);
result.re:=system.cos( x.re)*result.im;//
result.im:=system.sin( x.re)*result.im;//
//-------------------------------------//
//result:=result+1/result ------------------------//
x.im:=1/(result.re*result.re+result.im*result.im);//
result.re:=result.re+result.re*x.im; //
result.im:=result.im-result.im*x.im; //
//------------------------------------------------//
//result:=result/(2)=-0.5*result //
result.re:=result.re*0.5; //
result.im:=result.im*0.5; //
//-------------------------------//
end;
FUNCTION tan(CONST x:T_Complex):T_Complex;
begin
result:=sin(x)/cos(x);
end;
FUNCTION isValid(CONST c:T_Complex):boolean; inline;
begin
result:=not(isNan (c.re) or
isInfinite(c.re) or
isNan (c.im) or
isInfinite(c.im));
end;
FUNCTION bbIntersect(CONST b1,b2:T_boundingBox):T_boundingBox;
begin
result.x0:=max(b1.x0,b2.x0); result.y0:=max(b1.y0,b2.y0);
result.x1:=min(b1.x1,b2.x1); result.y1:=min(b1.y1,b2.y1);
end;
FUNCTION allOutside(CONST b:T_boundingBox; CONST p0,p1,p2 :T_Complex):boolean;
begin
result:=(max(p0.re,max(p1.re,p2.re))<b.x0) or
(min(p0.re,min(p1.re,p2.re))>b.x1) or
(max(p0.im,max(p1.im,p2.im))<b.y0) or
(min(p0.im,min(p1.im,p2.im))>b.y1);
end;
FUNCTION allOutside(CONST b:T_boundingBox; CONST p0,p1,p2,p3 :T_Complex):boolean;
begin
result:=(max(p0.re,max(p1.re,max( p2.re,p3.re)))<b.x0) or
(min(p0.re,min(p1.re,min( p2.re,p3.re)))>b.x1) or
(max(p0.im,max(p1.im,max( p2.im,p3.im)))<b.y0) or
(min(p0.im,min(p1.im,min( p2.im,p3.im)))>b.y1);
end;
FUNCTION allOutside(CONST b:T_boundingBox; CONST p0,p1,p2,p3,p4,p5:T_Complex):boolean;
begin
result:=(max(p0.re,max(p1.re,max( p2.re,max(p3.re,max(p4.re,p5.re)))))<b.x0) or
(min(p0.re,min(p1.re,min( p2.re,min(p3.re,min(p4.re,p5.re)))))>b.x1) or
(max(p0.im,max(p1.im,max( p2.im,max(p3.im,max(p4.im,p5.im)))))<b.y0) or
(min(p0.im,min(p1.im,min( p2.im,min(p3.im,min(p4.im,p5.im)))))>b.y1);
end;
//T_scaler:======================================================================================================================================
CONSTRUCTOR T_scaler.create(CONST width, height: longint; CONST centerX,centerY, zoom, rotationInDegrees: double);
begin
recreate(width,height,centerX,centerY,zoom,rotationInDegrees);
end;
PROCEDURE T_scaler.recreate(CONST width, height: longint; CONST centerX,centerY, zoom, rotationInDegrees: double);
begin
screenWidth :=width;
screenHeight:=height;
worldCenter.re:=centerX;
worldCenter.im:=centerY;
relativeZoom:=zoom;
rotation:=rotationInDegrees*pi/180;
recalc;
end;
DESTRUCTOR T_scaler.destroy; begin end;
PROCEDURE T_scaler.recalc;
begin
zoomRot.re:=system.cos(rotation);
zoomRot.im:=system.sin(rotation);
zoomRot:=zoomRot/(relativeZoom*sqrt(screenWidth*screenWidth+screenHeight*screenHeight));
invZoomRot:=1/zoomRot;
screenCenter.re:=0.5*screenWidth;
screenCenter.im:=0.5*screenHeight;
end;
FUNCTION T_scaler.getCenterX: double;
begin
result:=worldCenter.re;
end;
PROCEDURE T_scaler.setCenterX(CONST value: double);
begin
worldCenter.re:=value;
recalc;
end;
FUNCTION T_scaler.getCenterY: double;
begin
result:=worldCenter.im;
end;
PROCEDURE T_scaler.setCenterY(CONST value: double);
begin
worldCenter.im:=value;
recalc;
end;
PROCEDURE T_scaler.recenter(CONST newCenter:T_Complex);
begin
worldCenter:=newCenter;
recalc;
end;
FUNCTION T_scaler.getZoom: double;
begin
result:=relativeZoom;
end;
PROCEDURE T_scaler.setZoom(CONST value: double);
begin
relativeZoom:=value;
recalc;
end;
FUNCTION T_scaler.getRotation: double;
begin
result:=rotation/pi*180;
end;
PROCEDURE T_scaler.setRotation(CONST value: double);
begin
rotation:=value/180*pi;
while rotation<-pi do rotation:=rotation+2*pi;
while rotation> pi do rotation:=rotation-2*pi;
recalc;
end;
FUNCTION T_scaler.transform(CONST x, y: double): T_Complex;
begin
result.re:=x;
result.im:=screenHeight-y;
result:=(result-screenCenter)*zoomRot+worldCenter;
end;
FUNCTION T_scaler.mrofsnart(CONST x, y: double): T_Complex;
begin
result.re:=x;
result.im:=y;
result:=(result-worldCenter)*invZoomRot+screenCenter;
result.im:=screenHeight-result.im;
end;
PROCEDURE T_scaler.rescale(CONST newWidth, newHeight: longint);
begin
screenWidth:=newWidth;
screenHeight:=newHeight;
recalc;
end;
PROCEDURE T_scaler.moveCenter(CONST dx, dy: double);
VAR delta:T_Complex;
begin
delta.re:= dx;
delta.im:=-dy;
worldCenter:=worldCenter+delta*zoomRot;
recalc;
end;
PROCEDURE T_scaler.rotateToHorizontal(CONST screenDx,screenDy:longint);
begin
rotation:=rotation-arctan2(screenDy,screenDx);
recalc;
end;
FUNCTION T_scaler.getAbsoluteZoom: T_Complex;
begin
result:=zoomRot;
end;
FUNCTION T_scaler.getPositionString(CONST x, y: double; CONST Separator: ansistring): ansistring;
VAR p:T_Complex;
begin
p:=transform(x,y);
result:=floatToStr(p.re)+Separator+floatToStr(p.im);
end;
FUNCTION T_scaler.getPixelsBoundingBox:T_boundingBox;
begin
result.x0:=0;
result.y0:=0;
result.x1:=screenWidth ;
result.y1:=screenHeight;
end;
FUNCTION T_scaler.getWorldBoundingBox:T_boundingBox;
VAR p:T_Complex;
begin
p:=transform(0,0);
result.x0:=p.re;
result.x1:=p.re;
result.y0:=p.im;
result.y1:=p.im;
p:=transform(screenWidth,0);
result.x0:=min(result.x0,p.re);
result.x1:=max(result.x1,p.re);
result.y0:=min(result.y0,p.im);
result.y1:=max(result.y1,p.im);
p:=transform(screenWidth,screenHeight);
result.x0:=min(result.x0,p.re);
result.x1:=max(result.x1,p.re);
result.y0:=min(result.y0,p.im);
result.y1:=max(result.y1,p.im);
p:=transform(0,screenHeight);
result.x0:=min(result.x0,p.re);
result.x1:=max(result.x1,p.re);
result.y0:=min(result.y0,p.im);
result.y1:=max(result.y1,p.im);
end;
FUNCTION rootOfUnity(CONST alpha:double):T_Complex; inline;
begin
result.re:=system.cos(alpha);
result.im:=system.sin(alpha);
end;
FUNCTION DiscreteFourierTransform(CONST X:T_arrayOfComplex; CONST inverse:boolean):T_arrayOfComplex;
VAR i,j:longint;
r:T_Complex;
commonFactor:double;
begin
if inverse
then commonFactor:= 2*pi/length(X)
else commonFactor:=-2*pi/length(X);
setLength(result,length(X));
for j:=0 to length(result)-1 do begin
r:=0;
for i:=0 to length(X)-1 do r+=X[i]*rootOfUnity(commonFactor*i*j);
if inverse
then result[j]:=r*(1/length(X))
else result[j]:=r;
end;
end;
FUNCTION FastFourierTransform(CONST X:T_arrayOfComplex; CONST inverse:boolean):T_arrayOfComplex;
CONST Q3a:T_Complex=(re:-0.5;im:-0.86602540378443837);
Q3b:T_Complex=(re:-0.5;im: 0.86602540378443837);
Q5a:T_Complex=(re: 0.3090169943749474; im:-0.951056516295153);
Q5b:T_Complex=(re:-0.8090169943749474; im:-0.587785252292473);
Q5c:T_Complex=(re:-0.8090169943749474; im: 0.587785252292473);
Q5d:T_Complex=(re: 0.3090169943749474; im: 0.951056516295153);
VAR N1:longint=2;
N2:longint;
commonFactor:double;
innerX ,
innerFT:array of T_arrayOfComplex;
i,j,k:longint;
begin
N2:=length(x);
//Find smallest divider of length(X) by trial division
while (N1*N1<N2) and (N2 mod N1<>0) do inc(N1);
//Revert to DFT for prime cases
if N2 mod N1 <> 0 then exit(DiscreteFourierTransform(X,inverse));
N2:=N2 div N1;
setLength(innerX ,N1);
for i:=0 to N1-1 do setLength(innerX[i],N2);
j:=0;
k:=0;
for i:=0 to length(X)-1 do begin
innerX[j,k]:=X[i];
inc(j);
if j>=N1 then begin j:=0; inc(k); end;
end;
setLength(innerFT,N1);
for i:=0 to N1-1 do innerFT[i]:=FastFourierTransform(innerX[i],inverse);
//Twiddle...
for k:=1 to N1-1 do begin
if inverse
then commonFactor:= 2*pi/length(x)*k
else commonFactor:=-2*pi/length(x)*k;
for i:=0 to N2-1 do innerFT[k,i]*=rootOfUnity(commonFactor*i);
end;
setLength(result,length(X));
if N1=2 then begin
if inverse
then commonFactor:=1/2
else commonFactor:=1;
for i:=0 to N2-1 do result[ i]:=(innerFT[0,i]+innerFT[1,i])*commonFactor;
for i:=0 to N2-1 do result[N2+i]:=(innerFT[0,i]-innerFT[1,i])*commonFactor;
end else if N1=3 then begin
if inverse then begin
commonFactor:=1/3;
for i:=0 to N2-1 do result[ i]:=(innerFT[0,i]+innerFT[1,i] +innerFT[2,i] )*commonFactor;
for i:=0 to N2-1 do result[ N2+i]:=(innerFT[0,i]+innerFT[1,i]*Q3b+innerFT[2,i]*Q3a)*commonFactor;
for i:=0 to N2-1 do result[N2+N2+i]:=(innerFT[0,i]+innerFT[1,i]*Q3a+innerFT[2,i]*Q3b)*commonFactor;
end else begin
for i:=0 to N2-1 do result[ i]:=(innerFT[0,i]+innerFT[1,i] +innerFT[2,i] );
for i:=0 to N2-1 do result[ N2+i]:=(innerFT[0,i]+innerFT[1,i]*Q3a+innerFT[2,i]*Q3b);
for i:=0 to N2-1 do result[N2+N2+i]:=(innerFT[0,i]+innerFT[1,i]*Q3b+innerFT[2,i]*Q3a);
end;
end else if N1=5 then begin
if inverse then begin
commonFactor:=1/5;
for i:=0 to N2-1 do result[ i]:=(innerFT[0,i]+innerFT[1,i] +innerFT[2,i] +innerFT[3,i] +innerFT[4,i] )*commonFactor;
for i:=0 to N2-1 do result[ N2+i]:=(innerFT[0,i]+innerFT[1,i]*Q5d+innerFT[2,i]*Q5c+innerFT[3,i]*Q5b+innerFT[4,i]*Q5a)*commonFactor;
for i:=0 to N2-1 do result[ N2+N2+i]:=(innerFT[0,i]+innerFT[1,i]*Q5c+innerFT[2,i]*Q5a+innerFT[3,i]*Q5d+innerFT[4,i]*Q5b)*commonFactor;
for i:=0 to N2-1 do result[ N2+N2+N2+i]:=(innerFT[0,i]+innerFT[1,i]*Q5b+innerFT[2,i]*Q5d+innerFT[3,i]*Q5a+innerFT[4,i]*Q5c)*commonFactor;
for i:=0 to N2-1 do result[N2+N2+N2+N2+i]:=(innerFT[0,i]+innerFT[1,i]*Q5a+innerFT[2,i]*Q5b+innerFT[3,i]*Q5c+innerFT[4,i]*Q5d)*commonFactor;
end else begin
for i:=0 to N2-1 do result[ i]:=(innerFT[0,i]+innerFT[1,i] +innerFT[2,i] +innerFT[3,i] +innerFT[4,i] );
for i:=0 to N2-1 do result[ N2+i]:=(innerFT[0,i]+innerFT[1,i]*Q5a+innerFT[2,i]*Q5b+innerFT[3,i]*Q5c+innerFT[4,i]*Q5d);
for i:=0 to N2-1 do result[ N2+N2+i]:=(innerFT[0,i]+innerFT[1,i]*Q5b+innerFT[2,i]*Q5d+innerFT[3,i]*Q5a+innerFT[4,i]*Q5c);
for i:=0 to N2-1 do result[ N2+N2+N2+i]:=(innerFT[0,i]+innerFT[1,i]*Q5c+innerFT[2,i]*Q5a+innerFT[3,i]*Q5d+innerFT[4,i]*Q5b);
for i:=0 to N2-1 do result[N2+N2+N2+N2+i]:=(innerFT[0,i]+innerFT[1,i]*Q5d+innerFT[2,i]*Q5c+innerFT[3,i]*Q5b+innerFT[4,i]*Q5a);
end;
end else begin
setLength(innerX,N2);
//Map 0,0 0,1 0,2 ... 0,N2-1 (N1 arrays of length N2 each)
// 1,0 1,1 1,2 ... 1,N2-1
// ... ...
// N1-1,0 ... N1-1,N2-1
// to 0,0 1,0 2,0 ... N1-1,0 (N2 array of length N1 each)
// 0,1 1,1 2,1 ... N1-1,1
// ... ...
// 0,N2-1 ... N1-1,N2-1
for i:=0 to N2-1 do setLength(innerX[i],N1);
for j:=0 to N2-1 do for k:=0 to N1-1 do innerX[j,k]:=innerFT[k,j];
//Note: N1 is prime by construction, so...
setLength(innerFT,N2);
for i:=0 to N2-1 do innerFT[i]:=DiscreteFourierTransform(innerX[i],inverse);
j:=0;
k:=0;
for i:=0 to length(X)-1 do begin
result[i]:=innerFT[j,k];
inc(j);
if j>=N2 then begin j:=0; inc(k); end;
end;
end;
end;
INITIALIZATION
randomize;
end.