build.gradle

import org.springframework.boot.gradle.plugin.SpringBootPlugin

buildscript {
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath 'org.springframework.boot:spring-boot-gradle-plugin:2.5.5'
    }
}

ext {
    springCloudVersion = "2020.0.4"
    alibabaCloudVersion = "2020.0.RC1"
    springCloudK8sVersion = '2.0.1'
}

allprojects {
    repositories {
        mavenCentral()
    }
}

subprojects {
    apply plugin: "java"
    apply plugin: "org.springframework.boot"
    apply plugin: "io.spring.dependency-management"

    version = "0.0.1"

    sourceCompatibility = '1.8'
    targetCompatibility = '1.8'

    def defaultEncoding = 'UTF-8'
    tasks.withType(AbstractCompile).forEach { it.options.encoding = defaultEncoding }

    javadoc {
        options.encoding = defaultEncoding
        options.addBooleanOption('Xdoclint:none', true)
    }

    compileJava.dependsOn(processResources)

    springBoot {
        buildInfo()
    }

    bootJar {
        archiveFileName.set('app.jar')
    }

    dependencyManagement {
        imports {
            mavenBom "org.springframework.cloud:spring-cloud-dependencies:${springCloudVersion}"
            mavenBom "org.springframework.cloud:spring-cloud-kubernetes-dependencies:${springCloudK8sVersion}"
            mavenBom "com.alibaba.cloud:spring-cloud-alibaba-dependencies:${alibabaCloudVersion}"
            mavenBom SpringBootPlugin.BOM_COORDINATES
        }
    }

    dependencies {
        annotationProcessor "org.springframework.boot:spring-boot-configuration-processor"
        compileOnly "org.springframework.boot:spring-boot-configuration-processor"
        implementation "org.springframework.boot:spring-boot-starter-actuator"
        implementation "org.springframework.cloud:spring-cloud-starter"
        implementation "org.springframework.cloud:spring-cloud-starter-kubernetes-fabric8-all"
        implementation fileTree(dir: 'libs', includes: ['*.jar'])
    }
}