build.gradle

plugins {
	id 'java'
	id 'org.springframework.boot' version '3.2.5'
	id 'io.spring.dependency-management' version '1.1.4'
}

group = 'com.example'
version = '0.0.1-SNAPSHOT'

java {
    sourceCompatibility = JavaVersion.VERSION_20
    targetCompatibility = JavaVersion.VERSION_20
}

repositories {
	mavenCentral()
}

dependencies {
	implementation 'org.springframework.boot:spring-boot-starter'
	implementation 'org.projectlombok:lombok:1.18.32'
	compileOnly 'org.projectlombok:lombok:1.18.32'
	annotationProcessor 'org.projectlombok:lombok:1.18.32'
	implementation 'com.github.pengrad:java-telegram-bot-api:7.2.1'
	implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
	runtimeOnly 'org.postgresql:postgresql'
	implementation 'org.apache.commons:commons-csv:1.11.0'
	testImplementation 'org.springframework.boot:spring-boot-starter-test'
}

tasks.named('test') {
	useJUnitPlatform()
}

bootJar {
	archiveFileName = "cardioBot.jar"
}

tasks.register("stopDockerImage", Exec) {
	group "docker"
	commandLine "docker", "compose", "down"
}

tasks.register("bootJarWithStop") {
	group "build"
	dependsOn bootJar
	dependsOn stopDockerImage
}

tasks.register("buildDeployDockerImage", Exec) {
	group "docker"
	dependsOn bootJar
	commandLine "docker", "build", "--platform", "linux/amd64", "-t", "almaxgood/cardio-bot", "."
}

tasks.register("buildDockerImage", Exec) {
	group "docker"
	dependsOn bootJar
	commandLine "docker", "build", "-t", "cardio-bot", "."
}

tasks.register("rebuildDockerImage", Exec) {
	group "docker"
	dependsOn bootJarWithStop
	commandLine "docker", "build", "-t", "cardio-bot", "."
}

tasks.register("startDockerImage", Exec) {
	group "docker"
	dependsOn buildDockerImage
	commandLine "docker", "compose", "up", "-d"
}

tasks.register("restartDockerImage", Exec) {
	group "docker"
	dependsOn rebuildDockerImage
	commandLine "docker", "compose", "up", "-d"
}