Alternate sly-db display

[AkashaP]

Some of these problems are probably just my own configuration (i think i replicated on spacemacs too but i can't remember) but here were the issues i was coming across that I am addressing in these changes:

• Debugger kept getting either duplicated, or put into a different frame every time. Think this is something to do with the debugger auto focus customisation. I believe it may work fine with like, two windows, but I often work with 4 windows and new debugger windows constantly jumping around stressed me out.
• If user is typing code and a debugger is invoked, the window can briefly switch over to the debugger causing user to type into the wrong buffer for a second.
  for example, just try running (sleep 5) unbound-variable-error-creator, quickly switch to another buffer and hold down A. I find when the debugger is created, for a split second it gets focus and the A will be sent to the debugger, which is a hotkey for 'terminate inferior lisp process', obviously undesirable to press on accident. The with-selected-window macro of emacs is really built foolishly, as admitted in the documentation, it works by actually switching the window of focus for a split second.

I just finished this patch and i think it fixes these issues but i've only lightly tested it also it isn't really my best code i'm kind of scared to make any more changes right now

patch https://gist.github.com/AkashaP/849b7e4e5fa9d208f101f082864cea03

or replace the functions sly-db--display-debugger and sly-db-setup at roughly line 5505 with below:

(defun sly-db--display-debugger (_thread)
  "Display (or pop to) sly-db for THREAD as appropriate.
Also mark the window as a debugger window."
  (let* ((action '(sly-db--display-in-prev-sly-db-window))
         (buffer (current-buffer))
         (win
          (if (get-buffer-window buffer)
              (if (eq sly--send-last-command last-command)
                  (progn
                    (select-window (get-buffer-window buffer))
                    (selected-window))
                (get-buffer-window buffer))
            (if (or (eq sly-db-focus-debugger 'auto)
                    (eq sly--send-last-command last-command))
                (progn
                  (pop-to-buffer buffer action)
                  (selected-window))
              (if (and sly--send-last-command last-command
                       (eq sly--send-last-command last-command))
                  (progn
                    (select-window (display-buffer buffer action))
                    (selected-window))
                (display-buffer buffer action)))
            (get-buffer-window buffer))))
    (set-window-parameter win 'sly-db buffer)
    win))

(defun sly-db-setup (thread level condition restarts frame-specs conts)
  "Setup a new SLY-DB buffer.
CONDITION is a string describing the condition to debug.
RESTARTS is a list of strings (NAME DESCRIPTION) for each
available restart.  FRAME-SPECS is a list of (NUMBER DESCRIPTION
&optional PLIST) describing the initial portion of the
backtrace. Frames are numbered from 0.  CONTS is a list of
pending Emacs continuations."
  (with-current-buffer (sly-db-get-buffer thread)
    (cl-assert (if (equal sly-db-level level)
                   (equal sly-db-condition condition)
                 t)
               () "Bug: sly-db-level is equal but condition differs\n%s\n%s"
               sly-db-condition condition)
    (sly-db--display-debugger thread)
    (unless (equal sly-db-level level)
      (let ((inhibit-read-only t))
        (sly-db-mode)
        (add-hook 'kill-buffer-query-functions
                  #'sly-db-confirm-buffer-kill
                  nil t)
        (setq sly-current-thread thread)
        (setq sly-db-level level)
        (setq mode-name (format "sly-db[%d]" sly-db-level))
        (setq sly-db-condition condition)
        (setq sly-db-restarts restarts)
        (setq sly-db-continuations conts)
        (sly-db-insert-condition condition)
        (insert "\n\n" (sly-db-in-face section "Restarts:") "\n")
        (setq sly-db-restart-list-start-marker (point-marker))
        (sly-db-insert-restarts restarts 0 sly-db-initial-restart-limit)
        (insert "\n" (sly-db-in-face section "Backtrace:") "\n")
        (setq sly-db-backtrace-start-marker (point-marker))
        (save-excursion
          (if frame-specs
              (sly-db-insert-frames (sly-db-prune-initial-frames frame-specs) t)
            (insert "[No backtrace]")))
        (run-hooks 'sly-db-hook)
        (set-syntax-table lisp-mode-syntax-table)))
    (sly-recenter (point-min) 'allow-moving-point)
    (when sly--stack-eval-tags
      (sly-message "Entering recursive edit..")
      (recursive-edit))))