build.gradle

version = '1.9.8' //TODO duplicated with file
group = 'org.mockito'
description = 'Core API and implementation.'

allprojects {
    apply plugin: 'java'
    apply plugin: 'eclipse'
    apply plugin: 'idea'

    repositories {
        mavenCentral()
    }
}

sourceCompatibility = 1.5

configurations {
    provided
    testUtil //TODO move to separate project
}

sourceSets {
    main {
        java.srcDir 'src'
        compileClasspath = compileClasspath + configurations.provided
    }
    test {
        java.srcDir 'test'
        compileClasspath = compileClasspath + configurations.provided
    }
}

test.include "**/*Test.class"

tasks.withType(Compile) {
    options.warnings = false
}

dependencies {
    provided fileTree('lib/compile')
    compile fileTree('lib/run') { exclude '*.txt' }, fileTree('lib/repackaged') { exclude '*.txt'}

    testCompile fileTree("lib/test")
    testRuntime fileTree("lib/compile")

    testUtil sourceSets.test.output
}

// Configure VCS in generated IPR file
idea.project.ipr {
    withXml { provider ->
        provider.node.component.find { it.@name == 'VcsDirectoryMappings' }.mapping.@vcs = 'Git'
    }
}

idea.module.scopes.PROVIDED.plus += configurations.provided
eclipse.classpath.plusConfigurations += configurations.provided

def commonJarContent = copySpec {
    //source
    from(sourceSets.main.allSource)

    //mockito license
    from(".") { include 'LICENSE', 'NOTICE' }
    //repackaged license
    from("lib/repackaged") { exclude '**/*.jar' }
    //repackaged classes
    from(zipTree("lib/repackaged/cglib-and-asm-1.0.jar")) {
        exclude 'META-INF/MANIFEST.MF'
    }
}

jar {
    baseName = 'mockito-core'
    with commonJarContent
}

task allJar(type: Jar) {
    baseName = 'mockito-all'

    with commonJarContent

    //classes
    from(sourceSets.main.output)

    //3rd party library classes
    from(zipTree("lib/run/com.springsource.org.objenesis-1.0.0.jar")) { exclude "META-INF/maven/**" }
    from(zipTree("lib/run/com.springsource.org.hamcrest.core-1.1.0.jar")) { exclude "LICENSE.txt" }

    //3rd party license files
    from("lib/run") { exclude '**/*.jar' }
}

tasks.withType(Jar) { task ->
    doLast {
        project.exec {
            commandLine 'ant', '-f', 'build-ant.xml', "osgify.$task.baseName"
        }
    }
}

artifacts {
    archives allJar
}

/*
repositories {
    mavenCentral()
}

apply plugin: 'pmd'

pmd {
    ruleSetFiles = files('conf/pmd-rules.xml')
}
*/