build.gradle

apply plugin: 'java'
apply plugin: 'maven'
apply plugin: 'checkstyle'
apply plugin: 'eclipse'
apply plugin: 'idea'

defaultTasks 'clean', 'build', 'install'

version = '0.0.1'

repositories {
    mavenCentral()
    maven {
        url "http://sevntu-checkstyle.github.com/sevntu.checkstyle/maven2"
    }
}

[compileJava, compileTestJava]*.options*.encoding = 'UTF-8'


compileJava {
    // Suppress warnings about using Unsafe and sun.misc
    options.compilerArgs << '-XDignore.symbol.file'
    options.fork = true
    options.forkOptions.executable = 'javac'

    sourceCompatibility = 1.8
    targetCompatibility = 1.8
}

dependencies {
    checkstyle "com.github.sevntu.checkstyle:sevntu-checks:1.17.1"

    compile(
        'org.hdrhistogram:HdrHistogram:2.1.8',
        'uk.co.real-logic:Agrona:0.5',
        'uk.co.real-logic:aeron-client:0.9.6',
        'uk.co.real-logic:aeron-driver:0.9.6',
        'com.lmax:disruptor:3.3.4',
        'com.vlkan:flatbuffers:1.2.0-3f79e055')

    testCompile(
        'org.hamcrest:hamcrest-all:1.3',
        'junit:junit:4.12',
        'org.mockito:mockito-all:1.10.19')
}

checkstyle {
    configFile = new File(rootDir, 'config/checkstyle/checkstyle.xml')
    toolVersion = "6.14.1"
}

javadoc {
    title = '<h1>Tests</h1>'

    options.bottom = '<i>Copyright &#169; 2016. All Rights Reserved.</i>'
    options.addStringOption('XDignore.symbol.file', '-quiet')
}

task sourcesJar(type: Jar) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}

artifacts {
    archives sourcesJar
    archives javadocJar
}

task wrapper(type: Wrapper) {
    gradleVersion = '2.10'
}