build.gradle

plugins {
    id 'groovy'
    id 'java-gradle-plugin'
    id 'maven-publish'
    id 'com.gradle.plugin-publish' version '0.16.0'
}

pluginBundle {
    website = 'https://github.com/cdancy/gradle-artifactory-rest-plugin'
    vcsUrl = 'https://github.com/cdancy/gradle-artifactory-rest-plugin.git'
    tags = ['gradle', 'artifactory', 'rest', 'plugin', 'gradle-artifactory-rest-plugin', 'artifactory-rest']
}

gradlePlugin {
    plugins {
        main {
            id = 'com.github.gradle.artifactory.rest'
            displayName = 'Gradle Artifactory Rest Plugin'
            description = 'Gradle Plugin to work against Artifactorys REST Api'
            implementationClass = 'com.cdancy.gradle.artifactory.rest.ArtifactoryRestPlugin'
        }
    }
}

validateTaskProperties { failOnWarning = true }

repositories {
    gradlePluginPortal()
    mavenCentral()
}

dependencies {
    compile localGroovy()
    compile gradleApi()
    testCompile gradleTestKit()
    testCompile('org.spockframework:spock-core:1.0-groovy-2.4') {
        exclude module: 'groovy-all'
    }

    //Make sure this matches ArtifactoryRestPlugin.ARTIFACTORY_REST_DEFAULT_VERSION
    testCompile 'io.github.cdancy:artifactory-rest:1.1.1:all'
}

ext.compatibilityVersion = '1.8'
sourceCompatibility = compatibilityVersion
targetCompatibility = compatibilityVersion

tasks.withType(JavaCompile) {
    options.compilerArgs += ["-Xlint:-options"]
}

tasks.publishPlugins {
    onlyIf { !"$version".endsWith('SNAPSHOT') }
}

task release {
    outputs.upToDateWhen { false }
    dependsOn('publishPlugins')
}