build.gradle

plugins {
    id "cpp"
    id "google-test-test-suite"
    id "edu.wpi.first.GradleRIO" version "2022.4.1"
}

// Define my targets (RoboRIO) and artifacts (deployable files)
// This is added by GradleRIO's backing project DeployUtils.
deploy {
    targets {
        roborio(getTargetTypeClass('RoboRIO')) {
            // Team number is loaded either from the .wpilib/wpilib_preferences.json
            // or from command line. If not found an exception will be thrown.
            // You can use getTeamOrDefault(team) instead of getTeamNumber if you
            // want to store a team number in this file.
            team = project.frc.getTeamNumber()
            debug = project.frc.getDebugOrDefault(false)

            artifacts {
                // First part is artifact name, 2nd is artifact type
                // getTargetTypeClass is a shortcut to get the class type using a string

                frcCpp(getArtifactTypeClass('FRCNativeArtifact')) {
                }

                // Static files artifact
                frcStaticFileDeploy(getArtifactTypeClass('FileTreeArtifact')) {
                    files = project.fileTree('src/main/deploy')
                    directory = '/home/lvuser/deploy'
                }
            }
        }
    }
}

def deployArtifact = deploy.targets.roborio.artifacts.frcCpp

// Set this to true to enable desktop support.
def includeDesktopSupport = false

// Set to true to run simulation in debug mode
wpi.cpp.debugSimulation = false

// Default enable simgui
wpi.sim.addGui().defaultEnabled = false
// Enable DS but not by default
wpi.sim.addDriverstation()

model {
    components {
        spdlog(NativeLibrarySpec) {
            targetPlatform wpi.platforms.roborio
            if (includeDesktopSupport) {
                targetPlatform wpi.platforms.desktop
            }

            sources.cpp {
                source {
                    srcDir './third_party/spdlog-1.9.2/src'
                    include '**/*.cpp'
                }
                exportedHeaders {
                    srcDir './third_party/spdlog-1.9.2/include'
                }
            }
            
            binaries.all {
                if (targetPlatform.operatingSystem.isWindows()) {
                    cppCompiler.args << '/std:c++17'
                } else {
                    cppCompiler.args << '-std=c++17'
                }
                cppCompiler.define 'SPDLOG_COMPILED_LIB'
                cppCompiler.define 'SPDLOG_FMT_EXTERNAL'
            }

            binaries.withType(SharedLibraryBinarySpec) {
                buildable = false
            }

            wpi.cpp.deps.wpilib(it)
        }
        
        robolyon(NativeLibrarySpec) {
            targetPlatform wpi.platforms.roborio
            if (includeDesktopSupport) {
                targetPlatform wpi.platforms.desktop
            }

            sources.cpp {
                source {
                    srcDir './third_party/robolyon_lib/src'
                    include '**/*.cpp'
                }
                exportedHeaders {
                    srcDir './third_party/robolyon_lib/include'
                }
            }

            binaries.all {
                if (targetPlatform.operatingSystem.isWindows()) {
                    cppCompiler.args << '/std:c++17'
                } else {
                    cppCompiler.args << '-std=c++17'
                }
            }

            binaries.withType(SharedLibraryBinarySpec) {
                buildable = false
            }

            wpi.cpp.deps.wpilib(it)
        }


        frcUserProgram(NativeExecutableSpec) {
            targetPlatform wpi.platforms.roborio
            if (includeDesktopSupport) {
                targetPlatform wpi.platforms.desktop
            }

            sources.cpp {
                source {
                    srcDir 'src/main/cpp'
                    include '**/*.cpp', '**/*.cc'
                }
                exportedHeaders {
                    srcDir 'src/main/include'
                }
        	    lib library: 'spdlog', linkage: 'static'
                lib library: 'robolyon', linkage: 'static'
            }

            binaries.all {
                cppCompiler.define 'SPDLOG_COMPILED_LIB'
                cppCompiler.define 'SPDLOG_FMT_EXTERNAL'
            }

            // Set deploy task to deploy this component
            deployArtifact.component = it

            // Enable run tasks for this component
            wpi.cpp.enableExternalTasks(it)

            // Enable simulation for this component
            wpi.sim.enable(it)
            // Defining my dependencies. In this case, WPILib (+ friends), and vendor libraries.
            wpi.cpp.vendor.cpp(it)
            wpi.cpp.deps.wpilib(it)
        }
    }
    testSuites {
        frcUserProgramTest(GoogleTestTestSuiteSpec) {
            testing $.components.frcUserProgram

            sources.cpp {
                source {
                    srcDir 'src/test/cpp'
                    include '**/*.cpp'
                }
            }

            sources.cpp {
                source {
                    srcDir './third_party/robolyon_lib/src'
                    include '**/*.cpp'
                }
                exportedHeaders {
                    srcDir './third_party/robolyon_lib/include'
                }
            }
            sources.cpp {
                source {
                    srcDir './third_party/spdlog-1.9.2/src'
                    include '**/*.cpp'
                }
                exportedHeaders {
                    srcDir './third_party/spdlog-1.9.2/include'
                }
            }

            // Enable run tasks for this component
            wpi.cpp.enableExternalTasks(it)

            wpi.cpp.vendor.cpp(it)
            wpi.cpp.deps.wpilib(it)
            wpi.cpp.deps.googleTest(it)

            binaries.all {
                cppCompiler.define 'SPDLOG_COMPILED_LIB'
                cppCompiler.define 'SPDLOG_FMT_EXTERNAL'

            }
        }
    }
}