build.gradle

apply plugin: 'java-library'
apply plugin: 'pmd'
apply plugin: 'checkstyle'
apply plugin: 'com.github.spotbugs'
apply plugin: 'eclipse'

buildscript {
  repositories {
    maven {
      url "https://plugins.gradle.org/m2/"
    }
  }
  dependencies {
    classpath "gradle.plugin.com.github.spotbugs:spotbugs-gradle-plugin:1.6.3"
  }
}

sourceCompatibility = "1.11"
targetCompatibility = "1.11"

configurations.all {
    // Check for updates every build
    resolutionStrategy.cacheChangingModulesFor 0, 'seconds'
}

allprojects { 
	repositories {
	    jcenter()
	    maven {
	    	url "https://oss.sonatype.org/content/repositories/snapshots/"
	    }
	}
}

dependencies {
    // These dependencies is exported to consumers, that is to say found on their compile classpath.
    api('org.industrial-devops:titan-ccp-common:0.0.1-SNAPSHOT') { changing = true }
    api 'net.kieker-monitoring:kieker:1.14-SNAPSHOT'
    api 'net.sourceforge.teetime:teetime:3.0'

    // These dependencies are used internally, and not exposed to consumers on their own compile classpath.
    implementation 'org.apache.kafka:kafka-clients:2.1.0'
    implementation 'com.google.guava:guava:24.1-jre'
    implementation 'org.jctools:jctools-core:2.1.1'

    // Use JUnit test framework
    testImplementation 'junit:junit:4.12'
}

pmd {
  ruleSets = [] // Gradle requires to clean the rule sets first
  ruleSetFiles = files("config/pmd.xml")
  ignoreFailures = false
  toolVersion = "6.7.0"
}

checkstyle {
  configDir = file("config")
  configFile = file("config/checkstyle.xml")
  maxWarnings = 0
  ignoreFailures = false
  toolVersion = "8.12"
}

spotbugs {
  excludeFilter = file("config/spotbugs-exclude-filter.xml")
  reportLevel = "low"
  effort = "max"
  ignoreFailures = false
  toolVersion = '3.1.7'
}

// Per default XML reports for SpotBugs are generated
// Include this to generate HTML reports
tasks.withType(com.github.spotbugs.SpotBugsTask) {
  reports {
    // Either HTML or XML reports can be activated
    html.enabled true
    xml.enabled false
  }
}

task checkstyle {
  group 'Quality Assurance'
  description 'Run Checkstyle'
  
  dependsOn 'checkstyleMain'
  dependsOn 'checkstyleTest'
}

task pmd {
  group 'Quality Assurance'
  description 'Run PMD'

  dependsOn 'pmdMain'
  dependsOn 'pmdTest'
}

task spotbugs {
  group 'Quality Assurance'
  description 'Run SpotBugs'
  
  dependsOn 'spotbugsMain'
  dependsOn 'spotbugsTest'
}

eclipse {
    classpath {
       downloadSources=true
       downloadJavadoc=true
    }
}