build.gradle

buildscript {
    repositories {
        mavenCentral()
        maven {
            name = "forge"
            url = "http://files.minecraftforge.net/maven"
        }
        maven {
            name = "sonatype"
            url = "https://oss.sonatype.org/content/repositories/snapshots/"
        }
    }
    dependencies {
        classpath "net.minecraftforge.gradle:ForgeGradle:2.2-SNAPSHOT"
    }
}

// Ensure that we're using UTF-8.
tasks.withType(JavaCompile) {
    options.encoding = "UTF-8"
}

apply plugin: "idea"

idea {
    module {
        // For some reason this is necessary for IDEA 2014 workspaces to recognize assets
        inheritOutputDirs = true
    }
}

apply plugin: "net.minecraftforge.gradle.forge"

repositories {

}

// Define properties file
ext.configFile = file "build.properties"

configFile.withReader {
    // Load config. It shall from now be referenced as simply config or project.config
    def prop = new Properties()
    prop.load(it)
    project.ext.config = new ConfigSlurper().parse prop
}

version = config.minecraft_version + "-" + config.mod_version
group = "org.halvors.nuclearphysics"
archivesBaseName = "nuclearphysics"
sourceCompatibility = "1.8"
targetCompatibility = "1.8"

minecraft {
	version = config.minecraft_version + "-" + config.forge_version
    runDir = "eclipse"
    mappings = config.mcp_mappings

    // Replace version in Reference.java
    replace "@version", config.mod_version
}

dependencies {

}

processResources {
    // This will ensure that this task is redone when this versions change.
    inputs.property "mod_version", config.mod_version
    inputs.property "minecraft_version", config.minecraft_version
    inputs.property "forge_version", config.forge_version

    // Replace stuff in mcmod.info, nothing else
    from(sourceSets.main.resources.srcDirs) {
        include "mcmod.info"

        // Replace version and minecraft_version
        expand "version" : config.mod_version,
               "minecraft_version" : config.minecraft_version
    }

    // Copy everything else
    from(sourceSets.main.resources.srcDirs) {
		exclude "mcmod.info"
    }
}