build.gradle

buildscript {
  ext.kotlin_version = '1.1.2-4'

  repositories {
    jcenter()
  }

  dependencies {
    classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
  }
}

plugins {
  id 'java-library'
  id 'maven-publish'
  id 'com.jfrog.bintray' version '1.7.2'
  id 'net.researchgate.release' version '2.4.1'
  id 'maven'
}
apply plugin: 'kotlin'

group 'net.dinomite'
version project.version

sourceCompatibility = JavaVersion.VERSION_1_8

repositories {
  jcenter()
}

dependencies {
  api "com.github.vladimir-bukhtoyarov:bucket4j-core:2.0.1"
  implementation "org.jetbrains.kotlin:kotlin-stdlib-jre8:$kotlin_version"
  implementation "com.google.guava:guava:21.0"

  compileOnly "io.dropwizard:dropwizard-core:1.0.5"
}

task sourceJar(type: Jar, dependsOn: classes) {
  from sourceSets.main.allSource
}

task javadocJar(type: Jar, dependsOn: javadoc) {
  from javadoc.destinationDir
}

publishing {
  publications {
    bintray(MavenPublication) {
      from components.java
      groupId project.group
      artifactId project.name
      version project.version

      artifact sourceJar {
        classifier 'sources'
      }

      artifact javadocJar {
        classifier 'javadoc'
      }
    }
  }
}

release {
  tagTemplate = 'v$version'
  afterReleaseBuild.dependsOn bintrayUpload
}

bintray {
  user = System.getenv('BINTRAY_USER')
  key = System.getenv('BINTRAY_KEY')
  publications = ['bintray']

  pkg {
    repo = 'maven'
    licenses = ['Apache-2.0']
    vcsUrl = 'https://github.com/dinomite/dropwizard-tokenbucket'
    name = 'net.dinomite.dropwizard-tokenbucket'

    version {
      name = project.version
      released = new Date()
      vcsTag = 'v' + project.version
    }
  }
}

sourceSets {
  main.java.srcDirs += 'src/main/kotlin'
}