build.gradle

buildscript {
	dependencies {
		classpath "org.kohsuke:github-api:1.326"
	}
}

plugins {
	id "fabric-loom" version "1.8-SNAPSHOT"
	id "me.modmuss50.mod-publish-plugin" version "0.8.1"
	id "com.diffplug.spotless" version "6.25.0"
}

def ENV = System.getenv()

version = project.mod_version
group = project.maven_group

base {
	archivesName = project.archives_base_name
}

repositories {
	// Add repositories to retrieve artifacts from in here.
	// You should only use this when depending on other mods because
	// Loom adds the essential maven repositories to download Minecraft and libraries from automatically.
	// See https://docs.gradle.org/current/userguide/declaring_repositories.html
	// for more information about repositories.
	maven {url "https://maven.shedaniel.me/"}
	maven {url "https://maven.terraformersmc.com/releases/"}
}

// Override vulnerable dependencies until Minecraft updates to newer versions
configurations.all {
	resolutionStrategy {
		// v1.15.0, used by Minecraft 1.21.2 and 1.21.3, is vulnerable to CVE-2024-35255
		force "com.microsoft.azure:msal4j:1.17.2"
		// v4.1.97.Final, used by Minecraft 1.21 - 1.21.3, is vulnerable to CVE-2024-47535
		force "io.netty:netty-common:4.1.115.Final"
	}
}

dependencies {
	// To change the versions see the gradle.properties file
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
	modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"
	
	// Fabric API. This is technically optional, but you probably want it anyway.
	modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"
	
	// Mod Menu
	modApi "com.terraformersmc:modmenu:${project.modmenu_version}"
	include "com.terraformersmc:modmenu:${project.modmenu_version}"
	
	// Cloth Config
	modApi("me.shedaniel.cloth:cloth-config-fabric:${project.cloth_config_version}") {
		exclude(group: "net.fabricmc.fabric-api")
	}
	include("me.shedaniel.cloth:cloth-config-fabric:${project.cloth_config_version}") {
		exclude(group: "net.fabricmc.fabric-api")
	}
	
	constraints {
		modApi("org.yaml:snakeyaml:2.2") {
			because "version 1.27 pulled from cloth-config has security vulnerabilities"
		}
		modApi("com.google.code.gson:gson:2.10.1") {
			because "version 2.8.1 pulled from cloth-config has security vulnerabilities"
		}
	}
}

loom {
	accessWidenerPath = file("src/main/resources/chestesp.accesswidener")
}

configurations {
	productionRuntime {
		extendsFrom configurations.minecraftLibraries
		extendsFrom configurations.loaderLibraries
		extendsFrom configurations.minecraftRuntimeLibraries
	}
}

dependencies {
	productionRuntime "net.fabricmc:fabric-loader:${project.loader_version}"
	productionRuntime "net.fabricmc:intermediary:${project.minecraft_version}"
}

import net.fabricmc.loom.util.Platform
tasks.register('runEndToEndTest', JavaExec) {
	dependsOn remapJar, downloadAssets
	classpath.from configurations.productionRuntime
	mainClass = "net.fabricmc.loader.impl.launch.knot.KnotClient"
	workingDir = file("run")
	
	doFirst {
		classpath.from loom.minecraftProvider.minecraftClientJar
		workingDir.mkdirs()
		
		args(
			"--assetIndex", loom.minecraftProvider.versionInfo.assetIndex().fabricId(loom.minecraftProvider.minecraftVersion()),
			"--assetsDir", new File(loom.files.userCache, "assets").absolutePath,
			"--gameDir", workingDir.absolutePath
		)
		
		if (Platform.CURRENT.operatingSystem.isMacOS()) {
			jvmArgs("-XstartOnFirstThread")
		}
		
		jvmArgs(
			"-Dfabric.addMods=${configurations.modImplementation.find { it.name.contains('fabric-api') }.absolutePath}${File.pathSeparator}${remapJar.archiveFile.get().asFile.absolutePath}",
			"-Dchestesp.e2eTest",
			"-Dfabric-tag-conventions-v2.missingTagTranslationWarning=fail",
			"-Dfabric-tag-conventions-v1.legacyTagWarning=fail",
			"-Dmixin.debug.verify=true",
			"-Dmixin.debug.countInjections=true"
		)
	}
}

processResources {
	inputs.property "version", project.version
	
	filesMatching("fabric.mod.json") {
		expand "version": project.version
	}
}

tasks.withType(JavaCompile).configureEach {
	// Minecraft 1.20.5 (24w14a) upwards uses Java 21.
	it.options.release = 21
}

java {
	// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
	// if it is present.
	// If you remove this line, sources will not be generated.
	withSourcesJar()
	
	sourceCompatibility = JavaVersion.VERSION_21
	targetCompatibility = JavaVersion.VERSION_21
}

jar {
	from("LICENSE") {
		rename {"${it}_${base.archivesName.get()}"}
	}
}

spotless {
	lineEndings("WINDOWS")
	java {
		removeUnusedImports()
		indentWithTabs()
		trimTrailingWhitespace()
		eclipse().configFile(file("codestyle/formatter.xml"))
	}
	json {
		target "src/**/*.json"
		gson().indentWithSpaces(2).version("2.10.1")
	}
}

def getGhVersion() {
	return "v" + version.substring(0, version.indexOf("-MC"))
}

def getChangelogUrl() {
	def modSlug = archives_base_name.toLowerCase()
	def versionSlug = version.substring(0, version.indexOf("-MC")).replace(".", "-")
	return "https://www.wimods.net/${modSlug}/${modSlug}-${versionSlug}/"
}

publishMods {
	file = remapJar.archiveFile
	def archivesName = base.archivesName.get() as String
	additionalFiles.from(
		file("${project.buildDir}/libs/${archivesName}-${project.version}-sources.jar"),
	)
	type = getGhVersion().contains("pre") ? BETA : STABLE
	modLoaders.add("fabric")
	def changelogUrl = getChangelogUrl()
	
	curseforge {
		projectId = "870203"
		accessToken = providers.environmentVariable("CURSEFORGE_API_KEY")
		minecraftVersions.add("${project.cf_game_version}")
		requires("fabric-api")
		embeds("modmenu", "cloth-config")
		changelog = "A changelog can be found at: [${changelogUrl}](${changelogUrl}?mc=${project.minecraft_version}&utm_source=CurseForge&utm_medium=ChestESP&utm_campaign=Changelog&utm_content=CurseForge+ChestESP+MC${project.minecraft_version})"
	}
}

afterEvaluate {
	tasks.publishMods.dependsOn build
	tasks.publishCurseforge.dependsOn build
}

import org.kohsuke.github.GHReleaseBuilder
import org.kohsuke.github.GitHub

task github(dependsOn: build) {
	onlyIf {
		ENV.GITHUB_TOKEN
	}
	
	doLast {
		def github = GitHub.connectUsingOAuth(ENV.GITHUB_TOKEN as String)
		def repository = github.getRepository("Wurst-Imperium-MCX/ChestESP")
		def ghVersion = getGhVersion()
		
		def ghRelease = repository.getReleaseByTagName(ghVersion as String)
		if(ghRelease == null) {
			def releaseBuilder = new GHReleaseBuilder(repository, ghVersion as String)
			ghRelease = releaseBuilder.create()
		}
		
		ghRelease.uploadAsset(remapJar.archiveFile.get().getAsFile(), "application/java-archive");
		ghRelease.uploadAsset(remapSourcesJar.archiveFile.get().getAsFile(), "application/java-archive")
	}
}

import java.time.LocalDate
import org.kohsuke.github.GHIssueState
import org.kohsuke.github.GHMilestoneState
import java.time.ZoneId

task closeMilestone {
	onlyIf {
		ENV.GITHUB_TOKEN
	}
	
	doLast {
		def github = GitHub.connectUsingOAuth(ENV.GITHUB_TOKEN as String)
		def repository = github.getRepository("Wurst-Imperium/ChestESP")
		def ghVersion = getGhVersion()
		
		// Weird API design: listMilestones() requires GHIssueState while everything else uses GHMilestoneState.
		def milestone = repository.listMilestones(GHIssueState.ALL).find { it.title == ghVersion }
		if (milestone == null) {
			milestone = repository.createMilestone(ghVersion, "")
		}
		
		if (milestone.getState() != GHMilestoneState.CLOSED) {
			milestone.setDueOn(Date.from(LocalDate.now().atStartOfDay(ZoneId.systemDefault()).toInstant()))
			milestone.setDescription(getChangelogUrl())
			milestone.close()
		}
	}
}

task uploadBackups {
	dependsOn build
	
	onlyIf {
		ENV.WI_BACKUPS_API_KEY
	}
	
	doLast {
		def shortVersion = getGhVersion().substring(1)
		def backupUrl = "https://api.wurstclient.net/artifact-backups/ChestESP/${shortVersion}"
		
		def connection = new URL(backupUrl).openConnection() as HttpURLConnection
		def boundary = UUID.randomUUID().toString()
		connection.setRequestMethod("POST")
		connection.setRequestProperty("X-API-Key", ENV.WI_BACKUPS_API_KEY)
		connection.setRequestProperty("Accept", "application/json")
		connection.setRequestProperty("Content-Type", "multipart/form-data; boundary=$boundary")
		connection.doOutput = true
		
		def output = connection.outputStream
		[remapJar, remapSourcesJar].each { jarTask ->
			def file = jarTask.archiveFile.get().asFile
			output << "--${boundary}\r\n"
			output << "Content-Disposition: form-data; name=\"files\"; filename=\"${file.name}\"\r\n"
			output << "Content-Type: application/java-archive\r\n\r\n"
			file.withInputStream { input -> 
				output << input
			}
			output << "\r\n"
		}
		output << "--${boundary}--\r\n"
		output.flush()
		
		if(connection.responseCode != 200)
			throw new GradleException("Failed to upload backups: ${connection.responseCode} ${connection.responseMessage}")
	}
}