room50.asc

// Tankstelle (außen) (Police Molest)

/****************************
*   Raum-Funktionen
****************************/
function room_Load()
{
  aMusic8.Play();
	String seperator = String.Format("\\ **** Tankstelle (außen)");
	Door[eDoorNumTankstellentuer].Init(oTuer, hTuer);
	gScore.Visible = false;
	gBorder.Visible = false;
	PlayAmbientSound(1, 108, 100, 0, 0);
	
	if ( player.PreviousRoom != 51 )
	{
		player.x = 68;
		player.y = 61;
		player.FaceDirection(eDirectionUp);
	}
}

function room_AfterFadeIn()
{
	if ( player.PreviousRoom == 51 )
	{
	}
	else
	{
		Wait(50);
		PlaySound(50);
		Wait(40);
		player.Transparency = 0;
		PlaySound(78);
		player.Walk(27, 88, eBlock, eWalkableAreas);
		player.FaceDirection(eDirectionDown);
	}
	RemoveWalkableArea(6);
}


/****************************
*   Tür-Hotspot-Funktionen
****************************/
function hTuer_AnyClick()
{
	if ( Door[eDoorNumTankstellentuer].Click() == 0 ) Unhandled();
}


/****************************
*   Objekt-Funktionen
****************************/
function oBuschwerk_AnyClick()
{
	if (any_click_move(126, 112, eDirectionDown))
	{
		if (UsedAction(eActWalkTo))
		{
		}
		else if (UsedAction(eActLookAt))
		{
			Wait(5);
			player.Say("Eine kleine Anordnung von Büschen.");
		}
		else if (UsedAction(eActPickUp))
		{
			Wait(5);
			player.Say("Dazu bin ich nicht kräftig genug.");
		}
		else if (UsedAction(eActUse))
		{
			Wait(5);
			player.Say("Ich muss momentan keine Notdurft verrichten.");
		}
		else if (UsedAction(eActOpen) || UsedAction(eActClose))
		{
			Wait(5);
			player.Say("Das geht nicht.");
		}
		else if (UsedAction(eActPull) || UsedAction(eActPush))
		{
			Wait(5);
			player.Say("Das ist ziemlich stabil.");
		}
		else if (UsedAction(eActUseInventory))
		{
			Wait(5);
			player.Say("Nein.");
		}
		else Unhandled();
	}
}

function oStreifenwagen_AnyClick()
{
	if (UsedAction(eActWalkTo))
	{
		any_click_move(68, 61, eDirectionUp);
	}
	else if (UsedAction(eActPull) || UsedAction(eActPush))
	{
		//if (any_click_move(271, 140, eDirectionRight))
		{
			Wait(5);
			player.Say("Was soll denn der Quatsch?");
		}
	}
	else if (UsedAction(eActOpen))
	{
		//if (any_click_move(271, 140, eDirectionRight))
		{
			Wait(5);
			player.Say("Da ist nichts drin was ich jetzt brauche.");
		}
	}
	else if (UsedAction(eActUseInventory))
	{
		Wait(5);
		if (any_click_move(27, 88, eDirectionUp))
		{
			if ( player.ActiveInventory == iFahrzeugschluessel )
			{
				player.Say("Ja. Dann wollen wir mal.");
				player.Walk(27, 63, eBlock, eAnywhere);
				Wait(7);
				player.Walk(58, 59, eBlock, eAnywhere);
				player.FaceDirection(eDirectionRight);
				Wait(10);
				player.ChangeRoom(41);
			}
			else
			{
				player.Say("Ich brauche meinen Fahrzeugschlüssel.");
			}
		}
	}
	else if (UsedAction(eActUse) && player.InventoryQuantity[iFahrzeugschluessel.ID] > 0 )
	{
    if (any_click_move(27, 88, eDirectionUp))
		{ 
      player.Say("Ja. Dann wollen wir mal.");
      player.Walk(27, 63, eBlock, eAnywhere);
      Wait(7);
      player.Walk(58, 59, eBlock, eAnywhere);
      player.FaceDirection(eDirectionRight);
      Wait(10);
      player.ChangeRoom(41);
    }
  }
  else if (any_click_move(27, 88, eDirectionUp))
	{
		if (UsedAction(eActLookAt))
		{
			Wait(5);
			player.Say("Da hinten steht mein Wagen.");
		}
		else if (UsedAction(eActPickUp))
		{
			Wait(5);
			RestoreWalkableArea (6);
			player.Walk(68, 61, eBlock, eWalkableAreas);
			player.FaceDirection(eDirectionRight);
		}
		else if (UsedAction(eActClose))
		{
			Wait(5);
			player.Say("Ich habe schon abgeschlossen.");
		}
		else Unhandled();
	}
}


/****************************
*   Hotspot-Funktionen
****************************/
function hSchild_AnyClick()
{
	if (any_click_move(176, 94, eDirectionUp))
	{
		if (UsedAction(eActWalkTo))
		{
		}
		else if (UsedAction(eActLookAt))
		{
			Wait(5);
			player.Say("\"Stan's gebrauchtes Benzin?\"");
			player.Say("Ähm ...");
			Wait(7);
			player.FaceDirection(eDirectionDown);
			Wait(7);
			player.Say("Wie kann das denn funktionieren?");
		}
		else if (UsedAction(eActPickUp))
		{
			Wait(5);
			player.Say("Das sieht stabil und festgeschraubt aus.");
		}
		else if (UsedAction(eActUse))
		{
			Wait(5);
			player.Say("Womit denn?");
		}
		else if (UsedAction(eActOpen) || UsedAction(eActPull) || UsedAction(eActPush))
		{
			Wait(5);
			player.Say("Dazu bin ich nicht befugt.");
		}
		else if (UsedAction(eActClose))
		{
			Wait(5);
			player.Say("Denk mal nach.");
		}
		else if (UsedAction(eActUseInventory))
		{
			Wait(5);
			player.Say("Das bringt nichts.");
		}
		else Unhandled();
	}
}


/****************************
*   Regionen-Funktionen
****************************/