build.gradle

plugins {
    id 'java'
    id 'maven-publish'
}

group = 'net.phoenix'
version = '1.0.3'

repositories {
    mavenCentral()
}

dependencies {
    implementation 'org.jetbrains:annotations:24.0.0'
    testImplementation platform('org.junit:junit-bom:5.9.1')
    testImplementation 'org.junit.jupiter:junit-jupiter'
    implementation files("${System.properties['java.home']}/lib/tools.jar")
    implementation 'com.google.auto.service:auto-service:1.1.1'
    annotationProcessor('com.google.auto.service:auto-service:1.1.1')
}

test {
    useJUnitPlatform()
}

compileJava {
    options.fork = true
    options.forkOptions.with {
        jvmArgs = [
                '--add-exports=jdk.compiler/com.sun.tools.javac.code=ALL-UNNAMED',
                '--add-exports=jdk.compiler/com.sun.tools.javac.comp=ALL-UNNAMED',
                '--add-exports=jdk.compiler/com.sun.tools.javac.file=ALL-UNNAMED',
                '--add-exports=jdk.compiler/com.sun.tools.javac.main=ALL-UNNAMED',
                '--add-exports=jdk.compiler/com.sun.tools.javac.model=ALL-UNNAMED',
                '--add-exports=jdk.compiler/com.sun.tools.javac.parser=ALL-UNNAMED',
                '--add-exports=jdk.compiler/com.sun.tools.javac.processing=ALL-UNNAMED',
                '--add-exports=jdk.compiler/com.sun.tools.javac.tree=ALL-UNNAMED',
                '--add-exports=jdk.compiler/com.sun.tools.javac.util=ALL-UNNAMED'
        ]
    }
    options.compilerArgs += [
            '--add-exports', 'jdk.compiler/com.sun.tools.javac.code=ALL-UNNAMED',
            '--add-exports', 'jdk.compiler/com.sun.tools.javac.comp=ALL-UNNAMED',
            '--add-exports', 'jdk.compiler/com.sun.tools.javac.file=ALL-UNNAMED',
            '--add-exports', 'jdk.compiler/com.sun.tools.javac.main=ALL-UNNAMED',
            '--add-exports', 'jdk.compiler/com.sun.tools.javac.model=ALL-UNNAMED',
            '--add-exports', 'jdk.compiler/com.sun.tools.javac.parser=ALL-UNNAMED',
            '--add-exports', 'jdk.compiler/com.sun.tools.javac.processing=ALL-UNNAMED',
            '--add-exports', 'jdk.compiler/com.sun.tools.javac.tree=ALL-UNNAMED',
            '--add-exports', 'jdk.compiler/com.sun.tools.javac.util=ALL-UNNAMED'
    ]
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java
            version = '1.0.' + project.properties['VERSION_CODE']
        }
    }
    repositories {
        mavenLocal()
    }
}

tasks.register('incrementVersion') {
    doLast {
        def propsFile = file('gradle.properties')
        def props = new Properties()
        propsFile.withInputStream { props.load(it) }

        def versionCode = props['VERSION_CODE'].toInteger()
        versionCode++

        props['VERSION_CODE'] = versionCode.toString()
        propsFile.withWriter { props.store(it, null) }
    }
}

tasks.getByName('publish').dependsOn('incrementVersion')