-
Notifications
You must be signed in to change notification settings - Fork 0
/
posframe-20210311.937.tar
1496 lines (1271 loc) · 63 KB
/
posframe-20210311.937.tar
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
posframe-20210311.937/ 000755 000765 000024 00000000000 14024410245 015270 5 ustar 00duynguyen staff 000000 000000 posframe-20210311.937/posframe-pkg.el 000644 000765 000024 00000000706 14024410245 020210 0 ustar 00duynguyen staff 000000 000000 ;;; Generated package description from /Users/duynguyen/.emacs.d/elpa/posframe-20210311.937/posframe.el -*- no-byte-compile: t -*-
(define-package "posframe" "20210311.937" "Pop a posframe (just a frame) at point" '((emacs "26")) :commit "fff21ccb706b576f4074883f9fa87d2bcc534096" :authors '(("Feng Shu" . "[email protected]")) :maintainer '("Feng Shu" . "[email protected]") :keywords '("convenience" "tooltip") :url "https://github.com/tumashu/posframe")
posframe-20210311.937/posframe.el 000644 000765 000024 00000152174 14024410244 017437 0 ustar 00duynguyen staff 000000 000000 ;;; posframe.el --- Pop a posframe (just a frame) at point -*- lexical-binding:t -*-
;; Copyright (C) 2018-2020 Free Software Foundation, Inc.
;; Author: Feng Shu <[email protected]>
;; Maintainer: Feng Shu <[email protected]>
;; URL: https://github.com/tumashu/posframe
;; Package-Version: 20210311.937
;; Package-Commit: fff21ccb706b576f4074883f9fa87d2bcc534096
;; Version: 0.8.8
;; Keywords: convenience, tooltip
;; Package-Requires: ((emacs "26"))
;; This file is part of GNU Emacs.
;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
;;; Commentary:
;; * Posframe README :README:
;; ** What is posframe?
;; Posframe can pop up a frame at point, this *posframe* is a
;; child-frame connected to its root window's buffer.
;; The main advantages are:
;; 1. It is fast enough for daily usage :-)
;; 2. It works well with CJK languages.
;; NOTE:
;; 1. For MacOS users, posframe needs Emacs version >= 26.0.91
;; 2. GNOME users with GTK3 builds need Emacs 27 or later.
;; See variable `posframe-gtk-resize-child-frames'
;; which auto-detects this configuration.
;; More details:
;; 1. [[https://git.savannah.gnu.org/cgit/emacs.git/commit/?h=emacs-27&id=c49d379f17bcb0ce82604def2eaa04bda00bd5ec][Fix some problems with moving and resizing child frames]]
;; 2. [[https://lists.gnu.org/archive/html/emacs-devel/2020-01/msg00343.html][Emacs's set-frame-size can not work well with gnome-shell?]]
;; [[./snapshots/posframe-1.png]]
;; ** Installation
;; #+BEGIN_EXAMPLE
;; (require 'posframe)
;; #+END_EXAMPLE
;; ** Usage
;; *** Create a posframe
;; **** Simple way
;; #+BEGIN_EXAMPLE
;; (when (posframe-workable-p)
;; (posframe-show " *my-posframe-buffer*"
;; :string "This is a test"
;; :position (point)))
;; #+END_EXAMPLE
;; **** Advanced way
;; #+BEGIN_EXAMPLE
;; (defvar my-posframe-buffer " *my-posframe-buffer*")
;; (with-current-buffer (get-buffer-create my-posframe-buffer)
;; (erase-buffer)
;; (insert "Hello world"))
;; (when (posframe-workable-p)
;; (posframe-show my-posframe-buffer
;; :position (point)))
;; #+END_EXAMPLE
;; **** Arguments
;; #+BEGIN_EXAMPLE
;; C-h f posframe-show
;; #+END_EXAMPLE
;; *** Hide a posframe
;; #+BEGIN_EXAMPLE
;; (posframe-hide " *my-posframe-buffer*")
;; #+END_EXAMPLE
;; *** Hide all posframes
;; #+BEGIN_EXAMPLE
;; M-x posframe-hide-all
;; #+END_EXAMPLE
;; *** Delete a posframe
;; 1. Delete posframe and its buffer
;; #+BEGIN_EXAMPLE
;; (posframe-delete " *my-posframe-buffer*")
;; #+END_EXAMPLE
;; 2. Only delete the frame
;; #+BEGIN_EXAMPLE
;; (posframe-delete-frame " *my-posframe-buffer*")
;; #+END_EXAMPLE
;; *** Delete all posframes
;; #+BEGIN_EXAMPLE
;; M-x posframe-delete-all
;; #+END_EXAMPLE
;; Note: this command will delete all posframe buffers.
;; You probably shouldn't use it if you are sharing a buffer
;; between posframe and other packages.
;; *** Customizing mouse pointer control
;; By default, posframe moves the pointer to point (0,0) in
;; the frame, as a way to address an issue with mouse focus.
;; To disable this feature, add this to your init.el:
;; #+BEGIN_EXAMPLE
;; (setq posframe-mouse-banish nil)
;; #+END_EXAMPLE
;; *** Set fallback arguments of posframe-show
;; Users can set fallback values of posframe-show's arguments with the
;; help of `posframe-arghandler'. The example below sets fallback
;; border-width to 10 and fallback background color to green.
;; #+BEGIN_EXAMPLE
;; (setq posframe-arghandler #'my-posframe-arghandler)
;; (defun my-posframe-arghandler (buffer-or-name arg-name value)
;; (let ((info '(:internal-border-width 10 :background-color "green")))
;; (or (plist-get info arg-name) value)))
;; #+END_EXAMPLE
;; *** Some packages which use posframe
;; 1. [[https://github.com/yanghaoxie/which-key-posframe][which-key-posframe]]
;; 2. [[https://github.com/conao3/ddskk-posframe.el][ddskk-posframe]]
;; 3. [[https://github.com/tumashu/pyim][pyim]]
;; 4. [[https://github.com/tumashu/ivy-posframe][ivy-posframe]]
;; 5. [[https://github.com/tumashu/company-posframe][company-posframe]]
;; 6. [[https://github.com/randomwangran/org-marginalia-posframe][org-marginalia-posframe]]
;; 7. ...
;;; Code:
;; * posframe's code :CODE:
(require 'cl-lib)
(defgroup posframe nil
"Pop a posframe (just a frame) at point"
:group 'lisp
:prefix "posframe-")
(defcustom posframe-mouse-banish (not (eq system-type 'darwin))
"Mouse will be moved to (0 , 0) when it is non-nil.
This option is used to solve the problem of child frame getting
focus, with the help of `posframe--redirect-posframe-focus',
setting this option to `nil' will work well in *most* cases."
:group 'posframe
:type 'boolean)
(defcustom posframe-inhibit-double-buffering nil
"Set the posframe's frame-parameter: inhibit-double-buffering."
:group 'posframe
:type 'boolean)
(defcustom posframe-arghandler #'posframe-arghandler-default
"A function used to handle posframe-show's argument.
Users can use this feature to set the default value of
posframe-show's arguments."
:group 'posframe
:type 'function)
(defvar-local posframe--frame nil
"Record posframe's frame.")
(defvar-local posframe--last-posframe-pixel-position nil
"Record the last pixel position of posframe's frame.")
(defvar-local posframe--last-posframe-size nil
"Record the last size of posframe's frame.")
(defvar-local posframe--last-posframe-displayed-size nil
"Record the last displayed size of posframe's frame.")
(defvar-local posframe--last-parent-frame-size nil
"Record the last size of posframe's parent-frame.")
(defvar-local posframe--last-poshandler-info nil
"Record the last poshandler info.")
(defvar-local posframe--last-font-height-info nil
"Record the last font height info.")
(defvar-local posframe--last-args nil
"Record the last arguments of `posframe--create-posframe'.
If these args have changed, posframe will recreate its
frame.")
(defvar-local posframe--timeout-timer nil
"Record the timer to deal with timeout argument of `posframe-show'.")
(defvar-local posframe--refresh-timer nil
"Record the timer to deal with refresh argument of `posframe-show'.")
(defvar-local posframe--initialized-p nil
"Record initialize status of `posframe-show'.")
;; Avoid compilation warnings on Emacs < 27.
(defvar x-gtk-resize-child-frames)
(defvar posframe-gtk-resize-child-frames
(when (and
(> emacs-major-version 26)
(string-match-p "GTK3" system-configuration-features)
(let ((value (or (getenv "XDG_CURRENT_DESKTOP") (getenv "DESKTOP_SESSION"))))
(and (stringp value)
;; It can be "ubuntu:GNOME".
(string-match-p "GNOME" value))))
;; Not future-proof, but we can use it now.
'resize-mode)
"Value to bind `x-gtk-resize-child-frames' to.
The value `resize-mode' only has effect on new child frames, so
if you change it, call `posframe-delete-all' for it to take
effect.")
;;;###autoload
(defun posframe-workable-p ()
"Test posframe workable status."
(and (>= emacs-major-version 26)
(not (or noninteractive
emacs-basic-display
(not (display-graphic-p))))))
(cl-defun posframe--create-posframe (buffer-or-name
&key
parent-frame
foreground-color
background-color
left-fringe
right-fringe
border-width
border-color
internal-border-width
internal-border-color
font
keep-ratio
lines-truncate
override-parameters
respect-header-line
respect-mode-line
accept-focus)
"Create and return a posframe child frame.
This posframe's buffer is BUFFER-OR-NAME."
(let ((left-fringe (or left-fringe 0))
(right-fringe (or right-fringe 0))
;; See emacs.git: Add distinct controls for child frames' borders (Bug#45620)
;; http://git.savannah.gnu.org/cgit/emacs.git/commit/?id=ff7b1a133bfa7f2614650f8551824ffaef13fadc
(border-width (or border-width internal-border-width 0))
(border-color (or border-color internal-border-color))
(buffer (get-buffer-create buffer-or-name))
(after-make-frame-functions nil)
(x-gtk-resize-child-frames posframe-gtk-resize-child-frames)
(args (list parent-frame
foreground-color
background-color
right-fringe
left-fringe
border-width
internal-border-width
font
keep-ratio
override-parameters
respect-header-line
respect-mode-line
accept-focus)))
(with-current-buffer buffer
;; Many variables take effect after call `set-window-buffer'
(setq-local display-line-numbers nil)
(setq-local frame-title-format "")
(setq-local left-margin-width nil)
(setq-local right-margin-width nil)
(setq-local left-fringe-width nil)
(setq-local right-fringe-width nil)
(setq-local fringes-outside-margins 0)
;; Need to use `lines-truncate' as our keyword variable instead of
;; `truncate-lines' so we don't shadow the variable that we are trying to
;; set.
(setq-local truncate-lines lines-truncate)
(setq-local cursor-type nil)
(setq-local cursor-in-non-selected-windows nil)
(setq-local show-trailing-whitespace nil)
(unless respect-mode-line
(setq-local mode-line-format nil))
(unless respect-header-line
(setq-local header-line-format nil))
(add-hook 'kill-buffer-hook #'posframe-auto-delete nil t)
;; Create child-frame
(unless (and (frame-live-p posframe--frame)
;; For speed reason, posframe will reuse
;; existing frame at possible, but when
;; user change args, recreating frame
;; is needed.
(equal posframe--last-args args))
(posframe-delete-frame buffer)
(setq-local posframe--last-args args)
(setq-local posframe--last-posframe-pixel-position nil)
(setq-local posframe--last-posframe-size nil)
(setq-local posframe--frame
(make-frame
`(,@override-parameters
,(when foreground-color
(cons 'foreground-color foreground-color))
,(when background-color
(cons 'background-color background-color))
,(when font
(cons 'font font))
(parent-frame . ,(or parent-frame (window-frame)))
(keep-ratio ,keep-ratio)
(posframe-buffer . ,(cons (buffer-name buffer)
buffer))
(fullscreen . nil)
(no-accept-focus . ,(not accept-focus))
(min-width . 0)
(min-height . 0)
(border-width . 0)
(internal-border-width . ,border-width)
(child-frame-border-width . ,border-width)
(vertical-scroll-bars . nil)
(horizontal-scroll-bars . nil)
(left-fringe . ,left-fringe)
(right-fringe . ,right-fringe)
(menu-bar-lines . 0)
(tool-bar-lines . 0)
(tab-bar-lines . 0)
(line-spacing . 0)
(unsplittable . t)
(no-other-frame . t)
(undecorated . t)
(visibility . nil)
(cursor-type . nil)
(minibuffer . nil)
(width . 1)
(height . 1)
(no-special-glyphs . t)
(inhibit-double-buffering . ,posframe-inhibit-double-buffering)
;; Do not save child-frame when use desktop.el
(desktop-dont-save . t))))
(when border-color
(set-face-background 'internal-border border-color posframe--frame)
(when (facep 'child-frame-border)
(set-face-background 'child-frame-border border-color posframe--frame)))
(let ((posframe-window (frame-root-window posframe--frame)))
;; This method is more stable than 'setq mode/header-line-format nil'
(unless respect-mode-line
(set-window-parameter posframe-window 'mode-line-format 'none))
(unless respect-header-line
(set-window-parameter posframe-window 'header-line-format 'none))
(set-window-buffer posframe-window buffer)
(set-window-dedicated-p posframe-window t)))
posframe--frame)))
(defun posframe-arghandler-default (_buffer-or-name _arg-name value)
"The default value of `posframe-arghandler'. Return VALUE."
value)
;;;###autoload
(cl-defun posframe-show (buffer-or-name
&key
string
position
poshandler
width
height
min-width
min-height
x-pixel-offset
y-pixel-offset
left-fringe
right-fringe
border-width
border-color
internal-border-width
internal-border-color
font
foreground-color
background-color
respect-header-line
respect-mode-line
initialize
no-properties
keep-ratio
lines-truncate
override-parameters
timeout
refresh
accept-focus
hidehandler
&allow-other-keys)
"Pop up a posframe and show STRING at POSITION.
POSITION can be:
1. An integer, meaning point position.
2. A cons of two integers, meaning absolute X and Y coordinates.
3. Other type, in which case the corresponding POSHANDLER should be
provided.
POSHANDLER is a function of one argument returning an actual
position. Its argument is a plist of the following form:
(:position xxx
:position-info xxx
:poshandler xxx
:font-height xxx
:font-width xxx
:posframe xxx
:posframe-width xxx
:posframe-height xxx
:posframe-buffer xxx
:parent-frame xxx
:parent-window-left xxx
:parent-window-top xxx
:parent-frame-width xxx
:parent-frame-height xxx
:parent-window xxx
:parent-window-width xxx
:parent-window-height xxx
:minibuffer-height xxx
:mode-line-height xxx
:header-line-height xxx
:tab-line-height xxx
:x-pixel-offset xxx
:y-pixel-offset xxx)
By default, poshandler is auto-selected based on the type of POSITION,
but the selection can be overridden using the POSHANDLER argument.
The builtin poshandler functions are listed below:
1. `posframe-poshandler-frame-center'
2. `posframe-poshandler-frame-top-center'
3. `posframe-poshandler-frame-top-left-corner'
4. `posframe-poshandler-frame-top-right-corner'
5. `posframe-poshandler-frame-bottom-center'
6. `posframe-poshandler-frame-bottom-left-corner'
7. `posframe-poshandler-frame-bottom-right-corner'
8. `posframe-poshandler-window-center'
9. `posframe-poshandler-window-top-center'
10. `posframe-poshandler-window-top-left-corner'
11. `posframe-poshandler-window-top-right-corner'
12. `posframe-poshandler-window-bottom-center'
13. `posframe-poshandler-window-bottom-left-corner'
14. `posframe-poshandler-window-bottom-right-corner'
15. `posframe-poshandler-point-top-left-corner'
16. `posframe-poshandler-point-bottom-left-corner'
17. `posframe-poshandler-point-bottom-left-corner-upward'
18. `posframe-poshandler-point-window-center'
by the way, poshandler can be used by other packages easily
(for example: mini-frame) with the help of function
`posframe-poshandler-argbuilder'. like:
(let* ((info (posframe-poshandler-argbuilder child-frame))
(posn (posframe-poshandler-window-center info)))
`((left . ,(car posn))
(top . ,(cdr posn))))
This posframe's buffer is BUFFER-OR-NAME, which can be a buffer
or a name of a (possibly nonexistent) buffer.
If NO-PROPERTIES is non-nil, The STRING's properties will
be removed before being shown in posframe.
WIDTH, MIN-WIDTH, HEIGHT and MIN-HEIGHT, specify bounds on the
new total size of posframe. MIN-HEIGHT and MIN-WIDTH default to
the values of ‘window-min-height’ and ‘window-min-width’
respectively. These arguments are specified in the canonical
character width and height of posframe.
If LEFT-FRINGE or RIGHT-FRINGE is a number, left fringe or
right fringe with be shown with the specified width.
By default, posframe shows no borders, but users can specify
borders by setting BORDER-WIDTH to a positive number. Border
color can be specified by BORDER-COLOR.
INTERNAL-BORDER-WIDTH and INTERNAL-BORDER-COLOR are same as
BORDER-WIDTH and INTERNAL-BORDER-COLOR, but do not suggest to use
for the reason:
Add distinct controls for child frames' borders (Bug#45620)
http://git.savannah.gnu.org/cgit/emacs.git/commit/?id=ff7b1a133bfa7f2614650f8551824ffaef13fadc
Posframe's font as well as foreground and background colors are
derived from the current frame by default, but can be overridden
using the FONT, FOREGROUND-COLOR and BACKGROUND-COLOR arguments,
respectively.
By default, posframe will display no header-line, mode-line and
tab-line. In case a header-line, mode-line or tab-line is
desired, users can set RESPECT-HEADER-LINE and RESPECT-MODE-LINE
to t.
INITIALIZE is a function with no argument. It will run when
posframe buffer is first selected with `with-current-buffer'
in `posframe-show', and only run once (for performance reasons).
If LINES-TRUNCATE is non-nil, then lines will truncate in the
posframe instead of wrap.
OVERRIDE-PARAMETERS is very powful, *all* the frame parameters
used by posframe's frame can be overridden by it.
TIMEOUT can specify the number of seconds after which the posframe
will auto-hide.
If REFRESH is a number, posframe's frame-size will be re-adjusted
every REFRESH seconds.
When ACCEPT-FOCUS is non-nil, posframe will accept focus.
be careful, you may face some bugs when set it to non-nil.
HIDEHANDLER is a function, when it return t, posframe will be
hide when `post-command-hook' is executed, this function has a
plist argument:
(:posframe-buffer xxx
:posframe-parent-buffer xxx)
The builtin hidehandler functions are listed below:
1. `posframe-hidehandler-when-buffer-switch'
You can use `posframe-delete-all' to delete all posframes."
(let* ((position (or (funcall posframe-arghandler buffer-or-name :position position) (point)))
(poshandler (funcall posframe-arghandler buffer-or-name :poshandler poshandler))
(width (funcall posframe-arghandler buffer-or-name :width width))
(height (funcall posframe-arghandler buffer-or-name :height height))
(min-width (or (funcall posframe-arghandler buffer-or-name :min-width min-width) 1))
(min-height (or (funcall posframe-arghandler buffer-or-name :min-height min-height) 1))
(x-pixel-offset (or (funcall posframe-arghandler buffer-or-name :x-pixel-offset x-pixel-offset) 0))
(y-pixel-offset (or (funcall posframe-arghandler buffer-or-name :y-pixel-offset y-pixel-offset) 0))
(left-fringe (funcall posframe-arghandler buffer-or-name :left-fringe left-fringe))
(right-fringe (funcall posframe-arghandler buffer-or-name :right-fringe right-fringe))
(border-width (funcall posframe-arghandler buffer-or-name :border-width border-width))
(border-color (funcall posframe-arghandler buffer-or-name :border-color border-color))
(internal-border-width (funcall posframe-arghandler buffer-or-name :internal-border-width internal-border-width))
(internal-border-color (funcall posframe-arghandler buffer-or-name :internal-border-color internal-border-color))
(font (funcall posframe-arghandler buffer-or-name :font font))
(foreground-color (funcall posframe-arghandler buffer-or-name :foreground-color foreground-color))
(background-color (funcall posframe-arghandler buffer-or-name :background-color background-color))
(respect-header-line (funcall posframe-arghandler buffer-or-name :respect-header-line respect-header-line))
(respect-mode-line (funcall posframe-arghandler buffer-or-name :respect-mode-line respect-mode-line))
(initialize (funcall posframe-arghandler buffer-or-name :initialize initialize))
(no-properties (funcall posframe-arghandler buffer-or-name :no-properties no-properties))
(keep-ratio (funcall posframe-arghandler buffer-or-name :keep-ratio keep-ratio))
(lines-truncate (funcall posframe-arghandler buffer-or-name :lines-truncate lines-truncate))
(override-parameters (funcall posframe-arghandler buffer-or-name :override-parameters override-parameters))
(timeout (funcall posframe-arghandler buffer-or-name :timeout timeout))
(refresh (funcall posframe-arghandler buffer-or-name :refresh refresh))
(accept-focus (funcall posframe-arghandler buffer-or-name :accept-focus accept-focus))
(hidehandler (funcall posframe-arghandler buffer-or-name :hidehandler hidehandler))
;;-----------------------------------------------------
(buffer (get-buffer-create buffer-or-name))
(parent-window (selected-window))
(parent-window-top (window-pixel-top parent-window))
(parent-window-left (window-pixel-left parent-window))
(parent-window-width (window-pixel-width parent-window))
(parent-window-height (window-pixel-height parent-window))
(position-info
(if (integerp position)
(posn-at-point position parent-window)
position))
(parent-frame (window-frame parent-window))
(parent-frame-width (frame-pixel-width parent-frame))
(parent-frame-height (frame-pixel-height parent-frame))
(font-width (default-font-width))
(font-height (with-current-buffer (window-buffer parent-window)
(posframe--get-font-height position)))
(mode-line-height (window-mode-line-height))
(minibuffer-height (window-pixel-height (minibuffer-window)))
(header-line-height (window-header-line-height parent-window))
(tab-line-height (if (functionp 'window-tab-line-height)
(window-tab-line-height)
0))
(frame-resize-pixelwise t)
posframe)
(with-current-buffer buffer
;; Initialize
(unless posframe--initialized-p
(let ((func initialize))
(when (functionp func)
(funcall func)
(setq posframe--initialized-p t))))
;; Create posframe
(setq posframe
(posframe--create-posframe
buffer
:font font
:parent-frame parent-frame
:left-fringe left-fringe
:right-fringe right-fringe
:border-width border-width
:border-color border-color
:internal-border-width internal-border-width
:internal-border-color internal-border-color
:foreground-color foreground-color
:background-color background-color
:keep-ratio keep-ratio
:lines-truncate lines-truncate
:respect-header-line respect-header-line
:respect-mode-line respect-mode-line
:override-parameters override-parameters
:accept-focus accept-focus))
;; Remove tab-bar always.
(set-frame-parameter posframe 'tab-bar-lines 0)
(when (version< "27.0" emacs-version)
(setq-local tab-line-format nil))
;; Move mouse to (0 . 0)
(posframe--mouse-banish parent-frame posframe)
;; Insert string into the posframe buffer
(posframe--insert-string string no-properties)
;; Set posframe's size
(posframe--set-frame-size
posframe height min-height width min-width)
;; Move posframe
(posframe--set-frame-position
posframe
(posframe-run-poshandler
;; All poshandlers will get info from this plist.
(list :position position
:position-info position-info
:poshandler poshandler
:font-height font-height
:font-width font-width
:posframe posframe
:posframe-width (frame-pixel-width posframe)
:posframe-height (frame-pixel-height posframe)
:posframe-buffer buffer
:parent-frame parent-frame
:parent-frame-width parent-frame-width
:parent-frame-height parent-frame-height
:parent-window parent-window
:parent-window-top parent-window-top
:parent-window-left parent-window-left
:parent-window-width parent-window-width
:parent-window-height parent-window-height
:mode-line-height mode-line-height
:minibuffer-height minibuffer-height
:header-line-height header-line-height
:tab-line-height tab-line-height
:x-pixel-offset x-pixel-offset
:y-pixel-offset y-pixel-offset))
parent-frame-width parent-frame-height)
;; Delay hide posframe when timeout is a number.
(posframe--run-timeout-timer posframe timeout)
;; Re-adjust posframe's size when buffer's content has changed.
(posframe--run-refresh-timer
posframe refresh height min-height width min-width)
;; Make sure not hide buffer's content for scroll down.
(set-window-point (frame-root-window posframe--frame) 0)
;; Force raise the current posframe.
(raise-frame posframe--frame)
;; Hide posframe when switch buffer
(let* ((parent-buffer (window-buffer parent-window))
(parent-buffer-name (buffer-name parent-buffer)))
(set-frame-parameter posframe--frame 'posframe-hidehandler hidehandler)
(set-frame-parameter posframe--frame 'posframe-parent-buffer
(cons parent-buffer-name parent-buffer)))
;; Return posframe
posframe)))
(defun posframe--get-font-height (position)
"Get the font's height at POSITION."
(if (eq position (car posframe--last-font-height-info))
(cdr posframe--last-font-height-info)
(let* ((font (when (and (integerp position)
(not (= position 1)))
(font-at (if (>= position (point-max))
(- (point-max) 1)
position))))
(height (when (integerp position)
(if (or (= position 1) (not (fontp font)))
(default-line-height)
(aref (font-info font) 3)))))
(setq posframe--last-font-height-info
(cons position height))
height)))
(defun posframe--redirect-posframe-focus ()
"Redirect focus from the posframe to the parent frame. This prevents the
posframe from catching keyboard input if the window manager selects it."
(when (and (eq (selected-frame) posframe--frame)
;; Do not redirect focus when posframe can accept focus.
;; See posframe-show's accept-focus argument.
(frame-parameter (selected-frame) 'no-accept-focus))
(redirect-frame-focus posframe--frame (frame-parent))))
(if (version< emacs-version "27.1")
(add-hook 'focus-in-hook #'posframe--redirect-posframe-focus)
(add-function :after after-focus-change-function #'posframe--redirect-posframe-focus))
(defun posframe--mouse-banish (parent-frame &optional posframe)
"Banish mouse to the (0 . 0) of PARENT-FRAME.
Do not banish mouse when no-accept-focus frame parameter of POSFRAME
is non-nil.
FIXME: This is a hacky fix for the mouse focus problem, which like:
https://github.com/tumashu/posframe/issues/4#issuecomment-357514918"
(when (and posframe-mouse-banish
;; Do not banish mouse when posframe can accept focus.
;; See posframe-show's accept-focus argument.
(frame-parameter posframe 'no-accept-focus)
(not (equal (cdr (mouse-position)) '(0 . 0))))
(set-mouse-position parent-frame 0 0)))
(defun posframe--insert-string (string no-properties)
"Insert STRING to current buffer.
If NO-PROPERTIES is non-nil, all properties of STRING
will be removed."
(when (and string (stringp string))
(remove-text-properties
0 (length string) '(read-only t) string)
(let ((str (if no-properties
(substring-no-properties string)
string)))
(erase-buffer)
(insert str))))
(defun posframe--fit-frame-to-buffer (posframe height min-height width min-width)
;; This only has effect if the user set the latter var to `hide'.
(let ((x-gtk-resize-child-frames posframe-gtk-resize-child-frames))
;; More info: Don't skip empty lines when fitting mini frame to buffer (Bug#44080)
;; http://git.savannah.gnu.org/cgit/emacs.git/commit/?id=e0de9f3295b4c46cb7198ec0b9634809d7b7a36d
(if (functionp 'fit-frame-to-buffer-1)
(fit-frame-to-buffer-1
posframe height min-height width min-width nil nil nil)
(fit-frame-to-buffer
posframe height min-height width min-width))))
(defun posframe--set-frame-size (posframe height min-height width min-width)
"Set POSFRAME's size.
It will set the size by the POSFRAME's HEIGHT, MIN-HEIGHT
WIDTH and MIN-WIDTH."
(posframe--fit-frame-to-buffer
posframe height min-height width min-width)
(setq-local posframe--last-posframe-size
(list height min-height width min-width)))
(defun posframe--set-frame-position (posframe position
parent-frame-width
parent-frame-height)
"Move POSFRAME to POSITION.
This need PARENT-FRAME-WIDTH and PARENT-FRAME-HEIGHT"
(unless (and (equal position posframe--last-posframe-pixel-position)
;; When working frame's size change, re-posit
;; the posframe.
(equal posframe--last-parent-frame-size
(cons parent-frame-width parent-frame-height))
(equal posframe--last-posframe-displayed-size
(cons (frame-pixel-width posframe)
(frame-pixel-height posframe))))
(set-frame-position posframe (car position) (cdr position))
(setq-local posframe--last-posframe-pixel-position position)
(setq-local posframe--last-parent-frame-size
(cons parent-frame-width parent-frame-height))
(setq-local posframe--last-posframe-displayed-size
(cons (frame-pixel-width posframe)
(frame-pixel-height posframe))))
;; Make posframe's posframe--frame visible
(unless (frame-visible-p posframe)
(make-frame-visible posframe)
;; Fix issue: https://github.com/tumashu/ivy-posframe/pull/30
(redraw-frame posframe)))
(defun posframe--run-timeout-timer (posframe secs)
"Hide POSFRAME after a delay of SECS seconds."
(when (and (numberp secs) (> secs 0))
(when (timerp posframe--timeout-timer)
(cancel-timer posframe--timeout-timer))
(setq-local posframe--timeout-timer
(run-with-timer
secs nil #'posframe--make-frame-invisible posframe))))
(defun posframe--make-frame-invisible (frame)
"`make-frame-invisible' replacement to hide FRAME safely."
(when (frame-live-p frame)
(make-frame-invisible frame)))
(defun posframe--run-refresh-timer (posframe repeat
height min-height
width min-width)
"Refresh POSFRAME every REPEAT seconds.
It will set POSFRAME's size by the posframe's HEIGHT, MIN-HEIGHT,
WIDTH and MIN-WIDTH."
(when (and (numberp repeat) (> repeat 0))
(unless (and width height)
(when (timerp posframe--refresh-timer)
(cancel-timer posframe--refresh-timer))
(setq-local posframe--refresh-timer
(run-with-timer
nil repeat
#'(lambda (frame height min-height width min-width)
(let ((frame-resize-pixelwise t))
(when (and frame (frame-live-p frame))
(posframe--fit-frame-to-buffer
frame height min-height width min-width))))
posframe height min-height width min-width)))))
(defun posframe-refresh (buffer-or-name)
"Refresh posframe pertaining to BUFFER-OR-NAME.
For example:
(defvar buf \" *test*\")
(posframe-show buf)
(with-current-buffer buf
(erase-buffer)
(insert \"ffffffffffffff\")
(posframe-refresh buf))
User can use posframe-show's :refresh argument,
to do similar job:
(defvar buf \" *test*\")
(posframe-show buf :refresh 0.25)
(with-current-buffer buf
(erase-buffer)
(insert \"ffffffffffffff\"))"
(dolist (frame (frame-list))
(let ((buffer-info (frame-parameter frame 'posframe-buffer))
(frame-resize-pixelwise t))
(when (or (equal buffer-or-name (car buffer-info))
(equal buffer-or-name (cdr buffer-info)))
(with-current-buffer buffer-or-name
(apply #'posframe--fit-frame-to-buffer
frame posframe--last-posframe-size))))))
(defun posframe-hide (buffer-or-name)
"Hide posframe pertaining to BUFFER-OR-NAME.
BUFFER-OR-NAME can be a buffer or a buffer name."
;; Make sure buffer-list-update-hook is nil when posframe-hide is
;; called, otherwise:
;; (add-hook 'buffer-list-update-hook #'posframe-hide)
;; will lead to infinite recursion.
(let ((buffer-list-update-hook nil))
(dolist (frame (frame-list))
(let ((buffer-info (frame-parameter frame 'posframe-buffer)))
(when (or (equal buffer-or-name (car buffer-info))
(equal buffer-or-name (cdr buffer-info)))
(posframe--make-frame-invisible frame))))))
(defun posframe-run-hidehandler ()
"Run posframe hidehandler. this function is used in `post-command-hook'."
(ignore-errors
(dolist (frame (frame-list))
(let ((hidehandler (frame-parameter frame 'posframe-hidehandler))
(buffer (frame-parameter frame 'posframe-buffer))
(parent-buffer (frame-parameter frame 'posframe-parent-buffer)))
(when (and hidehandler
(funcall hidehandler
(list
:posframe-buffer buffer
:posframe-parent-buffer parent-buffer)))
(posframe--make-frame-invisible frame))))))
(add-hook 'post-command-hook #'posframe-run-hidehandler)
(defun posframe-hidehandler-when-buffer-switch (info)
"Posframe hidehandler function.
This function let posframe hide when user switch buffer.
Note: This function is called in `post-command-hook'."
(let ((parent-buffer (cdr (plist-get info :posframe-parent-buffer))))
(and (buffer-live-p parent-buffer)
(not (equal parent-buffer (current-buffer))))))
(defun posframe-delete (buffer-or-name)
"Delete posframe pertaining to BUFFER-OR-NAME and kill the buffer.
BUFFER-OR-NAME can be a buffer or a buffer name."
(posframe-delete-frame buffer-or-name)
(posframe--kill-buffer buffer-or-name))
(defun posframe-delete-frame (buffer-or-name)
"Delete posframe pertaining to BUFFER-OR-NAME.
BUFFER-OR-NAME can be a buffer or a buffer name."
(dolist (frame (frame-list))
(let ((buffer-info (frame-parameter frame 'posframe-buffer))
(buffer (get-buffer buffer-or-name)))
(when (or (equal buffer-or-name (car buffer-info))
(equal buffer-or-name (cdr buffer-info)))
(when buffer
(with-current-buffer buffer
(dolist (timer '(posframe--refresh-timer
posframe--timeout-timer))
(when (timerp timer)
(cancel-timer timer)))))
(delete-frame frame)))))
(defun posframe--kill-buffer (buffer-or-name)
"Kill posframe's buffer: BUFFER-OR-NAME.
BUFFER-OR-NAME can be a buffer or a buffer name."
(when (buffer-live-p (get-buffer buffer-or-name))
(kill-buffer buffer-or-name)))
(defun posframe-funcall (buffer-or-name function &rest arguments)
"Select posframe of BUFFER-OR-NAME and call FUNCTION with ARGUMENTS.
BUFFER-OR-NAME can be a buffer or a buffer name."
(when (functionp function)
(when (get-buffer buffer-or-name)
(with-current-buffer buffer-or-name
(when (framep posframe--frame)
(with-selected-frame posframe--frame
(apply function arguments)))))))
;;;###autoload
(defun posframe-hide-all ()
"Hide all posframe frames."
(interactive)
(dolist (frame (frame-list))
(when (frame-parameter frame 'posframe-buffer)
(posframe--make-frame-invisible frame))))
;;;###autoload
(defun posframe-delete-all ()
"Delete all posframe frames and buffers."
(interactive)
(dolist (frame (frame-list))
(when (frame-parameter frame 'posframe-buffer)
(delete-frame frame)))
(dolist (buffer (buffer-list))
(with-current-buffer buffer
(when posframe--frame
(posframe--kill-buffer buffer)))))
(defun posframe-auto-delete ()
"Auto delete posframe when its buffer is killed.
This function is used by `kill-buffer-hook'."
(posframe-delete-frame (current-buffer)))
;; Posframe's position handler
(defun posframe-run-poshandler (info)
"Run posframe's position handler.
the structure of INFO can be found in docstring
of `posframe-show'."
(if (equal info posframe--last-poshandler-info)
posframe--last-posframe-pixel-position
(setq posframe--last-poshandler-info info)
(funcall
(or (plist-get info :poshandler)
(let ((position (plist-get info :position)))
(cond ((integerp position)
#'posframe-poshandler-point-bottom-left-corner)
((and (consp position)
(integerp (car position))
(integerp (cdr position)))
#'posframe-poshandler-absolute-x-y)
(t (error "Posframe: have no valid poshandler")))))
info)))
(cl-defun posframe-poshandler-argbuilder (&optional
child-frame
&key
position
poshandler
x-pixel-offset
y-pixel-offset)
"Return a info list of CHILD-FRAME, which can be used as poshandler's info argument.