build.gradle

plugins {
    id "com.dorongold.task-tree" version "1.3"
//    id "org.sonarqube" version "2.3" apply false
//    id "com.jfrog.bintray" version "1.7" apply false
}

apply from: "${rootDir}/gradle/util.gradle"
apply from: "${rootDir}/gradle/dependencies.gradle"
apply from: "${rootDir}/gradle/java.gradle"
apply from: "${rootDir}/gradle/spock.gradle"
apply from: "${rootDir}/gradle/ide.gradle"

allprojects {
    repositories {
        jcenter()
    }
    group = 'io.github.venis.hl7'

    configurations.all {
        resolutionStrategy {
            failOnVersionConflict()
            libs.each { k, v -> force(v) }
            cacheDynamicVersionsFor 10*60, 'seconds'
            cacheChangingModulesFor 0, 'seconds'
        }
    }
}

subprojects {
    dependencies {
        compile libs.slf4jApi
        testCompile libs.slf4jSimple
    }

    // Common hapi testing
    test {
        def hapiDir = file("${project.buildDir}/tmp/hapi")
        doFirst {
            hapiDir.mkdirs()
        }
        systemProperty "hapi.home", "${hapiDir.absolutePath}"
    }

    task allDeps(type: DependencyReportTask) {}
}

apply from: "${rootDir}/gradle/pmd.gradle"
apply from: "${rootDir}/gradle/findbugs.gradle"
apply from: "${rootDir}/gradle/jdepend.gradle"
apply from: "${rootDir}/gradle/dependency.gradle"
apply from: "${rootDir}/gradle/cpd.gradle"
apply from: "${rootDir}/gradle/jacoco.gradle"
apply from: "${rootDir}/gradle/owasp.gradle"
apply from: "${rootDir}/gradle/bintray.gradle"
apply from: "${rootDir}/gradle/changelog.gradle"
apply from: "${rootDir}/gradle/release.gradle"
apply from: "${rootDir}/gradle/taskorder.gradle"
task wrapper(type: Wrapper) {
    gradleVersion = '3.5'
}