build.gradle

apply plugin: 'com.github.ben-manes.versions'
apply plugin: 'com.vanniktech.code.quality.tools'
apply plugin: 'com.vanniktech.android.junit.jacoco'

buildscript {
  ext.kotlinVersion = '1.2.41'
  ext.versions = [
    espresso: '3.0.1',
    testRules: '1.0.1',
  ]

  ext.deps = [
    'support': [
      'test': [
        'espresso': [
          'core': "com.android.support.test.espresso:espresso-core:${versions.espresso}",
        ],
        'runner': "com.android.support.test:runner:${versions.testRules}",
        'rules': "com.android.support.test:rules:${versions.testRules}",
      ],
    ],
    'fastLaneScreenGrab': "tools.fastlane:screengrab:1.1.0",
  ]

  repositories {
    mavenCentral()
    google()
    gradlePluginPortal()
  }
  dependencies {
    classpath 'com.vanniktech:gradle-code-quality-tools-plugin:0.10.0'
    classpath 'com.vanniktech:gradle-android-junit-jacoco-plugin:0.11.0'
    classpath 'com.vanniktech:gradle-maven-publish-plugin:0.4.0'

    classpath 'com.android.tools.build:gradle:3.0.1'
    classpath 'com.github.ben-manes:gradle-versions-plugin:0.17.0'
    classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion"
  }
}

codeQualityTools {
  lint {
    textReport = true
  }
  checkstyle {
    toolVersion = '8.7'
  }
  pmd {
    toolVersion = '6.0.1'
  }
  ktlint {
    toolVersion = '0.24.0'
  }
  detekt {
    toolVersion = '1.0.0.RC7'
  }
  errorProne {
    toolVersion = '2.1.2'
  }
}

junitJacoco {
  // Don't care about sample and generated modules
  ignoreProjects = ['app', 'emoji-ios', 'emoji-google', 'emoji-twitter', 'emoji-one', 'emoji-compat', 'emoji-kotlin']
}

subprojects {
  repositories {
    google()
    jcenter()
    mavenCentral()
  }
}

ext {
  minSdkVersion = 15
  compileSdkVersion = 27
  targetSdkVersion = 27

  supportLibraryVersion = '27.0.2'
  leakCanaryVersion = '1.5.1'

  versionCode = VERSION_CODE
  versionName = VERSION_NAME

  supportAppCompat = "com.android.support:appcompat-v7:$supportLibraryVersion"
  supportV4CoreUi = "com.android.support:support-core-ui:$supportLibraryVersion"
  supportV4Compat = "com.android.support:support-compat:$supportLibraryVersion"
  supportRecyclerView = "com.android.support:recyclerview-v7:$supportLibraryVersion"
  supportCardView = "com.android.support:cardview-v7:$supportLibraryVersion"
  supportAnnotations = "com.android.support:support-annotations:$supportLibraryVersion"
  supportEmoji = "com.android.support:support-emoji:$supportLibraryVersion"
  supportEmojiBundled = "com.android.support:support-emoji-bundled:$supportLibraryVersion"

  leakCanaryDebug = "com.squareup.leakcanary:leakcanary-android:$leakCanaryVersion"
  leakCanaryRelease = "com.squareup.leakcanary:leakcanary-android-no-op:$leakCanaryVersion"

  testing = [
          junit             : 'junit:junit:4.12',
          robolectric       : 'org.robolectric:robolectric:3.5.1',
          privateConstructor: 'com.pushtorefresh.java-private-constructor-checker:checker:1.2.0',
          assertJ           : 'org.assertj:assertj-core:3.8.0'
  ]

  javaVersion = JavaVersion.VERSION_1_7
}

task wrapper(type: Wrapper) {
  gradleVersion = '4.8'
  distributionType = Wrapper.DistributionType.ALL
}

subprojects {
  task allDependencies(type: DependencyReportTask) {}
}