build.gradle

plugins {
    id 'com.android.library'
    id 'org.jetbrains.kotlin.android'
    id 'com.google.devtools.ksp'
}

android {
    signingConfigs {
        release {
            try {
                storeFile file(KEYSTORE_FILEPATH)
                storePassword KEYSTORE_PASSWORD
                keyAlias KEYSTORE_ALIAS
                keyPassword KEY_PASSWORD
            } catch (ignored) {
                throw new InvalidUserDataException("You should define KEYSTORE_ALIAS, KEYSTORE_FILEPATH, KEYSTORE_PASSWORD and KEY_PASSWORD in gradle.properties.")
            }
        }
    }
    namespace 'com.brave.playlist'
    compileSdk 35

    buildFeatures {
        buildConfig = true
    }

    defaultConfig {
        minSdk 24
        targetSdk 35
        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
        consumerProguardFiles "consumer-rules.pro"
        vectorDrawables.useSupportLibrary = true
        ksp {
            arg("room.schemaLocation", "$projectDir/schemas")
        }
    }

    libraryVariants.configureEach { variant ->
        variant.outputs.configureEach { output ->
            outputFileName = "playlist_${variant.name}_${defaultConfig.versionName}.aar"
        }
    }

    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
            signingConfig signingConfigs.release
        }
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_17
        targetCompatibility JavaVersion.VERSION_17
    }
    kotlinOptions {
        jvmTarget = '17'
    }
}

ext {
    exoplayerVersion = '1.0.2' // using 1.0.2 version to align with chromium dependency
    room_version = "2.6.1"
}

dependencies {
    implementation 'androidx.core:core-ktx:1.13.1'
    implementation 'androidx.appcompat:appcompat:1.7.0'
    implementation 'com.google.android.material:material:1.12.0'
    implementation 'androidx.constraintlayout:constraintlayout:2.1.4'

    //noinspection GradleDependency
    implementation "androidx.media3:media3-exoplayer:$exoplayerVersion"
    //noinspection GradleDependency
    implementation "androidx.media3:media3-ui:$exoplayerVersion"
    //noinspection GradleDependency
    implementation "androidx.media3:media3-cast:$exoplayerVersion"
    //noinspection GradleDependency
    implementation "androidx.media3:media3-session:$exoplayerVersion"
    //noinspection GradleDependency
    implementation "androidx.media3:media3-exoplayer-hls:$exoplayerVersion"

    implementation "com.google.android.gms:play-services-cast-framework:21.5.0"

    implementation "androidx.preference:preference-ktx:1.2.1"

    implementation "com.google.code.gson:gson:2.10.1"

    implementation "androidx.room:room-runtime:$room_version"
    annotationProcessor "androidx.room:room-compiler:$room_version"
    //noinspection KaptUsageInsteadOfKsp
//    kapt "androidx.room:room-compiler:$room_version"
    ksp "androidx.room:room-compiler:$room_version"

    implementation 'androidx.lifecycle:lifecycle-viewmodel-ktx:2.8.6'

    implementation 'org.jetbrains.kotlinx:kotlinx-coroutines-android:1.7.3'

    implementation "com.github.bumptech.glide:glide:4.12.0"
    testImplementation 'junit:junit:4.13.2'
    androidTestImplementation 'androidx.test.ext:junit:1.2.1'
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(17)
    }
}