build.gradle

plugins {
    id 'java'
    id 'application'
    id 'io.spring.dependency-management' version '1.0.9.RELEASE'
}

group 'easymark'
version '1.0-SNAPSHOT'

application.mainClassName = 'easymark.Main'

dependencyManagement {
    imports {
        mavenBom 'org.springframework.security:spring-security-bom:5.3.3.RELEASE'
    }
}

repositories {
    mavenCentral()
}

dependencies {
    implementation 'com.google.code.gson:gson:2.8.6'
    implementation 'io.javalin:javalin:3.9.1'
    implementation 'org.slf4j:slf4j-simple:1.7.30'  // Logger for Javalin
    implementation 'io.pebbletemplates:pebble:3.1.2'
    implementation "org.springframework.security:spring-security-web"
    testCompile group: 'junit', name: 'junit', version: '4.12'
}

task buildDotFiles {
    doFirst {
        new File(rootDir, 'doc')
                .listFiles()
                .findAll { file -> file.getName().endsWith(".dot") }
                .each { file ->
                    def path = file.getAbsolutePath()
                    def cmd = "dot -Tsvg ${path} -o ${path.substring(0, path.length() - 3)}svg"
                    println cmd
                    def proc = cmd.execute()
                    proc.consumeProcessOutput(System.out, System.err)
                    proc.waitFor()
                }
    }
}