parse.ym

%{
#include <stdio.h>
#include <time.h>

#include "parse_handler.h"

int yylex(void);
void yyerror(char*);
extern int wk_lex_line;

static struct tm wkTime;

typedef struct setdata {
	int reps;
	double weight;
	int extend_reps;
	double extend_weight;
} setdata;
%}

%token DASH COLON TO AM PM NO PLUS BY EOW
%token <string> LINE PTEXT AMPM
%token <ival> INTEGER
%token <dval> DOUBLE

%type <sdval> setspec;
%type <dval> weight;
%type <ival> reps;

%union
{
	int ival;
	double dval;
	char* string;
	setdata sdval;
}

%%
batch:
			{ wkOnStartParse(); }
		workouts
			{ wkOnEndParse(); }
		;

workouts:
		workout
		| workouts EOW workout
		;

workout:
		day
		times
		mood
		cardio
		comments
		exercises { wkOnEndWorkout(); }
		;

day:
		INTEGER DASH INTEGER DASH INTEGER
			{
				memset(&wkTime, 0, sizeof(struct tm));
				wkTime.tm_year = $1 - 1900;
				wkTime.tm_mon = $3 - 1;
				wkTime.tm_mday = $5;
			}
		;

times:
		time
			{ wkOnStartTime(&wkTime); }
		TO time
			{ wkOnEndTime(&wkTime); }
		;

time:
		INTEGER COLON INTEGER AM
			{
				wkTime.tm_hour = $1;
				wkTime.tm_min = $3;
			}
		| INTEGER COLON INTEGER PM
			{
				wkTime.tm_hour = $1 + 12;
				wkTime.tm_min = $3;
			}
		;


mood:
		LINE
			{ wkOnMood($1); }
		;

cardio:
		LINE
			{ wkOnCardio($1); }
		| NO
			{ wkOnCardio(NULL); }
		;

comments:
		LINE
			{ wkOnComments($1); }
		;

exercises:
		exercise
		| exercise exercises
		;

exercise:
		LINE
			{ wkOnExerciseName($1); }
		sets
		;

sets:
		set
		| set sets
		;

set:
		setspec
			{
				setdata sd = $1;
				wkOnSet(sd.reps, sd.weight, sd.extend_reps, sd.extend_weight, NULL);
			}
		| setspec PTEXT
			{
				setdata sd = $1;
				wkOnSet(sd.reps, sd.weight, sd.extend_reps, sd.extend_weight, $2);
			}
		;

setspec:
		reps BY weight
			{
				setdata sd;
				sd.reps = $1;
				sd.weight = $3;
				sd.extend_reps = 0;
				sd.extend_weight = 0;
				$$ = sd;
			}
		| reps PLUS reps BY weight
			{
				setdata sd;
				sd.reps = $1;
				sd.weight = $5;
				sd.extend_reps = $3;
				sd.extend_weight = $5;
				$$ = sd;
			}
		| reps BY weight PLUS reps BY weight
			{
				setdata sd;
				sd.reps = $1;
				sd.weight = $3;
				sd.extend_reps = $5;
				sd.extend_weight = $7;
				$$ = sd;
			}
		;

weight:
		INTEGER
			{ $$ = (double)$1; }
		| DOUBLE
		;

reps:
		INTEGER
		;
%%
void yyerror(char* s)
{
  fprintf(stderr, "line %d: %s\n", wk_lex_line, s);
  return;
}