build.gradle

plugins {
    id 'fabric-loom' version '1.0-SNAPSHOT'
    id 'maven-publish'
}

archivesBaseName = "${project.modName}-${project.minecraftVersion}"

java {
    toolchain { languageVersion = JavaLanguageVersion.of(17) }
    withSourcesJar()
}

repositories {
    maven {
        name = "dv8tion"
        url = "https://m2.dv8tion.net/releases/"
        content { includeGroup "net.dv8tion" }
    }
}

dependencies {
    minecraft "com.mojang:minecraft:${project.minecraftVersion}"
    mappings "net.fabricmc:yarn:${project.yarnVersion}:v2"
    modImplementation "net.fabricmc:fabric-loader:${project.fabricLoaderVersion}"

    modImplementation(fabricApi.module("fabric-api-base", project.fabricApiVersion))
    modImplementation(fabricApi.module("fabric-command-api-v2", project.fabricApiVersion))
    modImplementation(fabricApi.module("fabric-lifecycle-events-v1", project.fabricApiVersion))

    // https://github.com/DV8FromTheWorld/JDA
    include implementation("net.dv8tion:JDA:5.0.0-alpha.18") {
        exclude module: 'opus-java'
    }
    // Include JDA's dependencies in the jar
    include("net.sf.trove4j:trove4j:3.0.3")
    include("org.apache.commons:commons-collections4:4.4")
    include("com.fasterxml.jackson.core:jackson-core:2.13.2")
    include("com.fasterxml.jackson.core:jackson-databind:2.13.2")
    include("com.fasterxml.jackson.core:jackson-annotations:2.13.2")
    include("com.squareup.okhttp3:okhttp:4.9.3")
    include("com.squareup.okio:okio-jvm:3.2.0") //okio-jvm, not okio. This cost me like 1hr of debugging
    include("com.neovisionaries:nv-websocket-client:2.14")
    modLocalRuntime("net.fabricmc:fabric-language-kotlin:1.7.3+kotlin.1.6.20") { // includes kotlin for squareup libs
        exclude module: "fabric-loader"
    }
}

processResources {
    inputs.property "version", project.version
    filesMatching("fabric.mod.json") {
        expand "version": project.version
    }
}

// configure the maven publication
publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java
        }
    }

    repositories {
        //maven repos go here
    }
}