build.gradle

plugins {
    id 'java-gradle-plugin'
    id 'groovy'

    id 'maven-publish'
    id 'com.gradle.plugin-publish' version '0.9.10'

    id 'net.minecrell.licenser' version '0.4.1'
}

sourceCompatibility = '1.8'
targetCompatibility = '1.8'

group = 'org.cadixdev.gradle'
version = '0.10.0-SNAPSHOT'
description = 'A Gradle plugin to manage patches for Git repositories'

dependencies {
    implementation gradleApi()
}

license {
    include '**/*.java'
    include '**/*.groovy'
}

task sourceJar(type: Jar) {
    archiveClassifier = 'sources'
    from sourceSets.main.allSource
}

task groovydocJar(type: Jar, dependsOn: groovydoc) {
    archiveClassifier = 'groovydoc'
    from groovydoc.destinationDir
}

gradlePlugin {
    plugins {
        gitpatcher {
            id = 'org.cadixdev.gitpatcher'
            implementationClass = 'org.cadixdev.gradle.gitpatcher.GitPatcher'
        }
    }
}

pluginBundle {
    website = 'https://github.com/CadixDev/gitpatcher'
    vcsUrl = website
    description = project.description
    tags = ['git']

    plugins {
        gitpatcherPlugin {
            id = 'org.cadixdev.gitpatcher'
            displayName = 'gitpatcher'
        }
    }
}