main.mfk

import nes_lib
import custom_random
import graphics
import graphics_buffer
import input

import sound/sound

import ui/screen
import ui/aquarium
import ui/commandbar
import ui/planteditor
import tank/tank

import fish/fish

byte in_nmi = 0
byte nmi_fail = 0
byte frame

volatile bool new_frame = false

void main() {
  init_graphics()

  init_rw_memory()

  init_random()
  init_tank()
  init_fish()

  init_plants()

  #if(music)
  famistudio_init(0, $D000)
  famistudio_sfx_init($E000)
  #endif

  init_title()
  draw_screen()

  process_buffered_writes()

  enable_graphics()

  while(true) {
    // Wait for NMI to complete rendering frame
    while (new_frame && not(buffer_screen_draw)) {}

    if (buffer_screen_draw) {
      screen_draw_tick()
    } else {
      sprite_tick()
      input_and_screen_tick()
      clear_remaining_oam()
    }
    // wait_for_sprite0_clear()

    new_frame = true
    frame += 1
  }
}

void nmi() {
  if in_nmi != 0 {
    // Overran NMI
    nmi_fail = 1
    asm {
      kil
    }
  }

  in_nmi = 1

  nmi_work()

  in_nmi = 0
}

inline void nmi_work() {
  if (buffer_screen_blank) {
    load_transition_palette()

    screen_transfer_tick()
    nmi_always_run()
    new_frame = false
    return
  }

  if (not(drawing_enabled)) {
    nmi_always_run()
    return
  }

  if (new_frame) {
    nmi_frame()

    new_frame = false
  }

  nmi_always_run()
}

void nmi_frame() {
  // set_color_effect(clear)
  sprite_render()

  process_buffered_writes()

  read_ppu_status()
  ppu_ctrl = standard_ppu_ctrl
  read_ppu_status()
  ppu_set_scroll(0, 0)

  // wait_for_sprite0_nmi()

  // set_color_effect(blue)
}

void nmi_always_run() {
  #if(music)
  famistudio_update()
  #endif
}

void irq() {

}